configure.ac

   1 dnl| configure.in
   2 dnl|
   3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 dnl| 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Free Software Foundation, Inc.
   5 dnl|
   6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
   7 dnl| it under the terms of the GNU General Public License as published by
   8 dnl| the Free Software Foundation, either version 3 of the License, or (at
   9 dnl| your option) any later version.
  10 dnl|
  11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
  12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 dnl| General Public License for more details.
  15 dnl|
  16 dnl| You should have received a copy of the GNU General Public License
  17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
  18 dnl|
  19 dnl| --------------------------------------------------------------------
  20 dnl|
  21 dnl| You can process this file with autoconf to produce a configure script.
  22 dnl| However, normally the supplied configure script will work fine.
  23 dnl|
  24 dnl| If you do need to change the configure script, instead of editing
  25 dnl| it directly, try to edit configure.in (in a way that will keep
  26 dnl| it portable to sites and systems other than your own), and run autoconf
  27 dnl| to regenerate configure.  Then submit your changes to be folded into
  28 dnl| the standard version of xboard.
  29
  30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
  31 AC_INIT([xboard],[4.8.0],[bug-xboard@gnu.org])
  32
  33 dnl| need this to be able to compile some files in a subdir (filebrowser)
  34 AM_INIT_AUTOMAKE([subdir-objects])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 AC_CONFIG_HEADERS([config.h])
  38
  39 dnl | a bunch of templates for defines used below
  40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
  41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
  42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
  43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
  44 AH_TEMPLATE([HAVE_RANDOM],[template])
  45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
  46 AH_TEMPLATE([IBMRTAIX],[template])
  47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
  48 AH_TEMPLATE([PTY_ITERATION],[template])
  49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
  50 AH_TEMPLATE([PTY_OPEN],[template])
  51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
  52 AH_TEMPLATE([REMOTE_SHELL],[template])
  53 AH_TEMPLATE([RTU],[template])
  54 AH_TEMPLATE([UNIPLUS],[template])
  55 AH_TEMPLATE([USE_PTYS],[template])
  56 AH_TEMPLATE([X_WCHAR],[template])
  57 AH_TEMPLATE([ATTENTION],[template])
  58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
  59 AH_TEMPLATE([USE_XAW3D],[template])
  60 AH_TEMPLATE([X_LOCALE],[template])
  61
  62
  63
  64 if test -z "$CFLAGS" ; then
  65 dnl| Prevent the next macro from setting CFLAGS to -g
  66   CFLAGS=" "
  67 fi
  68 AC_PROG_CC
  69
  70 dnl| need this to be able to compile files in a subdir
  71 AM_PROG_CC_C_O
  72
  73 AC_PROG_CPP
  74 AC_ISC_POSIX
  75 AC_PROG_INSTALL
  76
  77 dnl| add gettext support
  78 AM_GNU_GETTEXT_VERSION(0.17)
  79 AM_GNU_GETTEXT([external])
  80
  81 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
  82 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
  83 if test "$MINFO" = makeinfo_not_found ; then
  84    echo Please install \"makeinfo\"
  85    exit 1
  86 fi
  87 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
  88 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
  89 AC_SUBST(NROFFFLAGS)
  90 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
  91 AC_PATH_PROGS(PERLPATH, perl)
  92
  93 AC_HEADER_STDC
  94 AC_HEADER_TIME
  95 AC_HEADER_SYS_WAIT
  96 AC_HEADER_DIRENT
  97 AC_TYPE_SIGNAL
  98 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
  99 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
 100 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
 101 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
 102
 103 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
 104 AC_CHECK_FUNCS(gettimeofday ftime, break)
 105 AC_CHECK_FUNCS(random rand48, break)
 106 AC_CHECK_FUNCS(gethostname sysinfo, break)
 107 AC_CHECK_FUNC(setlocale, [],
 108   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
 109
 110 AC_CHECK_LIB(seq, getpseudotty)
 111
 112 dnl | add compiler warnings only if compiler understands them
 113 AC_MSG_CHECKING(whether compiler understands -Wall -Wno-parentheses)
 114 SAVE_CFLAGS="$CFLAGS"
 115 CFLAGS="$CFLAGS -Wall -Wno-parentheses"
 116 AC_TRY_COMPILE([],[],
 117   AC_MSG_RESULT(yes),
 118   AC_MSG_RESULT(no)
 119   CFLAGS="$SAVE_CFLAGS")
 120
 121 dnl | check for pkg-config
 122 AC_CHECK_PROGS([PKGCONFIG], [pkg-config], pkgconfig_not_found)
 123 AS_IF( [test "x$PKGCONFIG" = xpkgconfig_not_found],
 124        AC_MSG_ERROR([cannot find pkg-config! Please install it.]))
 125
 126 dnl | check for cairo and librsvg
 127 PKG_CHECK_MODULES([CAIRO], [ cairo >= 1.2.0 librsvg-2.0 >= 2.14.0 ])
 128 AC_SUBST(CAIRO_CFLAGS)
 129 AC_SUBST(CAIRO_LIBS)
 130
 131 dnl | check which front end to use
 132 dnl | first check for gtk
 133 dnl | then for Xaw3d
 134 dnl | and then for Xaw
 135 FRONTEND_CFLAGS=""
 136 FRONTEND_LIBS=""
 137
 138 AC_ARG_WITH([gtk],
 139             [AS_HELP_STRING([--with-gtk],[use GTK front-end (default)])],
 140             [with_GTK=$withval],
 141             [with_GTK="yes"])
 142
 143 AC_ARG_WITH([Xaw3d],
 144             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d front-end (not fully supported anymore)])],
 145             [with_Xaw3d="$withval"],
 146             [with_Xaw3d="no"])
 147
 148 AC_ARG_WITH([Xaw],
 149             [AS_HELP_STRING([--with-Xaw],[use Xaw front-end])],
 150             [with_Xaw="$withval"],
 151             [with_Xaw="no"])
 152
 153 AC_ARG_WITH([iconsdir],
 154             [AS_HELP_STRING([--with-iconsdir=DIR],
 155             [path where icons get installed (default: $datadir/icons/hicolor/48x48/apps)])],
 156             [ICONSDIR="$withval"],
 157             [ICONSDIR='$(datadir)/icons/hicolor/48x48/apps'])
 158
 159 AC_ARG_WITH([svgiconsdir],
 160             [AS_HELP_STRING([--with-svgiconsdir=DIR],
 161             [path where svg icons get installed (default: $datadir/icons/hicolor/scalable/apps)])],
 162             [SVGICONSDIR="$withval"],
 163             [SVGICONSDIR='$(datadir)/icons/hicolor/scalable/apps'])
 164
 165 AC_ARG_WITH([desktopdir],
 166             [AS_HELP_STRING([--with-desktopdir=DIR],
 167                             [path where desktop files get installed (default: $datadir/applications)])],
 168             [DESKTOPDIR="$withval"],
 169             [DESKTOPDIR='$(datadir)/applications'])
 170
 171 AC_ARG_WITH([mimedir],
 172             [AS_HELP_STRING([--with-mimedir=DIR],
 173                             [path where mime files get installed (default: $datadir/mime/packages)])],
 174             [MIMEDIR="$withval"],
 175             [MIMEDIR='$(datadir)/mime/packages'])
 176
 177 AC_ARG_WITH([gamedatadir],
 178             [AS_HELP_STRING([--with-gamedatadir=DIR],
 179                             [path where game data files get installed (default: $datadir/games/xboard)])],
 180             [GAMEDATADIR="$withval"],
 181             [GAMEDATADIR='$(datadir)/games/xboard'])
 182
 183 AC_ARG_ENABLE([update-mimedb],
 184               [AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]])],
 185               [enable_mimedb="no"],
 186               [enable_mimedb="yes"])
 187
 188 AC_ARG_ENABLE([osxapp],
 189               [AS_HELP_STRING([--enable-osxapp],[build a OSX app [default=no]])],
 190               [enable_OSXAPP=$enableval],
 191               [enable_OSXAPP="no"])
 192
 193 AS_IF([test x"$enable_OSXAPP" = x"yes"], [
 194      prefix=`pwd`/XBoard.app/Contents
 195      AC_DEFINE([OSXAPP], [1], [We are building an OSX APP, redefine some functions])
 196      with_GTK="yes"
 197      enable_mimedb="no"
 198      datarootdir='$(prefix)/Resources'
 199      datadir='$(datarootdir)/share'
 200      sysconfdir='$(datarootdir)/etc'
 201      infodir='$(datadir)/info'
 202      mandir='$(datadir)/man'
 203      bindir='$(prefix)/MacOS'
 204      localedir='$(datadir)/locale'
 205      GAMEDATADIR='$(datadir)/xboard'],[])
 206
 207 AM_CONDITIONAL(OSX_APP, test x"$enable_OSXAPP" = x"yes")
 208
 209 AM_CONDITIONAL(NLS_ENABLED, test x"$USE_NLS" = x"yes")
 210
 211 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x"$enable_mimedb" = x"yes")
 212 if test x"$enable_mimedb" = x"yes"; then
 213    AC_PATH_PROG([XDG_MIME],[xdg-mime])
 214    AC_SUBST(XDG_MIME)
 215    AC_PATH_PROG([XDG_DESKTOP_MENU],[xdg-desktop-menu])
 216    AC_SUBST(XDG_DESKTOP_MENU)
 217    AC_PATH_PROG([XDG_ICON_RESOURCE],[xdg-icon-resource])
 218    AC_SUBST(XDG_ICON_RESOURCE)
 219 fi
 220
 221 AC_SUBST(ICONSDIR)
 222 AC_SUBST(SVGICONSDIR)
 223 AC_SUBST(DESKTOPDIR)
 224 AC_SUBST(MIMEDIR)
 225 AC_SUBST(GAMEDATADIR)
 226
 227 dnl | check for libraries
 228 if test x"$with_GTK" = x"yes" ; then
 229   PKG_CHECK_MODULES([GTK], [ gtk+-2.0 >= 2.16.0 gmodule-2.0 ])
 230   FRONTEND_CFLAGS=$GTK_CFLAGS
 231   FRONTEND_LIBS=$GTK_LIBS
 232   with_Xaw="no"
 233 fi
 234
 235 if test x"$with_GTK" = x"no" ; then
 236
 237 dnl | general check for Xaw and Xaw3d
 238   AC_PATH_XTRA
 239   if test -n "$no_x" ; then
 240     AC_MSG_ERROR([ "    $PACKAGE requires the X Window System header files and libraries!
 241     They were not found on your system.  See FAQ topic C.2.
 242     configure failed"])
 243   fi
 244
 245   save_cflags="$CFLAGS"
 246   save_cppflags="$CPPFLAGS"
 247   CFLAGS="$CFLAGS $X_CFLAGS"
 248   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 249   AC_CHECK_HEADER([X11/Intrinsic.h],[xt="yes"],[xt="no"])
 250   CFLAGS="$save_cflags"
 251   CPPFLAGS="$save_cppflags"
 252
 253   if test "$xt" = "no" ; then
 254      AC_MSG_ERROR([Xt headers not found. Please install the X11 packages.])
 255   fi
 256
 257 dnl | check availability of Xaw3d
 258   FRONTEND_LIBS=
 259   AS_IF([test x"$with_Xaw3d" != x"no"],
 260             [AC_CHECK_LIB([Xaw3d],
 261                     [XawTextReplace],
 262                     [ FRONTEND_LIBS="-lXaw3d"
 263                       AC_DEFINE([USE_XAW3D], [1], [Define if you want to use Xaw3d])],
 264                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
 265                                [-lXaw])])
 266
 267 dnl | no Xaw3d, check for Xaw; make it the default
 268   if test x"$with_Xaw3d" = x"no" ; then
 269      with_Xaw=yes
 270      save_cflags="$CFLAGS"
 271      save_cppflags="$CPPFLAGS"
 272      CFLAGS="$CFLAGS $X_CFLAGS"
 273      CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 274      AC_CHECK_HEADER([X11/Xaw/Dialog.h],[xaw_headers="yes"], [xaw_headers="no"])
 275      CFLAGS="$save_cflags"
 276      CPPFLAGS="$save_cppflags"
 277
 278      if test x"$xaw_headers" = x"no" ; then
 279         AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
 280      fi
 281
 282      FRONTEND_LIBS="-lXaw"
 283   fi
 284
 285 fi
 286
 287 dnl | make results available in Makefile.am
 288 AM_CONDITIONAL([withGTK],   [test x"$with_GTK" = x"yes"])
 289 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw3d" = x"yes" || test x"$with_Xaw" = x"yes"])
 290
 291 dnl | end Front-end check
 292
 293 AC_CANONICAL_HOST
 294
 295 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
 296 dnl| we are trying to find out whether this is a System-V derivative in
 297 dnl| which pipes don't work with select() and if so, whether there is anything
 298 dnl| strange about the way to open a pty.  Some of the work was done above
 299 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
 300 dnl| properties of particular systems are also handled here.
 301
 302 dnl| 4/6/97 I'm not sure there really are any systems where pipes
 303 dnl| don't work with select(), and ptys cause problems on many
 304 dnl| systems, so I'm changing the default to disable ptys in all
 305 dnl| cases.  I will change it back if I get bug reports that are fixed
 306 dnl| by doing a "configure --enable-ptys"
 307
 308 USE_PTYS=0
 309 case "$host" in
 310   *-*-hpux* )
 311     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 312         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
 313     AC_DEFINE(PTY_NAME_SPRINTF,
 314         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
 315 dnl| USE_PTYS=1
 316     if test "$GCC" = yes; then
 317       CONF_CFLAGS="-fwritable-strings"
 318     else
 319
 320 dnl| Note: You might be able to build xboard even if your compiler does not
 321 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
 322 dnl| know whether the X header files on HP-UX require it.
 323
 324       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
 325     fi
 326
 327 dnl| HP doesn't supply a full set of X header files and libraries.  People
 328 dnl| often have some things installed in one place and some in another.
 329 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
 330 dnl| likely ones that might be missing here.  It might be better to
 331 dnl| change AC_PATH_XTRA to try to extract this information from imake,
 332 dnl| since folks who install the missing bits often configure their
 333 dnl| imake to find them, but I don't want to delve into autoconf and
 334 dnl| hack on its internals.
 335
 336     if test -d /opt/hppd/include/X11; then
 337       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
 338       X_LIBS="$X_LIBS -L/opt/hppd/lib"
 339     elif test -d /usr/contrib/X11R5/include; then
 340       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
 341       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
 342     elif test -d /usr/contrib/mitX11R5/include; then
 343       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
 344       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
 345     elif test -d /MIT/X11R5/include; then
 346       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
 347       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
 348     elif test -d /usr/local/include/X11R5; then
 349       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
 350       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
 351     fi
 352     if test -d /usr/include/X11R5; then
 353       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
 354       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
 355     elif test -d /usr/include/X11R4; then
 356       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
 357       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
 358     fi
 359   ;;
 360
 361   romp-ibm-aix* )
 362     AC_DEFINE(IBMRTAIX, 1)
 363 dnl| USE_PTYS=1
 364   ;;
 365
 366   i386-ibm-aix )
 367 dnl| USE_PTYS=1
 368     if test "$GCC" = yes; then
 369       CONF_CFLAGS="-fwritable-strings"
 370     fi
 371   ;;
 372
 373   *-*-aix3* | *-*-bosx* )
 374     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 375     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 376     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
 377 dnl| USE_PTYS=1
 378   ;;
 379
 380   *-*-cxux* )
 381     AC_DEFINE(FIRST_PTY_LETTER, 'A')
 382     AC_DEFINE(LAST_PTY_LETTER, 'P')
 383 dnl| USE_PTYS=1
 384   ;;
 385
 386   *-*-uniplus* )
 387     AC_DEFINE(UNIPLUS, 1)
 388 dnl| USE_PTYS=1
 389   ;;
 390
 391   *-*-rtu* )
 392     AC_DEFINE(FIRST_PTY_LETTER, 'z')
 393     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 394         [sprintf (pty_name, "/dev/ttyp%x", i);])
 395     AC_DEFINE(PTY_NAME_SPRINTF,
 396         [sprintf (pty_name, "/dev/pty%x", i);])
 397     AC_DEFINE(RTU, 1)
 398 dnl| USE_PTYS=1
 399   ;;
 400
 401   *-*-iris* | *-*-irix3* )
 402     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 403     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 404     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 405         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
 406 dnl| USE_PTYS=1
 407   ;;
 408
 409   *-*-irix* )
 410 dnl| USE_PTYS=1
 411   ;;
 412
 413   *-*-sunos4* | *-*-solaris1* )
 414
 415 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
 416 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
 417 dnl|  "overkill," but doesn't explain what should be done instead.
 418
 419     if test "$GCC" = yes; then
 420       PRE_XMULIB="-static"
 421       POST_XMULIB="-dynamic"
 422     else
 423       PRE_XMULIB="-Bstatic"
 424       POST_XMULIB="-Bdynamic"
 425     fi
 426   ;;
 427
 428   *-*-sunos5* | *-*-solaris2* )
 429 dnl| USE_PTYS=1
 430
 431 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
 432 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
 433 dnl| code above.
 434
 435     X_LIBS="$X_LIBS -lelf"
 436   ;;
 437
 438   *-*-sco* )
 439     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
 440     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
 441     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
 442 dnl| USE_PTYS=1
 443   ;;
 444
 445   *-*-dynix* | *-*-ptx* )
 446 dnl| USE_PTYS=1
 447   ;;
 448
 449   *-*-esix* )
 450 dnl| USE_PTYS=1
 451   ;;
 452
 453   *-*-usg5-4* | *-*-sysvr4* )
 454 dnl| USE_PTYS=1
 455   ;;
 456
 457   *-*-usg* | *-*-sysv* | *-*-aix* )
 458 dnl| USE_PTYS=1
 459   ;;
 460
 461   vax-*-ultrix )
 462     if test "$GCC" = yes; then
 463       CONF_CFLAGS="-fwritable-strings"
 464     fi
 465   ;;
 466
 467 dnl| add some libs for OS X
 468   *-apple-* )
 469     AC_MSG_WARN([Apple support is experimental, please report any problems to bug-xboard@gnu.org])
 470     AC_MSG_WARN([use --enable-osxapp to enable the build target and automatically adjust target directories])
 471     AC_MSG_WARN([Building an OSX app currently relies on some programs such as dylib that we don't test for])
 472     AC_MSG_WARN([patches welcome ;)])
 473     AC_PATH_PROG(SW_VERS, sw_vers)
 474     if test "x$SW_VERS" != "x"; then
 475       AC_MSG_CHECKING(Mac OS X version)
 476       MACOSX_VERSION=`$SW_VERS -productVersion`
 477       AC_MSG_RESULT([$MACOSX_VERSION])
 478     fi
 479     FRONTEND_LIBS="$FRONTEND_LIBS -headerpad_max_install_names "
 480     if test x"$enable_OSXAPP" = x"yes" ; then
 481         FRONTEND_LIBS="$FRONTEND_LIBS -lgtkmacintegration-gtk2"
 482     fi
 483     FRONTEND_CFLAGS="$FRONTEND_CFLAGS -I/opt/local/include -L/opt/local/lib"
 484   ;;
 485 esac
 486
 487
 488 AC_SUBST(FRONTEND_CFLAGS)
 489 AC_SUBST(FRONTEND_LIBS)
 490 AC_SUBST(PRE_XMULIB)
 491 AC_SUBST(POST_XMULIB)
 492 AC_SUBST(CONF_CFLAGS)
 493 AC_SUBST(CONF_LDFLAGS)
 494
 495 AC_MSG_CHECKING(whether ptys or pipes should be used)
 496 AC_ARG_ENABLE( [ptys],
 497                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
 498 [if test "$enableval" = yes; then
 499   USE_PTYS=1
 500   enable_ptys="ptys"
 501   AC_MSG_RESULT([ptys (user override)])
 502 fi
 503 if test "$enableval" = no; then
 504   USE_PTYS=0
 505   enable_ptys="pipes"
 506   AC_MSG_RESULT([pipes (user override)])
 507 fi],
 508 [if test "$USE_PTYS" = 1; then
 509   AC_MSG_RESULT(ptys)
 510   enable_ptys="ptys"
 511 else
 512   AC_MSG_RESULT(pipes)
 513   enable_ptys="pipes"
 514 fi])
 515 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
 516
 517
 518 dnl | define not to build zippy as a default, so that autoheader is happy
 519 AC_ARG_ENABLE( [zippy],
 520                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
 521                [],
 522                [enable_zippy="no"])
 523
 524 if test x"$enable_zippy" != x"no"; then
 525   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
 526 else
 527   AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
 528 fi
 529 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
 530
 531
 532 AC_ARG_ENABLE(sigint,
 533 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
 534 [if test "$enableval" = yes; then
 535   AC_DEFINE(ATTENTION, 1)
 536 fi
 537 enable_sigint=$enableval
 538 ],
 539 [enable_sigint="yes"
 540 AC_DEFINE(ATTENTION, 1)])
 541
 542
 543 if test x"$with_Xaw3d" = x"yes" -o  x"$with_Xaw" = x"yes" ; then
 544 dnl | save all information for X in X_LIBS, also add the libraries themself
 545 dnl | since AC_PATH_XTRA only adds the paths
 546 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
 547 AC_SUBST(X_CFLAGS)
 548 AC_SUBST(X_LIBS)
 549 fi
 550
 551 dnl create a string with configure options that can be passed to the
 552 dnl program, good for bug reports and version printout, see output below
 553 CONFIGURE_OPTIONS="prefix=$prefix; datarootdir=$datarootdir; \
 554 datadir=$datadir; gamedatadir=$GAMEDATADIR; desktopdir=$DESKTOPDIR; \
 555 mimedir=$MIMEDIR; iconsdir=$ICONSDIR; svgiconsdir=$SVGICONSDIR; infodir=$infodir; \
 556 sysconfigdir=$sysconfigdir; update_mimedb=$enable_mimedb; NLS=$USE_NLS; \
 557 GTK=$with_GTK; Xaw3d=$with_Xaw3d; Xaw=$with_Xaw; \
 558 ptys=$enable_ptys; zippy=$enable_zippy; sigint=$enable_sigint"
 559
 560 AC_SUBST(CONFIGURE_OPTIONS)
 561
 562 dnl |  output Makefile
 563 AC_CONFIG_FILES([Makefile cmail po/Makefile.in osxapp/Info.plist])
 564 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
 565 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
 566 AC_OUTPUT
 567
 568 dnl
 569 dnl Output a summary
 570 dnl
 571 echo ""
 572 echo " Configurations summary:"
 573 echo ""
 574 echo "        prefix:          $prefix       "
 575 echo "        datarootdir:     $datarootdir  "
 576 echo "        datadir:         $datadir      "
 577 echo "        gamedatadir:     $GAMEDATADIR  "
 578 echo "        desktopdir:      $DESKTOPDIR   "
 579 echo "        mimedir:         $MIMEDIR      "
 580 echo "        iconsdir:        $ICONSDIR     "
 581 echo "        svgiconsdir:     $SVGICONSDIR  "
 582 echo "        infodir:         $infodir   (info files will go here)"
 583 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
 584 echo ""
 585 echo "        update mimedb:   $enable_mimedb"
 586 echo ""
 587 echo "        NLS support:     $USE_NLS"
 588 echo ""
 589 echo "        GTK:             $with_GTK"
 590 echo "        Xaw3d:           $with_Xaw3d"
 591 echo "        Xaw:             $with_Xaw"
 592 echo ""
 593 echo "        ptys:            $enable_ptys"
 594 echo "        zippy:           $enable_zippy"
 595 echo "        sigint:          $enable_sigint"