configure.ac

   1 dnl| configure.in
   2 dnl|
   3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 dnl| 2008, 2009, 2010, 2011, 2012, 2013, 2014 Free Software Foundation, Inc.
   5 dnl|
   6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
   7 dnl| it under the terms of the GNU General Public License as published by
   8 dnl| the Free Software Foundation, either version 3 of the License, or (at
   9 dnl| your option) any later version.
  10 dnl|
  11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
  12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 dnl| General Public License for more details.
  15 dnl|
  16 dnl| You should have received a copy of the GNU General Public License
  17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
  18 dnl|
  19 dnl| --------------------------------------------------------------------
  20 dnl|
  21 dnl| You can process this file with autoconf to produce a configure script.
  22 dnl| However, normally the supplied configure script will work fine.
  23 dnl|
  24 dnl| If you do need to change the configure script, instead of editing
  25 dnl| it directly, try to edit configure.in (in a way that will keep
  26 dnl| it portable to sites and systems other than your own), and run autoconf
  27 dnl| to regenerate configure.  Then submit your changes to be folded into
  28 dnl| the standard version of xboard.
  29
  30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
  31 AC_INIT([xboard],[4.8.0],[bug-xboard@gnu.org])
  32
  33 dnl| need this to be able to compile some files in a subdir (filebrowser)
  34 AM_INIT_AUTOMAKE([subdir-objects])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 AC_CONFIG_HEADERS([config.h])
  38
  39 dnl | a bunch of templates for defines used below
  40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
  41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
  42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
  43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
  44 AH_TEMPLATE([HAVE_RANDOM],[template])
  45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
  46 AH_TEMPLATE([IBMRTAIX],[template])
  47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
  48 AH_TEMPLATE([PTY_ITERATION],[template])
  49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
  50 AH_TEMPLATE([PTY_OPEN],[template])
  51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
  52 AH_TEMPLATE([REMOTE_SHELL],[template])
  53 AH_TEMPLATE([RTU],[template])
  54 AH_TEMPLATE([UNIPLUS],[template])
  55 AH_TEMPLATE([USE_PTYS],[template])
  56 AH_TEMPLATE([X_WCHAR],[template])
  57 AH_TEMPLATE([ATTENTION],[template])
  58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
  59 AH_TEMPLATE([USE_XAW3D],[template])
  60 AH_TEMPLATE([X_LOCALE],[template])
  61
  62
  63
  64 if test -z "$CFLAGS" ; then
  65 dnl| Prevent the next macro from setting CFLAGS to -g
  66   CFLAGS=" "
  67 fi
  68 AC_PROG_CC
  69
  70 dnl| need this to be able to compile files in a subdir
  71 AM_PROG_CC_C_O
  72
  73 AC_PROG_CPP
  74 AC_ISC_POSIX
  75 AC_PROG_INSTALL
  76
  77 dnl| add gettext support
  78 AM_GNU_GETTEXT_VERSION(0.17)
  79 AM_GNU_GETTEXT([external])
  80
  81 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
  82 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
  83 if test "$MINFO" = makeinfo_not_found ; then
  84    echo Please install \"makeinfo\"
  85    exit 1
  86 fi
  87 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
  88 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
  89 AC_SUBST(NROFFFLAGS)
  90 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
  91 AC_PATH_PROGS(PERLPATH, perl)
  92
  93 AC_HEADER_STDC
  94 AC_HEADER_TIME
  95 AC_HEADER_SYS_WAIT
  96 AC_HEADER_DIRENT
  97 AC_TYPE_SIGNAL
  98 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
  99 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
 100 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
 101 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
 102
 103 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
 104 AC_CHECK_FUNCS(gettimeofday ftime, break)
 105 AC_CHECK_FUNCS(random rand48, break)
 106 AC_CHECK_FUNCS(gethostname sysinfo, break)
 107 AC_CHECK_FUNC(setlocale, [],
 108   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
 109
 110 AC_CHECK_LIB(seq, getpseudotty)
 111
 112 dnl | add compiler warnings only if compiler understands them
 113 AC_MSG_CHECKING(whether compiler understands -Wall -Wno-parentheses)
 114 SAVE_CFLAGS="$CFLAGS"
 115 CFLAGS="$CFLAGS -Wall -Wno-parentheses"
 116 AC_TRY_COMPILE([],[],
 117   AC_MSG_RESULT(yes),
 118   AC_MSG_RESULT(no)
 119   CFLAGS="$SAVE_CFLAGS")
 120
 121 dnl | check for pkg-config
 122 AC_CHECK_PROGS([PKGCONFIG], [pkg-config], pkgconfig_not_found)
 123 AS_IF( [test "x$PKGCONFIG" = xpkgconfig_not_found],
 124        AC_MSG_ERROR([cannot find pkg-config! Please install it.]))
 125
 126 dnl | check for cairo and librsvg
 127 PKG_CHECK_MODULES([CAIRO], [ cairo >= 1.2.0 librsvg-2.0 >= 2.14.0 ])
 128 AC_SUBST(CAIRO_CFLAGS)
 129 AC_SUBST(CAIRO_LIBS)
 130
 131 dnl | check which front end to use
 132 dnl | first check for gtk
 133 dnl | then for Xaw3d
 134 dnl | and then for Xaw
 135 FRONTEND_CFLAGS=""
 136 FRONTEND_LIBS=""
 137
 138 AC_ARG_WITH([gtk],
 139             [AS_HELP_STRING([--with-gtk],[use GTK front-end])],
 140             [with_GTK=$withval],
 141             [with_GTK="no"])
 142
 143 AC_ARG_WITH([Xaw3d],
 144             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d front-end (not fully supported anymore)])],
 145             [with_Xaw3d="$withval"],
 146             [with_Xaw3d="no"])
 147
 148 AC_ARG_WITH([Xaw],
 149             [AS_HELP_STRING([--with-Xaw],[use Xaw front-end (default)])],
 150             [with_Xaw="$withval"],
 151             [with_Xaw="yes"])
 152
 153 AC_ARG_WITH([iconsdir],
 154             [AS_HELP_STRING([--with-iconsdir=DIR],
 155             [path where icons get installed (default: $datadir/icons/hicolor/48x48/apps)])],
 156             [ICONSDIR="$withval"],
 157             [ICONSDIR='$(datadir)/icons/hicolor/48x48/apps'])
 158
 159 AC_ARG_WITH([svgiconsdir],
 160             [AS_HELP_STRING([--with-svgiconsdir=DIR],
 161             [path where svg icons get installed (default: $datadir/icons/hicolor/scalable/apps)])],
 162             [SVGICONSDIR="$withval"],
 163             [SVGICONSDIR='$(datadir)/icons/hicolor/scalable/apps'])
 164
 165 AC_ARG_WITH([desktopdir],
 166             [AS_HELP_STRING([--with-desktopdir=DIR],
 167                             [path where desktop files get installed (default: $datadir/applications)])],
 168             [DESKTOPDIR="$withval"],
 169             [DESKTOPDIR='$(datadir)/applications'])
 170
 171 AC_ARG_WITH([mimedir],
 172             [AS_HELP_STRING([--with-mimedir=DIR],
 173                             [path where mime files get installed (default: $datadir/mime/packages)])],
 174             [MIMEDIR="$withval"],
 175             [MIMEDIR='$(datadir)/mime/packages'])
 176
 177 AC_ARG_WITH([gamedatadir],
 178             [AS_HELP_STRING([--with-gamedatadir=DIR],
 179                             [path where game data files get installed (default: $datadir/games/xboard)])],
 180             [GAMEDATADIR="$withval"],
 181             [GAMEDATADIR='$(datadir)/games/xboard'])
 182
 183 AC_ARG_ENABLE([update-mimedb],
 184               [AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]])],
 185               [enable_mimedb="no"],
 186               [enable_mimedb="yes"])
 187
 188 AC_ARG_ENABLE([osxapp],
 189               [AS_HELP_STRING([--enable-osxapp],[build a OSX app [default=no]])],
 190               [enable_OSXAPP=$enableval],
 191               [enable_OSXAPP="no"])
 192
 193 AS_IF([test x"$enable_OSXAPP" = x"yes"], [
 194      AC_PREFIX_DEFAULT([`pwd`/XBoard.app/Contents])
 195      AC_DEFINE([OSXAPP], [1], [We are building an OSX APP, redefine some functions])],
 196      with_GTK="yes"
 197      enable_mimedb="no"
 198      datarootdir='$(prefix)/Resources'
 199      datadir='$(datarootdir)/share'
 200      sysconfdir='$(datarootdir)/etc'
 201      infodir='$(datadir)/info'
 202      mandir='$(datadir)/man'
 203      bindir='$(prefix)/MacOS'
 204      localedir='$(datadir)/locale'
 205      GAMEDATADIR='$(datadir)/xboard'
 206 ])
 207
 208 AM_CONDITIONAL(OSX_APP, test x"$enable_OSXAPP" = x"yes")
 209
 210 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x"$enable_mimedb" = x"yes")
 211 if test x"$enable_mimedb" = x"yes"; then
 212    AC_PATH_PROG([XDG_MIME],[xdg-mime])
 213    AC_SUBST(XDG_MIME)
 214    AC_PATH_PROG([XDG_DESKTOP_MENU],[xdg-desktop-menu])
 215    AC_SUBST(XDG_DESKTOP_MENU)
 216    AC_PATH_PROG([XDG_ICON_RESOURCE],[xdg-icon-resource])
 217    AC_SUBST(XDG_ICON_RESOURCE)
 218 fi
 219
 220 AC_SUBST(ICONSDIR)
 221 AC_SUBST(SVGICONSDIR)
 222 AC_SUBST(DESKTOPDIR)
 223 AC_SUBST(MIMEDIR)
 224 AC_SUBST(GAMEDATADIR)
 225
 226 dnl | check for libraries
 227 if test x"$with_GTK" = x"yes" ; then
 228   PKG_CHECK_MODULES([GTK], [ gtk+-2.0 >= 2.16.0 gmodule-2.0 ])
 229   FRONTEND_CFLAGS=$GTK_CFLAGS
 230   FRONTEND_LIBS=$GTK_LIBS
 231   with_Xaw="no"
 232 fi
 233
 234 if test x"$with_GTK" = x"no" ; then
 235
 236 dnl | general check for Xaw and Xaw3d
 237   AC_PATH_XTRA
 238   if test -n "$no_x" ; then
 239     AC_MSG_ERROR([ "    $PACKAGE requires the X Window System header files and libraries!
 240     They were not found on your system.  See FAQ topic C.2.
 241     configure failed"])
 242   fi
 243
 244   save_cflags="$CFLAGS"
 245   save_cppflags="$CPPFLAGS"
 246   CFLAGS="$CFLAGS $X_CFLAGS"
 247   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 248   AC_CHECK_HEADER([X11/Intrinsic.h],[xt="yes"],[xt="no"])
 249   CFLAGS="$save_cflags"
 250   CPPFLAGS="$save_cppflags"
 251
 252   if test "$xt" = "no" ; then
 253      AC_MSG_ERROR([Xt headers not found. Please install the X11 packages.])
 254   fi
 255
 256 dnl | check availability of Xaw3d
 257   FRONTEND_LIBS=
 258   AS_IF([test x"$with_Xaw3d" != x"no"],
 259             [AC_CHECK_LIB([Xaw3d],
 260                     [XawTextReplace],
 261                     [ FRONTEND_LIBS="-lXaw3d"
 262                       AC_DEFINE([USE_XAW3D], [1], [Define if you want to use Xaw3d])],
 263                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
 264                                [-lXaw])])
 265
 266 dnl | no Xaw3d, check for Xaw; make it the default
 267   if test x"$with_Xaw3d" = x"no" ; then
 268      with_Xaw=yes
 269      save_cflags="$CFLAGS"
 270      save_cppflags="$CPPFLAGS"
 271      CFLAGS="$CFLAGS $X_CFLAGS"
 272      CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 273      AC_CHECK_HEADER([X11/Xaw/Dialog.h],[xaw_headers="yes"], [xaw_headers="no"])
 274      CFLAGS="$save_cflags"
 275      CPPFLAGS="$save_cppflags"
 276
 277      if test x"$xaw_headers" = x"no" ; then
 278         AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
 279      fi
 280
 281      FRONTEND_LIBS="-lXaw"
 282   fi
 283
 284 fi
 285
 286 dnl | make results available in Makefile.am
 287 AM_CONDITIONAL([withGTK],   [test x"$with_GTK" = x"yes"])
 288 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw3d" = x"yes" || test x"$with_Xaw" = x"yes"])
 289
 290 dnl | end Front-end check
 291
 292 AC_CANONICAL_HOST
 293
 294 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
 295 dnl| we are trying to find out whether this is a System-V derivative in
 296 dnl| which pipes don't work with select() and if so, whether there is anything
 297 dnl| strange about the way to open a pty.  Some of the work was done above
 298 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
 299 dnl| properties of particular systems are also handled here.
 300
 301 dnl| 4/6/97 I'm not sure there really are any systems where pipes
 302 dnl| don't work with select(), and ptys cause problems on many
 303 dnl| systems, so I'm changing the default to disable ptys in all
 304 dnl| cases.  I will change it back if I get bug reports that are fixed
 305 dnl| by doing a "configure --enable-ptys"
 306
 307 USE_PTYS=0
 308 case "$host" in
 309   *-*-hpux* )
 310     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 311         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
 312     AC_DEFINE(PTY_NAME_SPRINTF,
 313         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
 314 dnl| USE_PTYS=1
 315     if test "$GCC" = yes; then
 316       CONF_CFLAGS="-fwritable-strings"
 317     else
 318
 319 dnl| Note: You might be able to build xboard even if your compiler does not
 320 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
 321 dnl| know whether the X header files on HP-UX require it.
 322
 323       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
 324     fi
 325
 326 dnl| HP doesn't supply a full set of X header files and libraries.  People
 327 dnl| often have some things installed in one place and some in another.
 328 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
 329 dnl| likely ones that might be missing here.  It might be better to
 330 dnl| change AC_PATH_XTRA to try to extract this information from imake,
 331 dnl| since folks who install the missing bits often configure their
 332 dnl| imake to find them, but I don't want to delve into autoconf and
 333 dnl| hack on its internals.
 334
 335     if test -d /opt/hppd/include/X11; then
 336       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
 337       X_LIBS="$X_LIBS -L/opt/hppd/lib"
 338     elif test -d /usr/contrib/X11R5/include; then
 339       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
 340       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
 341     elif test -d /usr/contrib/mitX11R5/include; then
 342       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
 343       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
 344     elif test -d /MIT/X11R5/include; then
 345       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
 346       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
 347     elif test -d /usr/local/include/X11R5; then
 348       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
 349       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
 350     fi
 351     if test -d /usr/include/X11R5; then
 352       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
 353       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
 354     elif test -d /usr/include/X11R4; then
 355       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
 356       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
 357     fi
 358   ;;
 359
 360   romp-ibm-aix* )
 361     AC_DEFINE(IBMRTAIX, 1)
 362 dnl| USE_PTYS=1
 363   ;;
 364
 365   i386-ibm-aix )
 366 dnl| USE_PTYS=1
 367     if test "$GCC" = yes; then
 368       CONF_CFLAGS="-fwritable-strings"
 369     fi
 370   ;;
 371
 372   *-*-aix3* | *-*-bosx* )
 373     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 374     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 375     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
 376 dnl| USE_PTYS=1
 377   ;;
 378
 379   *-*-cxux* )
 380     AC_DEFINE(FIRST_PTY_LETTER, 'A')
 381     AC_DEFINE(LAST_PTY_LETTER, 'P')
 382 dnl| USE_PTYS=1
 383   ;;
 384
 385   *-*-uniplus* )
 386     AC_DEFINE(UNIPLUS, 1)
 387 dnl| USE_PTYS=1
 388   ;;
 389
 390   *-*-rtu* )
 391     AC_DEFINE(FIRST_PTY_LETTER, 'z')
 392     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 393         [sprintf (pty_name, "/dev/ttyp%x", i);])
 394     AC_DEFINE(PTY_NAME_SPRINTF,
 395         [sprintf (pty_name, "/dev/pty%x", i);])
 396     AC_DEFINE(RTU, 1)
 397 dnl| USE_PTYS=1
 398   ;;
 399
 400   *-*-iris* | *-*-irix3* )
 401     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 402     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 403     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 404         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
 405 dnl| USE_PTYS=1
 406   ;;
 407
 408   *-*-irix* )
 409 dnl| USE_PTYS=1
 410   ;;
 411
 412   *-*-sunos4* | *-*-solaris1* )
 413
 414 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
 415 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
 416 dnl|  "overkill," but doesn't explain what should be done instead.
 417
 418     if test "$GCC" = yes; then
 419       PRE_XMULIB="-static"
 420       POST_XMULIB="-dynamic"
 421     else
 422       PRE_XMULIB="-Bstatic"
 423       POST_XMULIB="-Bdynamic"
 424     fi
 425   ;;
 426
 427   *-*-sunos5* | *-*-solaris2* )
 428 dnl| USE_PTYS=1
 429
 430 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
 431 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
 432 dnl| code above.
 433
 434     X_LIBS="$X_LIBS -lelf"
 435   ;;
 436
 437   *-*-sco* )
 438     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
 439     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
 440     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
 441 dnl| USE_PTYS=1
 442   ;;
 443
 444   *-*-dynix* | *-*-ptx* )
 445 dnl| USE_PTYS=1
 446   ;;
 447
 448   *-*-esix* )
 449 dnl| USE_PTYS=1
 450   ;;
 451
 452   *-*-usg5-4* | *-*-sysvr4* )
 453 dnl| USE_PTYS=1
 454   ;;
 455
 456   *-*-usg* | *-*-sysv* | *-*-aix* )
 457 dnl| USE_PTYS=1
 458   ;;
 459
 460   vax-*-ultrix )
 461     if test "$GCC" = yes; then
 462       CONF_CFLAGS="-fwritable-strings"
 463     fi
 464   ;;
 465
 466 dnl| add some libs for OS X
 467   *-apple-* )
 468     AC_MSG_WARN([Apple support is experimental, please report any problems to bug-xboard@gnu.org])
 469     AC_MSG_WARN([use --enable-osxapp to enable the build target and automatically adjust target directories])
 470     AC_MSG_WARN([Building an OSX app currently relies on some programs such as dylib that we don't test for])
 471     AC_MSG_WARN([patches welcome ;)])
 472     AC_PATH_PROG(SW_VERS, sw_vers)
 473     if test "x$SW_VERS" != "x"; then
 474       AC_MSG_CHECKING(Mac OS X version)
 475       MACOSX_VERSION=`$SW_VERS -productVersion`
 476       AC_MSG_RESULT([$MACOSX_VERSION])
 477     fi
 478     FRONTEND_LIBS="$FRONTEND_LIBS -lgtkmacintegration -headerpad_max_install_names "
 479     FRONTEND_CFLAGS="$FRONTEND_CFLAGS -I/opt/local/include -L/opt/local/lib"
 480   ;;
 481 esac
 482
 483
 484 AC_SUBST(FRONTEND_CFLAGS)
 485 AC_SUBST(FRONTEND_LIBS)
 486 AC_SUBST(PRE_XMULIB)
 487 AC_SUBST(POST_XMULIB)
 488 AC_SUBST(CONF_CFLAGS)
 489 AC_SUBST(CONF_LDFLAGS)
 490
 491 AC_MSG_CHECKING(whether ptys or pipes should be used)
 492 AC_ARG_ENABLE( [ptys],
 493                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
 494 [if test "$enableval" = yes; then
 495   USE_PTYS=1
 496   enable_ptys="ptys"
 497   AC_MSG_RESULT([ptys (user override)])
 498 fi
 499 if test "$enableval" = no; then
 500   USE_PTYS=0
 501   enable_ptys="pipes"
 502   AC_MSG_RESULT([pipes (user override)])
 503 fi],
 504 [if test "$USE_PTYS" = 1; then
 505   AC_MSG_RESULT(ptys)
 506   enable_ptys="ptys"
 507 else
 508   AC_MSG_RESULT(pipes)
 509   enable_ptys="pipes"
 510 fi])
 511 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
 512
 513
 514 dnl | define not to build zippy as a default, so that autoheader is happy
 515 AC_ARG_ENABLE( [zippy],
 516                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
 517                [],
 518                [enable_zippy="no"])
 519
 520 if test x"$enable_zippy" != x"no"; then
 521   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
 522 else
 523   AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
 524 fi
 525 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
 526
 527
 528 AC_ARG_ENABLE(sigint,
 529 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
 530 [if test "$enableval" = yes; then
 531   AC_DEFINE(ATTENTION, 1)
 532 fi
 533 enable_sigint=$enableval
 534 ],
 535 [enable_sigint="yes"
 536 AC_DEFINE(ATTENTION, 1)])
 537
 538
 539 if test x"$with_Xaw3d" = x"yes" -o  x"$with_Xaw" = x"yes" ; then
 540 dnl | save all information for X in X_LIBS, also add the libraries themself
 541 dnl | since AC_PATH_XTRA only adds the paths
 542 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
 543 AC_SUBST(X_CFLAGS)
 544 AC_SUBST(X_LIBS)
 545 fi
 546
 547 dnl create a string with configure options that can be passed to the
 548 dnl program, good for bug reports and version printout, see output below
 549 CONFIGURE_OPTIONS="prefix=$prefix; datarootdir=$datarootdir; \
 550 datadir=$datadir; gamedatadir=$GAMEDATADIR; desktopdir=$DESKTOPDIR; \
 551 mimedir=$MIMEDIR; iconsdir=$ICONSDIR; svgiconsdir=$SVGICONSDIR; infodir=$infodir; \
 552 sysconfigdir=$sysconfigdir; update_mimedb=$enable_mimedb; NLS=$USE_NLS; \
 553 GKT=$with_GTK; Xaw3d=$with_Xaw3d; Xaw=$with_Xaw; \
 554 ptys=$enable_ptys; zippy=$enable_zippy; sigint=$enable_sigint"
 555
 556 AC_SUBST(CONFIGURE_OPTIONS)
 557
 558 dnl |  output Makefile
 559 AC_CONFIG_FILES([Makefile cmail po/Makefile.in osxapp/Info.plist])
 560 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
 561 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
 562 AC_OUTPUT
 563
 564 dnl
 565 dnl Output a summary
 566 dnl
 567 echo ""
 568 echo " Configurations summary:"
 569 echo ""
 570 echo "        prefix:          $prefix       "
 571 echo "        datarootdir:     $datarootdir  "
 572 echo "        datadir:         $datadir      "
 573 echo "        gamedatadir:     $GAMEDATADIR  "
 574 echo "        desktopdir:      $DESKTOPDIR   "
 575 echo "        mimedir:         $MIMEDIR      "
 576 echo "        iconsdir:        $ICONSDIR     "
 577 echo "        svgiconsdir:     $SVGICONSDIR  "
 578 echo "        infodir:         $infodir   (info files will go here)"
 579 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
 580 echo ""
 581 echo "        update mimedb:   $enable_mimedb"
 582 echo ""
 583 echo "        NLS support:     $USE_NLS"
 584 echo ""
 585 echo "        GTK:             $with_GTK"
 586 echo "        Xaw3d:           $with_Xaw3d"
 587 echo "        Xaw:             $with_Xaw"
 588 echo ""
 589 echo "        ptys:            $enable_ptys"
 590 echo "        zippy:           $enable_zippy"
 591 echo "        sigint:          $enable_sigint"