configure.ac

   1 dnl| configure.in
   2 dnl|
   3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 dnl| 2008, 2009, 2010, 2011, 2012, 2013 Free Software Foundation, Inc.
   5 dnl|
   6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
   7 dnl| it under the terms of the GNU General Public License as published by
   8 dnl| the Free Software Foundation, either version 3 of the License, or (at
   9 dnl| your option) any later version.
  10 dnl|
  11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
  12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 dnl| General Public License for more details.
  15 dnl|
  16 dnl| You should have received a copy of the GNU General Public License
  17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
  18 dnl|
  19 dnl| --------------------------------------------------------------------
  20 dnl|
  21 dnl| You can process this file with autoconf to produce a configure script.
  22 dnl| However, normally the supplied configure script will work fine.
  23 dnl|
  24 dnl| If you do need to change the configure script, instead of editing
  25 dnl| it directly, try to edit configure.in (in a way that will keep
  26 dnl| it portable to sites and systems other than your own), and run autoconf
  27 dnl| to regenerate configure.  Then submit your changes to be folded into
  28 dnl| the standard version of xboard.
  29
  30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
  31 AC_INIT([xboard],[master-20130828],[bug-xboard@gnu.org])
  32
  33 dnl| need this to be able to compile some files in a subdir (filebrowser)
  34 AM_INIT_AUTOMAKE([subdir-objects])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 AC_CONFIG_HEADERS([config.h])
  38
  39 dnl | a bunch of templates for defines used below
  40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
  41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
  42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
  43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
  44 AH_TEMPLATE([HAVE_RANDOM],[template])
  45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
  46 AH_TEMPLATE([IBMRTAIX],[template])
  47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
  48 AH_TEMPLATE([PTY_ITERATION],[template])
  49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
  50 AH_TEMPLATE([PTY_OPEN],[template])
  51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
  52 AH_TEMPLATE([REMOTE_SHELL],[template])
  53 AH_TEMPLATE([RTU],[template])
  54 AH_TEMPLATE([UNIPLUS],[template])
  55 AH_TEMPLATE([USE_PTYS],[template])
  56 AH_TEMPLATE([X_WCHAR],[template])
  57 AH_TEMPLATE([ATTENTION],[template])
  58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
  59 AH_TEMPLATE([HAVE_LIBXPM],[template])
  60 AH_TEMPLATE([USE_XAW3D],[template])
  61 AH_TEMPLATE([X_LOCALE],[template])
  62
  63
  64
  65 if test -z "$CFLAGS" ; then
  66 dnl| Prevent the next macro from setting CFLAGS to -g
  67   CFLAGS=" "
  68 fi
  69 AC_PROG_CC
  70
  71 dnl| need this to be able to compile files in a subdir
  72 AM_PROG_CC_C_O
  73
  74 AC_PROG_CPP
  75 AC_ISC_POSIX
  76 AC_PROG_INSTALL
  77
  78 dnl| add gettext support
  79 AM_GNU_GETTEXT_VERSION(0.17)
  80 AM_GNU_GETTEXT([external])
  81
  82 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
  83 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
  84 if test "$MINFO" = makeinfo_not_found ; then
  85    echo Please install \"makeinfo\"
  86    exit 1
  87 fi
  88 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
  89 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
  90 AC_SUBST(NROFFFLAGS)
  91 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
  92 AC_PATH_PROGS(PERLPATH, perl)
  93
  94 AC_HEADER_STDC
  95 AC_HEADER_TIME
  96 AC_HEADER_SYS_WAIT
  97 AC_HEADER_DIRENT
  98 AC_TYPE_SIGNAL
  99 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
 100 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
 101 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
 102 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
 103
 104 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
 105 AC_CHECK_FUNCS(gettimeofday ftime, break)
 106 AC_CHECK_FUNCS(random rand48, break)
 107 AC_CHECK_FUNCS(gethostname sysinfo, break)
 108 AC_CHECK_FUNC(setlocale, [],
 109   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
 110
 111 AC_CHECK_LIB(seq, getpseudotty)
 112
 113 dnl | add compiler warnings only if compiler understands them
 114 AC_MSG_CHECKING(whether compiler understands -Wall -Wno-parentheses)
 115 SAVE_CFLAGS="$CFLAGS"
 116 CFLAGS="$CFLAGS -Wall -Wno-parentheses"
 117 AC_TRY_COMPILE([],[],
 118   AC_MSG_RESULT(yes),
 119   AC_MSG_RESULT(no)
 120   CFLAGS="$SAVE_CFLAGS")
 121
 122 dnl | check for pkg-config
 123 AC_CHECK_PROGS([PKGCONFIG], [pkg-config], pkgconfig_not_found)
 124 AS_IF( [test "x$PKGCONFIG" = xpkgconfig_not_found],
 125        AC_MSG_ERROR([cannot find pkg-config! Please install it.]))
 126
 127 dnl | check for cairo and librsvg
 128 PKG_CHECK_MODULES([CAIRO], [ cairo >= 1.2.0 librsvg-2.0 >= 2.14.0 ])
 129 AC_SUBST(CAIRO_CFLAGS)
 130 AC_SUBST(CAIRO_LIBS)
 131
 132 dnl | check which front end to use
 133 dnl | first check for gtk
 134 dnl | then for Xaw3d
 135 dnl | and then for Xaw
 136 FRONTEND_CFLAGS=""
 137 FRONTEND_LIBS=""
 138
 139 AC_ARG_WITH([gtk],
 140             [AS_HELP_STRING([--with-gtk],[use GTK front-end (experimental)])],
 141             [with_GTK=$withval],
 142             [with_GTK="no"])
 143
 144 AC_ARG_WITH([Xaw3d],
 145             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d front-end (not fully supported anymore)])],
 146             [with_Xaw3d="$withval"],
 147             [with_Xaw3d="no"])
 148
 149 AC_ARG_WITH([Xaw],
 150             [AS_HELP_STRING([--with-Xaw],[use Xaw front-end (default)])],
 151             [with_Xaw="$withval"],
 152             [with_Xaw="yes"])
 153
 154 AC_ARG_WITH([iconsdir],
 155             [AS_HELP_STRING([--with-iconsdir=DIR],
 156             [path where icons get installed (default: $datadir/icons/hicolor/48x48/apps)])],
 157             [ICONSDIR="$withval"],
 158             [ICONSDIR='$(datadir)/icons/hicolor/48x48/apps'])
 159
 160 AC_ARG_WITH([svgiconsdir],
 161             [AS_HELP_STRING([--with-svgiconsdir=DIR],
 162             [path where svg icons get installed (default: $datadir/icons/hicolor/scalable/apps)])],
 163             [SVGICONSDIR="$withval"],
 164             [SVGICONSDIR='$(datadir)/icons/hicolor/scalable/apps'])
 165
 166 AC_ARG_WITH([desktopdir],
 167             [AS_HELP_STRING([--with-desktopdir=DIR],
 168                             [path where desktop files get installed (default: $datadir/applications)])],
 169             [DESKTOPDIR="$withval"],
 170             [DESKTOPDIR='$(datadir)/applications'])
 171
 172 AC_ARG_WITH([mimedir],
 173             [AS_HELP_STRING([--with-mimedir=DIR],
 174                             [path where mime files get installed (default: $datadir/mime/packages)])],
 175             [MIMEDIR="$withval"],
 176             [MIMEDIR='$(datadir)/mime/packages'])
 177
 178 AC_ARG_WITH([gamedatadir],
 179             [AS_HELP_STRING([--with-gamedatadir=DIR],
 180                             [path where game data files get installed (default: $datadir/games/xboard)])],
 181             [GAMEDATADIR="$withval"],
 182             [GAMEDATADIR='$(datadir)/games/xboard'])
 183
 184 AC_SUBST(ICONSDIR)
 185 AC_SUBST(SVGICONSDIR)
 186 AC_SUBST(DESKTOPDIR)
 187 AC_SUBST(MIMEDIR)
 188 AC_SUBST(GAMEDATADIR)
 189
 190 dnl | check for libraries
 191 if test x"$with_GTK" = x"yes" ; then
 192   PKG_CHECK_MODULES([GTK], [ gtk+-2.0 >= 2.16.0 gmodule-2.0 ])
 193   FRONTEND_CFLAGS=$GTK_CFLAGS
 194   FRONTEND_LIBS=$GTK_LIBS
 195   with_Xaw="no"
 196 fi
 197
 198 if test x"$with_GTK" = x"no" ; then
 199
 200 dnl | general check for Xaw and Xaw3d
 201   AC_PATH_XTRA
 202   if test -n "$no_x" ; then
 203     AC_MSG_ERROR([ "    $PACKAGE requires the X Window System header files and libraries!
 204     They were not found on your system.  See FAQ topic C.2.
 205     configure failed"])
 206   fi
 207
 208   save_cflags="$CFLAGS"
 209   save_cppflags="$CPPFLAGS"
 210   CFLAGS="$CFLAGS $X_CFLAGS"
 211   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 212   AC_CHECK_HEADER([X11/Intrinsic.h],[xt="yes"],[xt="no"])
 213   CFLAGS="$save_cflags"
 214   CPPFLAGS="$save_cppflags"
 215
 216   if test "$xt" = "no" ; then
 217      AC_MSG_ERROR([Xt headers not found. Please install the X11 packages.])
 218   fi
 219
 220 dnl | check availability of Xaw3d
 221   FRONTEND_LIBS=
 222   AS_IF([test x"$with_Xaw3d" != x"no"],
 223             [AC_CHECK_LIB([Xaw3d],
 224                     [XawTextReplace],
 225                     [ FRONTEND_LIBS="-lXaw3d"
 226                       AC_DEFINE([USE_XAW3D], [1], [Define if you want to use Xaw3d])],
 227                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
 228                                [-lXaw])])
 229
 230 dnl | no Xaw3d, check for Xaw; make it the default
 231   if test x"$with_Xaw3d" = x"no" ; then
 232      with_Xaw=yes
 233      save_cflags="$CFLAGS"
 234      save_cppflags="$CPPFLAGS"
 235      CFLAGS="$CFLAGS $X_CFLAGS"
 236      CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 237      AC_CHECK_HEADER([X11/Xaw/Dialog.h],[xaw_headers="yes"], [xaw_headers="no"])
 238      CFLAGS="$save_cflags"
 239      CPPFLAGS="$save_cppflags"
 240
 241      if test x"$xaw_headers" = x"no" ; then
 242         AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
 243      fi
 244
 245      FRONTEND_LIBS="-lXaw"
 246   fi
 247
 248 fi
 249
 250 dnl | make results available in Makefile.am
 251 AM_CONDITIONAL([withGTK],   [test x"$with_GTK" = x"yes"])
 252 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw3d" = x"yes" || test x"$with_Xaw" = x"yes"])
 253
 254
 255 AC_SUBST(FRONTEND_CFLAGS)
 256 AC_SUBST(FRONTEND_LIBS)
 257
 258 dnl | end Front-end check
 259
 260 AC_CANONICAL_HOST
 261
 262 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
 263 dnl| we are trying to find out whether this is a System-V derivative in
 264 dnl| which pipes don't work with select() and if so, whether there is anything
 265 dnl| strange about the way to open a pty.  Some of the work was done above
 266 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
 267 dnl| properties of particular systems are also handled here.
 268
 269 dnl| 4/6/97 I'm not sure there really are any systems where pipes
 270 dnl| don't work with select(), and ptys cause problems on many
 271 dnl| systems, so I'm changing the default to disable ptys in all
 272 dnl| cases.  I will change it back if I get bug reports that are fixed
 273 dnl| by doing a "configure --enable-ptys"
 274
 275 USE_PTYS=0
 276 case "$host" in
 277   *-*-hpux* )
 278     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 279         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
 280     AC_DEFINE(PTY_NAME_SPRINTF,
 281         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
 282 dnl| USE_PTYS=1
 283     if test "$GCC" = yes; then
 284       CONF_CFLAGS="-fwritable-strings"
 285     else
 286
 287 dnl| Note: You might be able to build xboard even if your compiler does not
 288 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
 289 dnl| know whether the X header files on HP-UX require it.
 290
 291       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
 292     fi
 293
 294 dnl| HP doesn't supply a full set of X header files and libraries.  People
 295 dnl| often have some things installed in one place and some in another.
 296 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
 297 dnl| likely ones that might be missing here.  It might be better to
 298 dnl| change AC_PATH_XTRA to try to extract this information from imake,
 299 dnl| since folks who install the missing bits often configure their
 300 dnl| imake to find them, but I don't want to delve into autoconf and
 301 dnl| hack on its internals.
 302
 303     if test -d /opt/hppd/include/X11; then
 304       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
 305       X_LIBS="$X_LIBS -L/opt/hppd/lib"
 306     elif test -d /usr/contrib/X11R5/include; then
 307       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
 308       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
 309     elif test -d /usr/contrib/mitX11R5/include; then
 310       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
 311       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
 312     elif test -d /MIT/X11R5/include; then
 313       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
 314       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
 315     elif test -d /usr/local/include/X11R5; then
 316       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
 317       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
 318     fi
 319     if test -d /usr/include/X11R5; then
 320       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
 321       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
 322     elif test -d /usr/include/X11R4; then
 323       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
 324       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
 325     fi
 326   ;;
 327
 328   romp-ibm-aix* )
 329     AC_DEFINE(IBMRTAIX, 1)
 330 dnl| USE_PTYS=1
 331   ;;
 332
 333   i386-ibm-aix )
 334 dnl| USE_PTYS=1
 335     if test "$GCC" = yes; then
 336       CONF_CFLAGS="-fwritable-strings"
 337     fi
 338   ;;
 339
 340   *-*-aix3* | *-*-bosx* )
 341     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 342     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 343     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
 344 dnl| USE_PTYS=1
 345   ;;
 346
 347   *-*-cxux* )
 348     AC_DEFINE(FIRST_PTY_LETTER, 'A')
 349     AC_DEFINE(LAST_PTY_LETTER, 'P')
 350 dnl| USE_PTYS=1
 351   ;;
 352
 353   *-*-uniplus* )
 354     AC_DEFINE(UNIPLUS, 1)
 355 dnl| USE_PTYS=1
 356   ;;
 357
 358   *-*-rtu* )
 359     AC_DEFINE(FIRST_PTY_LETTER, 'z')
 360     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 361         [sprintf (pty_name, "/dev/ttyp%x", i);])
 362     AC_DEFINE(PTY_NAME_SPRINTF,
 363         [sprintf (pty_name, "/dev/pty%x", i);])
 364     AC_DEFINE(RTU, 1)
 365 dnl| USE_PTYS=1
 366   ;;
 367
 368   *-*-iris* | *-*-irix3* )
 369     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 370     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 371     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 372         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
 373 dnl| USE_PTYS=1
 374   ;;
 375
 376   *-*-irix* )
 377 dnl| USE_PTYS=1
 378   ;;
 379
 380   *-*-sunos4* | *-*-solaris1* )
 381
 382 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
 383 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
 384 dnl|  "overkill," but doesn't explain what should be done instead.
 385
 386     if test "$GCC" = yes; then
 387       PRE_XMULIB="-static"
 388       POST_XMULIB="-dynamic"
 389     else
 390       PRE_XMULIB="-Bstatic"
 391       POST_XMULIB="-Bdynamic"
 392     fi
 393   ;;
 394
 395   *-*-sunos5* | *-*-solaris2* )
 396 dnl| USE_PTYS=1
 397
 398 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
 399 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
 400 dnl| code above.
 401
 402     X_LIBS="$X_LIBS -lelf"
 403   ;;
 404
 405   *-*-sco* )
 406     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
 407     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
 408     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
 409 dnl| USE_PTYS=1
 410   ;;
 411
 412   *-*-dynix* | *-*-ptx* )
 413 dnl| USE_PTYS=1
 414   ;;
 415
 416   *-*-esix* )
 417 dnl| USE_PTYS=1
 418   ;;
 419
 420   *-*-usg5-4* | *-*-sysvr4* )
 421 dnl| USE_PTYS=1
 422   ;;
 423
 424   *-*-usg* | *-*-sysv* | *-*-aix* )
 425 dnl| USE_PTYS=1
 426   ;;
 427
 428   vax-*-ultrix )
 429     if test "$GCC" = yes; then
 430       CONF_CFLAGS="-fwritable-strings"
 431     fi
 432   ;;
 433
 434 dnl| add some libs for OS X
 435   *-apple-* )
 436   ;;
 437 esac
 438
 439 AC_ARG_ENABLE(  [xpm],
 440                 [AS_HELP_STRING([--enable-xpm],[libXpm will be used if found (default)])],
 441                 [enable_xpm="$enableval"],
 442                 [enable_xpm="yes"])
 443
 444 if test x"$enable_xpm" != "xno"; then
 445   save_cflags="$CFLAGS"
 446   save_cppflags="$CPPFLAGS"
 447   CFLAGS="$CFLAGS $X_CFLAGS"
 448   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 449   AC_CHECK_HEADERS(X11/xpm.h)
 450   CFLAGS="$save_cflags"
 451   CPPFLAGS="$save_cppflags"
 452   if test "$ac_cv_header_X11_xpm_h" = "yes"; then
 453     save_ldflags="$LDFLAGS"
 454     LDFLAGS="$LDFLAGS $X_LIBS"
 455     AC_CHECK_LIB(Xpm, XpmReadFileToPixmap,
 456                  [X_PRE_LIBS="-lXpm $X_PRE_LIBS"; AC_DEFINE(HAVE_LIBXPM)], [],
 457                  [$X_PRE_LIBS -lX11 $X_EXTRA_LIBS])
 458     LDFLAGS="$save_ldflags"
 459   fi
 460 fi
 461
 462 AC_SUBST(PRE_XMULIB)
 463 AC_SUBST(POST_XMULIB)
 464 AC_SUBST(CONF_CFLAGS)
 465 AC_SUBST(CONF_LDFLAGS)
 466
 467 AC_MSG_CHECKING(whether ptys or pipes should be used)
 468 AC_ARG_ENABLE( [ptys],
 469                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
 470 [if test "$enableval" = yes; then
 471   USE_PTYS=1
 472   enable_ptys="ptys"
 473   AC_MSG_RESULT([ptys (user override)])
 474 fi
 475 if test "$enableval" = no; then
 476   USE_PTYS=0
 477   enable_ptys="pipes"
 478   AC_MSG_RESULT([pipes (user override)])
 479 fi],
 480 [if test "$USE_PTYS" = 1; then
 481   AC_MSG_RESULT(ptys)
 482   enable_ptys="ptys"
 483 else
 484   AC_MSG_RESULT(pipes)
 485   enable_ptys="pipes"
 486 fi])
 487 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
 488
 489
 490 dnl | define not to build zippy as a default, so that autoheader is happy
 491 AC_ARG_ENABLE( [zippy],
 492                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
 493                [],
 494                [enable_zippy="no"])
 495
 496 if test x"$enable_zippy" != xno; then
 497   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
 498 else
 499   AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
 500 fi
 501 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
 502
 503
 504 AC_ARG_ENABLE(sigint,
 505 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
 506 [if test "$enableval" = yes; then
 507   AC_DEFINE(ATTENTION, 1)
 508 fi
 509 enable_sigint=$enableval
 510 ],
 511 [enable_sigint="yes"
 512 AC_DEFINE(ATTENTION, 1)])
 513
 514
 515 if test x"$with_Xaw3d" = x"yes" -o  x"$with_Xaw" = x"yes" ; then
 516 dnl | save all information for X in X_LIBS, also add the libraries themself
 517 dnl | since AC_PATH_XTRA only adds the paths
 518 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
 519 AC_SUBST(X_CFLAGS)
 520 AC_SUBST(X_LIBS)
 521 fi
 522
 523 dnl | should we install desktop icons and mime associations?
 524 AC_ARG_ENABLE(  [update-mimedb],
 525                 [AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]])],
 526                 [enable_mimedb="no"],
 527                 [enable_mimedb="yes"])
 528
 529 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x"$enable_mimedb" = "xyes")
 530
 531 if test x"$enable_mimedb" = "xyes"; then
 532    AC_PATH_PROG([XDG_MIME],[xdg-mime])
 533    AC_SUBST(XDG_MIME)
 534    AC_PATH_PROG([XDG_DESKTOP_MENU],[xdg-desktop-menu])
 535    AC_SUBST(XDG_DESKTOP_MENU)
 536    AC_PATH_PROG([XDG_ICON_RESOURCE],[xdg-icon-resource])
 537    AC_SUBST(XDG_ICON_RESOURCE)
 538 fi
 539
 540 dnl create a string with configure options that can be passed to the
 541 dnl program, good for bug reports and version printout, see output below
 542 CONFIGURE_OPTIONS="prefix=$prefix; datarootdir=$datarootdir; \
 543 datadir=$datadir; gamedatadir=$GAMEDATADIR; desktopdir=$DESKTOPDIR; \
 544 mimedir=$MIMEDIR; iconsdir=$ICONSDIR; svgiconsdir=$SVGICONSDIR; infodir=$infodir; \
 545 sysconfigdir=$sysconfigdir; update_mimedb=$enable_mimedb; NLS=$USE_NLS; \
 546 GKT=$with_GTK; Xaw3d=$with_Xaw3d; Xaw=$with_Xaw; xpm=$enable_xpm; \
 547 ptys=$enable_ptys; zippy=$enable_zippy; sigint=$enable_sigint"
 548
 549 AC_SUBST(CONFIGURE_OPTIONS)
 550
 551 dnl |  output Makefile
 552 AC_CONFIG_FILES([Makefile cmail po/Makefile.in])
 553 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
 554 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
 555 AC_OUTPUT
 556
 557 dnl
 558 dnl Output a summary
 559 dnl
 560 echo ""
 561 echo " Configurations summary:"
 562 echo ""
 563 echo "        prefix:          $prefix       "
 564 echo "        datarootdir:     $datarootdir  "
 565 echo "        datadir:         $datadir      "
 566 echo "        gamedatadir:     $GAMEDATADIR  "
 567 echo "        desktopdir:      $DESKTOPDIR   "
 568 echo "        mimedir:         $MIMEDIR      "
 569 echo "        iconsdir:        $ICONSDIR     "
 570 echo "        svgiconsdir:     $SVGICONSDIR  "
 571 echo "        infodir:         $infodir   (info files will go here)"
 572 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
 573 echo ""
 574 echo "        update mimedb:   $enable_mimedb"
 575 echo ""
 576 echo "        NLS support:     $USE_NLS"
 577 echo ""
 578 echo "        GTK:             $with_GTK"
 579 echo "        Xaw3d:           $with_Xaw3d"
 580 echo "        Xaw:             $with_Xaw"
 581 echo ""
 582 echo "        xpm:             $enable_xpm"
 583 echo "        ptys:            $enable_ptys"
 584 echo "        zippy:           $enable_zippy"
 585 echo "        sigint:          $enable_sigint"