configure.ac

   1 dnl| configure.in
   2 dnl|
   3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 dnl| 2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
   5 dnl|
   6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
   7 dnl| it under the terms of the GNU General Public License as published by
   8 dnl| the Free Software Foundation, either version 3 of the License, or (at
   9 dnl| your option) any later version.
  10 dnl|
  11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
  12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 dnl| General Public License for more details.
  15 dnl|
  16 dnl| You should have received a copy of the GNU General Public License
  17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
  18 dnl|
  19 dnl| --------------------------------------------------------------------
  20 dnl|
  21 dnl| You can process this file with autoconf to produce a configure script.
  22 dnl| However, normally the supplied configure script will work fine.
  23 dnl|
  24 dnl| If you do need to change the configure script, instead of editing
  25 dnl| it directly, try to edit configure.in (in a way that will keep
  26 dnl| it portable to sites and systems other than your own), and run autoconf
  27 dnl| to regenerate configure.  Then submit your changes to be folded into
  28 dnl| the standard version of xboard.
  29
  30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
  31 AC_INIT([xboard],[master-20120430],[bug-xboard@gnu.org])
  32
  33 dnl| need this to be able to compile some files in a subdir (filebrowser)
  34 AM_INIT_AUTOMAKE([subdir-objects])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 AC_CONFIG_HEADERS([config.h])
  38
  39 dnl | a bunch of templates for defines used below
  40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
  41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
  42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
  43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
  44 AH_TEMPLATE([HAVE_RANDOM],[template])
  45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
  46 AH_TEMPLATE([IBMRTAIX],[template])
  47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
  48 AH_TEMPLATE([PTY_ITERATION],[template])
  49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
  50 AH_TEMPLATE([PTY_OPEN],[template])
  51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
  52 AH_TEMPLATE([REMOTE_SHELL],[template])
  53 AH_TEMPLATE([RTU],[template])
  54 AH_TEMPLATE([UNIPLUS],[template])
  55 AH_TEMPLATE([USE_PTYS],[template])
  56 AH_TEMPLATE([X_WCHAR],[template])
  57 AH_TEMPLATE([ATTENTION],[template])
  58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
  59 AH_TEMPLATE([HAVE_LIBXPM],[template])
  60 AH_TEMPLATE([USE_XAW3D],[template])
  61 AH_TEMPLATE([X_LOCALE],[template])
  62
  63
  64
  65 if test -z "$CFLAGS" ; then
  66 dnl| Prevent the next macro from setting CFLAGS to -g
  67   CFLAGS=" "
  68 fi
  69 AC_PROG_CC
  70
  71 dnl| need this to be able to compile files in a subdir
  72 AM_PROG_CC_C_O
  73
  74 AC_PROG_CPP
  75 AC_ISC_POSIX
  76 AC_PROG_INSTALL
  77
  78 dnl| add gettext support
  79 AM_GNU_GETTEXT_VERSION(0.17)
  80 AM_GNU_GETTEXT([external])
  81
  82 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
  83 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
  84 if test "$MINFO" = makeinfo_not_found ; then
  85    echo Please install \"makeinfo\"
  86    exit 1
  87 fi
  88 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
  89 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
  90 AC_SUBST(NROFFFLAGS)
  91 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
  92 AC_PATH_PROGS(PERLPATH, perl)
  93
  94 AC_HEADER_STDC
  95 AC_HEADER_TIME
  96 AC_HEADER_SYS_WAIT
  97 AC_HEADER_DIRENT
  98 AC_TYPE_SIGNAL
  99 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
 100 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
 101 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
 102 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
 103
 104 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
 105 AC_CHECK_FUNCS(gettimeofday ftime, break)
 106 AC_CHECK_FUNCS(random rand48, break)
 107 AC_CHECK_FUNCS(gethostname sysinfo, break)
 108 AC_CHECK_FUNC(setlocale, [],
 109   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
 110
 111 AC_CHECK_LIB(seq, getpseudotty)
 112
 113 dnl | add compiler warnings only if compiler understands them
 114 AC_MSG_CHECKING(whether compiler understands -Wall -Wno-parentheses)
 115 SAVE_CFLAGS="$CFLAGS"
 116 CFLAGS="$CFLAGS -Wall -Wno-parentheses"
 117 AC_TRY_COMPILE([],[],
 118   AC_MSG_RESULT(yes),
 119   AC_MSG_RESULT(no)
 120   CFLAGS="$SAVE_CFLAGS")
 121
 122
 123 dnl | check for X-libraries
 124 AC_PATH_XTRA
 125 if test -n "$no_x" ; then
 126   echo $PACKAGE requires the X Window System header files and libraries!
 127   echo They were not found on your system.  See FAQ topic C.2.
 128   echo configure failed
 129   exit 1
 130 fi
 131
 132 AC_CHECK_HEADER(X11/Intrinsic.h,xt="yes",xt="no")
 133
 134 if test "$xt" = "no" ; then
 135    echo Xt headers not found
 136    exit 1
 137 fi
 138
 139 dnl | test if user wants ot use Xaw3d or Xaw
 140
 141 dnl | add configure option for Xaw3d
 142 AC_ARG_WITH([Xaw3d],
 143             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d instead of Xaw])],
 144             [],
 145             [with_Xaw3d=no])
 146
 147 dnl | check availability of Xaw3d
 148 XAW_LIBS=
 149 AS_IF([test x"$with_Xaw3d" != x"no"],
 150       [AC_CHECK_LIB([Xaw3d],
 151                     [XawTextReplace],
 152                     [AC_SUBST([XAW_LIBS],["-lXaw3d"])
 153                      AC_DEFINE([USE_XAW3D], [1],
 154                                [Define if you want to use Xaw3d])],
 155                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
 156                                [-lXaw])])
 157 dnl | no Xaw3d, check for Xaw
 158 if test x"$with_Xaw3d" = x"no" ; then
 159    AC_CHECK_HEADER(X11/Xaw/Dialog.h,xaw_headers="yes", xaw_headers="no")
 160    if test x"$xaw_headers" = x"no" ; then
 161       AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
 162    fi
 163    XAW_LIBS="-lXaw"
 164 fi
 165 AC_SUBST(XAW_LIBS)
 166
 167 dnl | end Xaw/Xaw3d test
 168
 169
 170 AC_CANONICAL_HOST
 171
 172 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
 173 dnl| we are trying to find out whether this is a System-V derivative in
 174 dnl| which pipes don't work with select() and if so, whether there is anything
 175 dnl| strange about the way to open a pty.  Some of the work was done above
 176 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
 177 dnl| properties of particular systems are also handled here.
 178
 179 dnl| 4/6/97 I'm not sure there really are any systems where pipes
 180 dnl| don't work with select(), and ptys cause problems on many
 181 dnl| systems, so I'm changing the default to disable ptys in all
 182 dnl| cases.  I will change it back if I get bug reports that are fixed
 183 dnl| by doing a "configure --enable-ptys"
 184
 185 USE_PTYS=0
 186 case "$host" in
 187   *-*-hpux* )
 188     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 189         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
 190     AC_DEFINE(PTY_NAME_SPRINTF,
 191         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
 192 dnl| USE_PTYS=1
 193     if test "$GCC" = yes; then
 194       CONF_CFLAGS="-fwritable-strings"
 195     else
 196
 197 dnl| Note: You might be able to build xboard even if your compiler does not
 198 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
 199 dnl| know whether the X header files on HP-UX require it.
 200
 201       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
 202     fi
 203
 204 dnl| HP doesn't supply a full set of X header files and libraries.  People
 205 dnl| often have some things installed in one place and some in another.
 206 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
 207 dnl| likely ones that might be missing here.  It might be better to
 208 dnl| change AC_PATH_XTRA to try to extract this information from imake,
 209 dnl| since folks who install the missing bits often configure their
 210 dnl| imake to find them, but I don't want to delve into autoconf and
 211 dnl| hack on its internals.
 212
 213     if test -d /opt/hppd/include/X11; then
 214       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
 215       X_LIBS="$X_LIBS -L/opt/hppd/lib"
 216     elif test -d /usr/contrib/X11R5/include; then
 217       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
 218       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
 219     elif test -d /usr/contrib/mitX11R5/include; then
 220       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
 221       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
 222     elif test -d /MIT/X11R5/include; then
 223       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
 224       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
 225     elif test -d /usr/local/include/X11R5; then
 226       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
 227       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
 228     fi
 229     if test -d /usr/include/X11R5; then
 230       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
 231       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
 232     elif test -d /usr/include/X11R4; then
 233       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
 234       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
 235     fi
 236   ;;
 237
 238   romp-ibm-aix* )
 239     AC_DEFINE(IBMRTAIX, 1)
 240 dnl| USE_PTYS=1
 241   ;;
 242
 243   i386-ibm-aix )
 244 dnl| USE_PTYS=1
 245     if test "$GCC" = yes; then
 246       CONF_CFLAGS="-fwritable-strings"
 247     fi
 248   ;;
 249
 250   *-*-aix3* | *-*-bosx* )
 251     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 252     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 253     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
 254 dnl| USE_PTYS=1
 255   ;;
 256
 257   *-*-cxux* )
 258     AC_DEFINE(FIRST_PTY_LETTER, 'A')
 259     AC_DEFINE(LAST_PTY_LETTER, 'P')
 260 dnl| USE_PTYS=1
 261   ;;
 262
 263   *-*-uniplus* )
 264     AC_DEFINE(UNIPLUS, 1)
 265 dnl| USE_PTYS=1
 266   ;;
 267
 268   *-*-rtu* )
 269     AC_DEFINE(FIRST_PTY_LETTER, 'z')
 270     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 271         [sprintf (pty_name, "/dev/ttyp%x", i);])
 272     AC_DEFINE(PTY_NAME_SPRINTF,
 273         [sprintf (pty_name, "/dev/pty%x", i);])
 274     AC_DEFINE(RTU, 1)
 275 dnl| USE_PTYS=1
 276   ;;
 277
 278   *-*-iris* | *-*-irix3* )
 279     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 280     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 281     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 282         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
 283 dnl| USE_PTYS=1
 284   ;;
 285
 286   *-*-irix* )
 287 dnl| USE_PTYS=1
 288   ;;
 289
 290   *-*-sunos4* | *-*-solaris1* )
 291
 292 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
 293 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
 294 dnl|  "overkill," but doesn't explain what should be done instead.
 295
 296     if test "$GCC" = yes; then
 297       PRE_XMULIB="-static"
 298       POST_XMULIB="-dynamic"
 299     else
 300       PRE_XMULIB="-Bstatic"
 301       POST_XMULIB="-Bdynamic"
 302     fi
 303   ;;
 304
 305   *-*-sunos5* | *-*-solaris2* )
 306 dnl| USE_PTYS=1
 307
 308 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
 309 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
 310 dnl| code above.
 311
 312     X_LIBS="$X_LIBS -lelf"
 313   ;;
 314
 315   *-*-sco* )
 316     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
 317     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
 318     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
 319 dnl| USE_PTYS=1
 320   ;;
 321
 322   *-*-dynix* | *-*-ptx* )
 323 dnl| USE_PTYS=1
 324   ;;
 325
 326   *-*-esix* )
 327 dnl| USE_PTYS=1
 328   ;;
 329
 330   *-*-usg5-4* | *-*-sysvr4* )
 331 dnl| USE_PTYS=1
 332   ;;
 333
 334   *-*-usg* | *-*-sysv* | *-*-aix* )
 335 dnl| USE_PTYS=1
 336   ;;
 337
 338   vax-*-ultrix )
 339     if test "$GCC" = yes; then
 340       CONF_CFLAGS="-fwritable-strings"
 341     fi
 342   ;;
 343
 344 dnl| add some libs for OS X
 345   *-apple-* )
 346   ;;
 347 esac
 348
 349 AC_ARG_ENABLE(  [xpm],
 350                 [AS_HELP_STRING([--enable-xpm],[libXpm will be used if found (default)])],
 351                 [enable_xpm="$enableval"],
 352                 [enable_xpm="yes"])
 353
 354 if test x"$enable_xpm" != "xno"; then
 355   save_cflags="$CFLAGS"
 356   CFLAGS="$CFLAGS $X_CFLAGS"
 357   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 358   AC_CHECK_HEADERS(X11/xpm.h)
 359   CFLAGS="$save_cflags"
 360   if test "$ac_cv_header_X11_xpm_h" = "yes"; then
 361     save_ldflags="$LDFLAGS"
 362     LDFLAGS="$LDFLAGS $X_LIBS"
 363     AC_CHECK_LIB(Xpm, XpmReadFileToPixmap,
 364                  [X_PRE_LIBS="-lXpm $X_PRE_LIBS"; AC_DEFINE(HAVE_LIBXPM)], [],
 365                  [$X_PRE_LIBS -lX11 $X_EXTRA_LIBS])
 366     LDFLAGS="$save_ldflags"
 367   fi
 368 fi
 369
 370 AC_SUBST(PRE_XMULIB)
 371 AC_SUBST(POST_XMULIB)
 372 AC_SUBST(CONF_CFLAGS)
 373 AC_SUBST(CONF_LDFLAGS)
 374
 375 AC_MSG_CHECKING(whether ptys or pipes should be used)
 376 AC_ARG_ENABLE( [ptys],
 377                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
 378 [if test "$enableval" = yes; then
 379   USE_PTYS=1
 380   enable_ptys="ptys"
 381   AC_MSG_RESULT([ptys (user override)])
 382 fi
 383 if test "$enableval" = no; then
 384   USE_PTYS=0
 385   enable_ptys="pipes"
 386   AC_MSG_RESULT([pipes (user override)])
 387 fi],
 388 [if test "$USE_PTYS" = 1; then
 389   AC_MSG_RESULT(ptys)
 390   enable_ptys="ptys"
 391 else
 392   AC_MSG_RESULT(pipes)
 393   enable_ptys="pipes"
 394 fi])
 395 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
 396
 397
 398 dnl | define not to build zippy as a default, so that autoheader is happy
 399 AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
 400 AC_ARG_ENABLE( [zippy],
 401                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
 402                [],
 403                [enable_zippy="yes"])
 404
 405 if test x"$enable_zippy" != xno; then
 406   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
 407 fi
 408 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
 409
 410
 411 AC_ARG_ENABLE(sigint,
 412 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
 413 [if test "$enableval" = yes; then
 414   AC_DEFINE(ATTENTION, 1)
 415 fi
 416 enable_sigint=$enableval
 417 ],
 418 [enable_sigint="yes"
 419 AC_DEFINE(ATTENTION, 1)])
 420
 421
 422 dnl | save all information for X in X_LIBS, also add the libraries themself
 423 dnl | since AC_PATH_XTRA only adds the paths
 424 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
 425 AC_SUBST(X_CFLAGS)
 426 AC_SUBST(X_LIBS)
 427
 428 dnl | should we install desktop icons and mime associations?
 429 AC_ARG_ENABLE(  [update-mimedb],
 430                 [AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]])],
 431                 [enable_mimedb="no"],
 432                 [enable_mimedb="yes"])
 433
 434 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x"$enable_mimedb" = "xyes")
 435
 436 if test x"$enable_mimedb" = "xyes"; then
 437    AC_PATH_PROG([XDG_MIME],[xdg-mime])
 438    AC_SUBST(XDG_MIME)
 439    AC_PATH_PROG([XDG_DESKTOP_MENU],[xdg-desktop-menu])
 440    AC_SUBST(XDG_DESKTOP_MENU)
 441    AC_PATH_PROG([XDG_ICON_RESOURCE],[xdg-icon-resource])
 442    AC_SUBST(XDG_ICON_RESOURCE)
 443 fi
 444
 445 dnl |  output Makefile
 446 AC_CONFIG_FILES([Makefile cmail po/Makefile.in])
 447 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
 448 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
 449 AC_OUTPUT
 450
 451 dnl
 452 dnl Output a summary
 453 dnl
 454 echo ""
 455 echo " Configurations summary:"
 456 echo ""
 457 echo "        prefix:          $prefix       "
 458 echo "        datarootdir:     $datarootdir  "
 459 echo "        datadir:         $datadir   (icons will go in \$datadir/icons/hicolor/...)"
 460 echo "                                    (bitmaps will go in \$datadir/games/xboard/...)"
 461 echo "        infodir:         $infodir   (info files will go here)"
 462 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
 463 echo ""
 464 echo "        update mimedb:   $enable_mimedb"
 465 echo ""
 466 echo "        NLS support:     $USE_NLS"
 467 echo ""
 468 echo "        Xaw3d:           $with_Xaw3d"
 469 echo ""
 470 echo "        xpm:             $enable_xpm"
 471 echo "        ptys:            $enable_ptys"
 472 echo "        zippy:           $enable_zippy"
 473 echo "        sigint:          $enable_sigint"