configure.ac

   1 dnl| configure.in
   2 dnl|
   3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 dnl| 2008, 2009, 2010, 2011, 2012, 2013, 2014 Free Software Foundation, Inc.
   5 dnl|
   6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
   7 dnl| it under the terms of the GNU General Public License as published by
   8 dnl| the Free Software Foundation, either version 3 of the License, or (at
   9 dnl| your option) any later version.
  10 dnl|
  11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
  12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 dnl| General Public License for more details.
  15 dnl|
  16 dnl| You should have received a copy of the GNU General Public License
  17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
  18 dnl|
  19 dnl| --------------------------------------------------------------------
  20 dnl|
  21 dnl| You can process this file with autoconf to produce a configure script.
  22 dnl| However, normally the supplied configure script will work fine.
  23 dnl|
  24 dnl| If you do need to change the configure script, instead of editing
  25 dnl| it directly, try to edit configure.in (in a way that will keep
  26 dnl| it portable to sites and systems other than your own), and run autoconf
  27 dnl| to regenerate configure.  Then submit your changes to be folded into
  28 dnl| the standard version of xboard.
  29
  30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
  31 AC_INIT([xboard],[4.8.0],[bug-xboard@gnu.org])
  32
  33 dnl| need this to be able to compile some files in a subdir (filebrowser)
  34 AM_INIT_AUTOMAKE([subdir-objects])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 AC_CONFIG_HEADERS([config.h])
  38
  39 dnl | a bunch of templates for defines used below
  40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
  41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
  42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
  43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
  44 AH_TEMPLATE([HAVE_RANDOM],[template])
  45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
  46 AH_TEMPLATE([IBMRTAIX],[template])
  47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
  48 AH_TEMPLATE([PTY_ITERATION],[template])
  49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
  50 AH_TEMPLATE([PTY_OPEN],[template])
  51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
  52 AH_TEMPLATE([REMOTE_SHELL],[template])
  53 AH_TEMPLATE([RTU],[template])
  54 AH_TEMPLATE([UNIPLUS],[template])
  55 AH_TEMPLATE([USE_PTYS],[template])
  56 AH_TEMPLATE([X_WCHAR],[template])
  57 AH_TEMPLATE([ATTENTION],[template])
  58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
  59 AH_TEMPLATE([USE_XAW3D],[template])
  60 AH_TEMPLATE([X_LOCALE],[template])
  61
  62
  63
  64 if test -z "$CFLAGS" ; then
  65 dnl| Prevent the next macro from setting CFLAGS to -g
  66   CFLAGS=" "
  67 fi
  68 AC_PROG_CC
  69
  70 dnl| need this to be able to compile files in a subdir
  71 AM_PROG_CC_C_O
  72
  73 AC_PROG_CPP
  74 AC_ISC_POSIX
  75 AC_PROG_INSTALL
  76
  77 dnl| add gettext support
  78 AM_GNU_GETTEXT_VERSION(0.17)
  79 AM_GNU_GETTEXT([external])
  80
  81 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
  82 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
  83 if test "$MINFO" = makeinfo_not_found ; then
  84    echo Please install \"makeinfo\"
  85    exit 1
  86 fi
  87 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
  88 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
  89 AC_SUBST(NROFFFLAGS)
  90 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
  91 AC_PATH_PROGS(PERLPATH, perl)
  92
  93 AC_HEADER_STDC
  94 AC_HEADER_TIME
  95 AC_HEADER_SYS_WAIT
  96 AC_HEADER_DIRENT
  97 AC_TYPE_SIGNAL
  98 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
  99 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
 100 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
 101 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
 102
 103 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
 104 AC_CHECK_FUNCS(gettimeofday ftime, break)
 105 AC_CHECK_FUNCS(random rand48, break)
 106 AC_CHECK_FUNCS(gethostname sysinfo, break)
 107 AC_CHECK_FUNC(setlocale, [],
 108   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
 109
 110 AC_CHECK_LIB(seq, getpseudotty)
 111
 112 dnl | add compiler warnings only if compiler understands them
 113 AC_MSG_CHECKING(whether compiler understands -Wall -Wno-parentheses)
 114 SAVE_CFLAGS="$CFLAGS"
 115 CFLAGS="$CFLAGS -Wall -Wno-parentheses"
 116 AC_TRY_COMPILE([],[],
 117   AC_MSG_RESULT(yes),
 118   AC_MSG_RESULT(no)
 119   CFLAGS="$SAVE_CFLAGS")
 120
 121 dnl | check for pkg-config
 122 AC_CHECK_PROGS([PKGCONFIG], [pkg-config], pkgconfig_not_found)
 123 AS_IF( [test "x$PKGCONFIG" = xpkgconfig_not_found],
 124        AC_MSG_ERROR([cannot find pkg-config! Please install it.]))
 125
 126 dnl | check for cairo and librsvg
 127 PKG_CHECK_MODULES([CAIRO], [ cairo >= 1.2.0 librsvg-2.0 >= 2.14.0 ])
 128 AC_SUBST(CAIRO_CFLAGS)
 129 AC_SUBST(CAIRO_LIBS)
 130
 131 dnl | check which front end to use
 132 dnl | first check for gtk
 133 dnl | then for Xaw3d
 134 dnl | and then for Xaw
 135 FRONTEND_CFLAGS=""
 136 FRONTEND_LIBS=""
 137
 138 AC_ARG_WITH([gtk],
 139             [AS_HELP_STRING([--with-gtk],[use GTK front-end])],
 140             [with_GTK=$withval],
 141             [with_GTK="no"])
 142
 143 AC_ARG_WITH([Xaw3d],
 144             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d front-end (not fully supported anymore)])],
 145             [with_Xaw3d="$withval"],
 146             [with_Xaw3d="no"])
 147
 148 AC_ARG_WITH([Xaw],
 149             [AS_HELP_STRING([--with-Xaw],[use Xaw front-end (default)])],
 150             [with_Xaw="$withval"],
 151             [with_Xaw="yes"])
 152
 153 AC_ARG_WITH([iconsdir],
 154             [AS_HELP_STRING([--with-iconsdir=DIR],
 155             [path where icons get installed (default: $datadir/icons/hicolor/48x48/apps)])],
 156             [ICONSDIR="$withval"],
 157             [ICONSDIR='$(datadir)/icons/hicolor/48x48/apps'])
 158
 159 AC_ARG_WITH([svgiconsdir],
 160             [AS_HELP_STRING([--with-svgiconsdir=DIR],
 161             [path where svg icons get installed (default: $datadir/icons/hicolor/scalable/apps)])],
 162             [SVGICONSDIR="$withval"],
 163             [SVGICONSDIR='$(datadir)/icons/hicolor/scalable/apps'])
 164
 165 AC_ARG_WITH([desktopdir],
 166             [AS_HELP_STRING([--with-desktopdir=DIR],
 167                             [path where desktop files get installed (default: $datadir/applications)])],
 168             [DESKTOPDIR="$withval"],
 169             [DESKTOPDIR='$(datadir)/applications'])
 170
 171 AC_ARG_WITH([mimedir],
 172             [AS_HELP_STRING([--with-mimedir=DIR],
 173                             [path where mime files get installed (default: $datadir/mime/packages)])],
 174             [MIMEDIR="$withval"],
 175             [MIMEDIR='$(datadir)/mime/packages'])
 176
 177 AC_ARG_WITH([gamedatadir],
 178             [AS_HELP_STRING([--with-gamedatadir=DIR],
 179                             [path where game data files get installed (default: $datadir/games/xboard)])],
 180             [GAMEDATADIR="$withval"],
 181             [GAMEDATADIR='$(datadir)/games/xboard'])
 182
 183 AC_ARG_ENABLE([update-mimedb],
 184               [AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]])],
 185               [enable_mimedb="no"],
 186               [enable_mimedb="yes"])
 187
 188 AC_ARG_ENABLE([osxapp],
 189               [AS_HELP_STRING([--enable-osxapp],[build a OSX app [default=no]])],
 190               [enable_OSXAPP=$withval],
 191               [enable_OSXAPP="no"])
 192
 193 AS_IF([test x"$enable_OSXAPP" = x"yes"], [
 194      AC_PREFIX_DEFAULT([`pwd`/XBoard.app/Contents])
 195      with_GTK="yes"
 196      enable_mimedb="no"
 197      datarootdir='$(prefix)/Resources'
 198      datadir='$(datarootdir)/share'
 199      sysconfdir='$(datarootdir)/etc'
 200      infodir='$(datadir)/info'
 201      mandir='$(datadir)/man'
 202      bindir='$(prefix)/MacOS'
 203      localedir='$(datadir)/locale'
 204      GAMEDATADIR='$(datadir)/xboard'
 205 ])
 206
 207 AM_CONDITIONAL(OSX_APP, test x"$enable_OSXAPP" = x"yes")
 208
 209 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x"$enable_mimedb" = x"yes")
 210 if test x"$enable_mimedb" = x"yes"; then
 211    AC_PATH_PROG([XDG_MIME],[xdg-mime])
 212    AC_SUBST(XDG_MIME)
 213    AC_PATH_PROG([XDG_DESKTOP_MENU],[xdg-desktop-menu])
 214    AC_SUBST(XDG_DESKTOP_MENU)
 215    AC_PATH_PROG([XDG_ICON_RESOURCE],[xdg-icon-resource])
 216    AC_SUBST(XDG_ICON_RESOURCE)
 217 fi
 218
 219 AC_SUBST(ICONSDIR)
 220 AC_SUBST(SVGICONSDIR)
 221 AC_SUBST(DESKTOPDIR)
 222 AC_SUBST(MIMEDIR)
 223 AC_SUBST(GAMEDATADIR)
 224
 225 dnl | check for libraries
 226 if test x"$with_GTK" = x"yes" ; then
 227   PKG_CHECK_MODULES([GTK], [ gtk+-2.0 >= 2.16.0 gmodule-2.0 ])
 228   FRONTEND_CFLAGS=$GTK_CFLAGS
 229   FRONTEND_LIBS=$GTK_LIBS
 230   with_Xaw="no"
 231 fi
 232
 233 if test x"$with_GTK" = x"no" ; then
 234
 235 dnl | general check for Xaw and Xaw3d
 236   AC_PATH_XTRA
 237   if test -n "$no_x" ; then
 238     AC_MSG_ERROR([ "    $PACKAGE requires the X Window System header files and libraries!
 239     They were not found on your system.  See FAQ topic C.2.
 240     configure failed"])
 241   fi
 242
 243   save_cflags="$CFLAGS"
 244   save_cppflags="$CPPFLAGS"
 245   CFLAGS="$CFLAGS $X_CFLAGS"
 246   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 247   AC_CHECK_HEADER([X11/Intrinsic.h],[xt="yes"],[xt="no"])
 248   CFLAGS="$save_cflags"
 249   CPPFLAGS="$save_cppflags"
 250
 251   if test "$xt" = "no" ; then
 252      AC_MSG_ERROR([Xt headers not found. Please install the X11 packages.])
 253   fi
 254
 255 dnl | check availability of Xaw3d
 256   FRONTEND_LIBS=
 257   AS_IF([test x"$with_Xaw3d" != x"no"],
 258             [AC_CHECK_LIB([Xaw3d],
 259                     [XawTextReplace],
 260                     [ FRONTEND_LIBS="-lXaw3d"
 261                       AC_DEFINE([USE_XAW3D], [1], [Define if you want to use Xaw3d])],
 262                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
 263                                [-lXaw])])
 264
 265 dnl | no Xaw3d, check for Xaw; make it the default
 266   if test x"$with_Xaw3d" = x"no" ; then
 267      with_Xaw=yes
 268      save_cflags="$CFLAGS"
 269      save_cppflags="$CPPFLAGS"
 270      CFLAGS="$CFLAGS $X_CFLAGS"
 271      CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 272      AC_CHECK_HEADER([X11/Xaw/Dialog.h],[xaw_headers="yes"], [xaw_headers="no"])
 273      CFLAGS="$save_cflags"
 274      CPPFLAGS="$save_cppflags"
 275
 276      if test x"$xaw_headers" = x"no" ; then
 277         AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
 278      fi
 279
 280      FRONTEND_LIBS="-lXaw"
 281   fi
 282
 283 fi
 284
 285 dnl | make results available in Makefile.am
 286 AM_CONDITIONAL([withGTK],   [test x"$with_GTK" = x"yes"])
 287 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw3d" = x"yes" || test x"$with_Xaw" = x"yes"])
 288
 289 dnl | end Front-end check
 290
 291 AC_CANONICAL_HOST
 292
 293 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
 294 dnl| we are trying to find out whether this is a System-V derivative in
 295 dnl| which pipes don't work with select() and if so, whether there is anything
 296 dnl| strange about the way to open a pty.  Some of the work was done above
 297 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
 298 dnl| properties of particular systems are also handled here.
 299
 300 dnl| 4/6/97 I'm not sure there really are any systems where pipes
 301 dnl| don't work with select(), and ptys cause problems on many
 302 dnl| systems, so I'm changing the default to disable ptys in all
 303 dnl| cases.  I will change it back if I get bug reports that are fixed
 304 dnl| by doing a "configure --enable-ptys"
 305
 306 USE_PTYS=0
 307 case "$host" in
 308   *-*-hpux* )
 309     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 310         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
 311     AC_DEFINE(PTY_NAME_SPRINTF,
 312         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
 313 dnl| USE_PTYS=1
 314     if test "$GCC" = yes; then
 315       CONF_CFLAGS="-fwritable-strings"
 316     else
 317
 318 dnl| Note: You might be able to build xboard even if your compiler does not
 319 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
 320 dnl| know whether the X header files on HP-UX require it.
 321
 322       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
 323     fi
 324
 325 dnl| HP doesn't supply a full set of X header files and libraries.  People
 326 dnl| often have some things installed in one place and some in another.
 327 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
 328 dnl| likely ones that might be missing here.  It might be better to
 329 dnl| change AC_PATH_XTRA to try to extract this information from imake,
 330 dnl| since folks who install the missing bits often configure their
 331 dnl| imake to find them, but I don't want to delve into autoconf and
 332 dnl| hack on its internals.
 333
 334     if test -d /opt/hppd/include/X11; then
 335       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
 336       X_LIBS="$X_LIBS -L/opt/hppd/lib"
 337     elif test -d /usr/contrib/X11R5/include; then
 338       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
 339       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
 340     elif test -d /usr/contrib/mitX11R5/include; then
 341       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
 342       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
 343     elif test -d /MIT/X11R5/include; then
 344       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
 345       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
 346     elif test -d /usr/local/include/X11R5; then
 347       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
 348       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
 349     fi
 350     if test -d /usr/include/X11R5; then
 351       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
 352       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
 353     elif test -d /usr/include/X11R4; then
 354       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
 355       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
 356     fi
 357   ;;
 358
 359   romp-ibm-aix* )
 360     AC_DEFINE(IBMRTAIX, 1)
 361 dnl| USE_PTYS=1
 362   ;;
 363
 364   i386-ibm-aix )
 365 dnl| USE_PTYS=1
 366     if test "$GCC" = yes; then
 367       CONF_CFLAGS="-fwritable-strings"
 368     fi
 369   ;;
 370
 371   *-*-aix3* | *-*-bosx* )
 372     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 373     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 374     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
 375 dnl| USE_PTYS=1
 376   ;;
 377
 378   *-*-cxux* )
 379     AC_DEFINE(FIRST_PTY_LETTER, 'A')
 380     AC_DEFINE(LAST_PTY_LETTER, 'P')
 381 dnl| USE_PTYS=1
 382   ;;
 383
 384   *-*-uniplus* )
 385     AC_DEFINE(UNIPLUS, 1)
 386 dnl| USE_PTYS=1
 387   ;;
 388
 389   *-*-rtu* )
 390     AC_DEFINE(FIRST_PTY_LETTER, 'z')
 391     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 392         [sprintf (pty_name, "/dev/ttyp%x", i);])
 393     AC_DEFINE(PTY_NAME_SPRINTF,
 394         [sprintf (pty_name, "/dev/pty%x", i);])
 395     AC_DEFINE(RTU, 1)
 396 dnl| USE_PTYS=1
 397   ;;
 398
 399   *-*-iris* | *-*-irix3* )
 400     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 401     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 402     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 403         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
 404 dnl| USE_PTYS=1
 405   ;;
 406
 407   *-*-irix* )
 408 dnl| USE_PTYS=1
 409   ;;
 410
 411   *-*-sunos4* | *-*-solaris1* )
 412
 413 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
 414 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
 415 dnl|  "overkill," but doesn't explain what should be done instead.
 416
 417     if test "$GCC" = yes; then
 418       PRE_XMULIB="-static"
 419       POST_XMULIB="-dynamic"
 420     else
 421       PRE_XMULIB="-Bstatic"
 422       POST_XMULIB="-Bdynamic"
 423     fi
 424   ;;
 425
 426   *-*-sunos5* | *-*-solaris2* )
 427 dnl| USE_PTYS=1
 428
 429 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
 430 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
 431 dnl| code above.
 432
 433     X_LIBS="$X_LIBS -lelf"
 434   ;;
 435
 436   *-*-sco* )
 437     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
 438     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
 439     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
 440 dnl| USE_PTYS=1
 441   ;;
 442
 443   *-*-dynix* | *-*-ptx* )
 444 dnl| USE_PTYS=1
 445   ;;
 446
 447   *-*-esix* )
 448 dnl| USE_PTYS=1
 449   ;;
 450
 451   *-*-usg5-4* | *-*-sysvr4* )
 452 dnl| USE_PTYS=1
 453   ;;
 454
 455   *-*-usg* | *-*-sysv* | *-*-aix* )
 456 dnl| USE_PTYS=1
 457   ;;
 458
 459   vax-*-ultrix )
 460     if test "$GCC" = yes; then
 461       CONF_CFLAGS="-fwritable-strings"
 462     fi
 463   ;;
 464
 465 dnl| add some libs for OS X
 466   *-apple-* )
 467     AC_MSG_WARN([Apple support is experimental, please report any problems to bug-xboard@gnu.org])
 468     AC_MSG_WARN([use --enable-osxapp to enable the build target and automatically adjust target directories])
 469     AC_MSG_WARN([Building an OSX app currently relies on some programs such as dylib that we don't test for])
 470     AC_MSG_WARN([patches welcome ;)])
 471     AC_PATH_PROG(SW_VERS, sw_vers)
 472     if test "x$SW_VERS" != "x"; then
 473       AC_MSG_CHECKING(Mac OS X version)
 474       MACOSX_VERSION=`$SW_VERS -productVersion`
 475       AC_MSG_RESULT([$MACOSX_VERSION])
 476     fi
 477     FRONTEND_LIBS="$FRONTEND_LIBS -lgtkmacintegration -headerpad_max_install_names "
 478     FRONTEND_CFLAGS="$FRONTEND_CFLAGS -I/opt/local/include -L/opt/local/lib"
 479   ;;
 480 esac
 481
 482
 483 AC_SUBST(FRONTEND_CFLAGS)
 484 AC_SUBST(FRONTEND_LIBS)
 485 AC_SUBST(PRE_XMULIB)
 486 AC_SUBST(POST_XMULIB)
 487 AC_SUBST(CONF_CFLAGS)
 488 AC_SUBST(CONF_LDFLAGS)
 489
 490 AC_MSG_CHECKING(whether ptys or pipes should be used)
 491 AC_ARG_ENABLE( [ptys],
 492                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
 493 [if test "$enableval" = yes; then
 494   USE_PTYS=1
 495   enable_ptys="ptys"
 496   AC_MSG_RESULT([ptys (user override)])
 497 fi
 498 if test "$enableval" = no; then
 499   USE_PTYS=0
 500   enable_ptys="pipes"
 501   AC_MSG_RESULT([pipes (user override)])
 502 fi],
 503 [if test "$USE_PTYS" = 1; then
 504   AC_MSG_RESULT(ptys)
 505   enable_ptys="ptys"
 506 else
 507   AC_MSG_RESULT(pipes)
 508   enable_ptys="pipes"
 509 fi])
 510 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
 511
 512
 513 dnl | define not to build zippy as a default, so that autoheader is happy
 514 AC_ARG_ENABLE( [zippy],
 515                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
 516                [],
 517                [enable_zippy="no"])
 518
 519 if test x"$enable_zippy" != x"no"; then
 520   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
 521 else
 522   AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
 523 fi
 524 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
 525
 526
 527 AC_ARG_ENABLE(sigint,
 528 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
 529 [if test "$enableval" = yes; then
 530   AC_DEFINE(ATTENTION, 1)
 531 fi
 532 enable_sigint=$enableval
 533 ],
 534 [enable_sigint="yes"
 535 AC_DEFINE(ATTENTION, 1)])
 536
 537
 538 if test x"$with_Xaw3d" = x"yes" -o  x"$with_Xaw" = x"yes" ; then
 539 dnl | save all information for X in X_LIBS, also add the libraries themself
 540 dnl | since AC_PATH_XTRA only adds the paths
 541 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
 542 AC_SUBST(X_CFLAGS)
 543 AC_SUBST(X_LIBS)
 544 fi
 545
 546 dnl create a string with configure options that can be passed to the
 547 dnl program, good for bug reports and version printout, see output below
 548 CONFIGURE_OPTIONS="prefix=$prefix; datarootdir=$datarootdir; \
 549 datadir=$datadir; gamedatadir=$GAMEDATADIR; desktopdir=$DESKTOPDIR; \
 550 mimedir=$MIMEDIR; iconsdir=$ICONSDIR; svgiconsdir=$SVGICONSDIR; infodir=$infodir; \
 551 sysconfigdir=$sysconfigdir; update_mimedb=$enable_mimedb; NLS=$USE_NLS; \
 552 GKT=$with_GTK; Xaw3d=$with_Xaw3d; Xaw=$with_Xaw; \
 553 ptys=$enable_ptys; zippy=$enable_zippy; sigint=$enable_sigint"
 554
 555 AC_SUBST(CONFIGURE_OPTIONS)
 556
 557 dnl |  output Makefile
 558 AC_CONFIG_FILES([Makefile cmail po/Makefile.in osxapp/Info.plist])
 559 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
 560 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
 561 AC_OUTPUT
 562
 563 dnl
 564 dnl Output a summary
 565 dnl
 566 echo ""
 567 echo " Configurations summary:"
 568 echo ""
 569 echo "        prefix:          $prefix       "
 570 echo "        datarootdir:     $datarootdir  "
 571 echo "        datadir:         $datadir      "
 572 echo "        gamedatadir:     $GAMEDATADIR  "
 573 echo "        desktopdir:      $DESKTOPDIR   "
 574 echo "        mimedir:         $MIMEDIR      "
 575 echo "        iconsdir:        $ICONSDIR     "
 576 echo "        svgiconsdir:     $SVGICONSDIR  "
 577 echo "        infodir:         $infodir   (info files will go here)"
 578 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
 579 echo ""
 580 echo "        update mimedb:   $enable_mimedb"
 581 echo ""
 582 echo "        NLS support:     $USE_NLS"
 583 echo ""
 584 echo "        GTK:             $with_GTK"
 585 echo "        Xaw3d:           $with_Xaw3d"
 586 echo "        Xaw:             $with_Xaw"
 587 echo ""
 588 echo "        ptys:            $enable_ptys"
 589 echo "        zippy:           $enable_zippy"
 590 echo "        sigint:          $enable_sigint"