configure.ac

   1 dnl| configure.in
   2 dnl|
   3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 dnl| 2008, 2009, 2010, 2011, 2012, 2013 Free Software Foundation, Inc.
   5 dnl|
   6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
   7 dnl| it under the terms of the GNU General Public License as published by
   8 dnl| the Free Software Foundation, either version 3 of the License, or (at
   9 dnl| your option) any later version.
  10 dnl|
  11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
  12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 dnl| General Public License for more details.
  15 dnl|
  16 dnl| You should have received a copy of the GNU General Public License
  17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
  18 dnl|
  19 dnl| --------------------------------------------------------------------
  20 dnl|
  21 dnl| You can process this file with autoconf to produce a configure script.
  22 dnl| However, normally the supplied configure script will work fine.
  23 dnl|
  24 dnl| If you do need to change the configure script, instead of editing
  25 dnl| it directly, try to edit configure.in (in a way that will keep
  26 dnl| it portable to sites and systems other than your own), and run autoconf
  27 dnl| to regenerate configure.  Then submit your changes to be folded into
  28 dnl| the standard version of xboard.
  29
  30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
  31 AC_INIT([xboard],[master-20130828],[bug-xboard@gnu.org])
  32
  33 dnl| need this to be able to compile some files in a subdir (filebrowser)
  34 AM_INIT_AUTOMAKE([subdir-objects])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 AC_CONFIG_HEADERS([config.h])
  38
  39 dnl | a bunch of templates for defines used below
  40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
  41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
  42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
  43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
  44 AH_TEMPLATE([HAVE_RANDOM],[template])
  45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
  46 AH_TEMPLATE([IBMRTAIX],[template])
  47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
  48 AH_TEMPLATE([PTY_ITERATION],[template])
  49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
  50 AH_TEMPLATE([PTY_OPEN],[template])
  51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
  52 AH_TEMPLATE([REMOTE_SHELL],[template])
  53 AH_TEMPLATE([RTU],[template])
  54 AH_TEMPLATE([UNIPLUS],[template])
  55 AH_TEMPLATE([USE_PTYS],[template])
  56 AH_TEMPLATE([X_WCHAR],[template])
  57 AH_TEMPLATE([ATTENTION],[template])
  58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
  59 AH_TEMPLATE([HAVE_LIBXPM],[template])
  60 AH_TEMPLATE([USE_XAW3D],[template])
  61 AH_TEMPLATE([X_LOCALE],[template])
  62
  63
  64
  65 if test -z "$CFLAGS" ; then
  66 dnl| Prevent the next macro from setting CFLAGS to -g
  67   CFLAGS=" "
  68 fi
  69 AC_PROG_CC
  70
  71 dnl| need this to be able to compile files in a subdir
  72 AM_PROG_CC_C_O
  73
  74 AC_PROG_CPP
  75 AC_ISC_POSIX
  76 AC_PROG_INSTALL
  77
  78 dnl| add gettext support
  79 AM_GNU_GETTEXT_VERSION(0.17)
  80 AM_GNU_GETTEXT([external])
  81
  82 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
  83 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
  84 if test "$MINFO" = makeinfo_not_found ; then
  85    echo Please install \"makeinfo\"
  86    exit 1
  87 fi
  88 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
  89 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
  90 AC_SUBST(NROFFFLAGS)
  91 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
  92 AC_PATH_PROGS(PERLPATH, perl)
  93
  94 AC_HEADER_STDC
  95 AC_HEADER_TIME
  96 AC_HEADER_SYS_WAIT
  97 AC_HEADER_DIRENT
  98 AC_TYPE_SIGNAL
  99 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
 100 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
 101 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
 102 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
 103
 104 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
 105 AC_CHECK_FUNCS(gettimeofday ftime, break)
 106 AC_CHECK_FUNCS(random rand48, break)
 107 AC_CHECK_FUNCS(gethostname sysinfo, break)
 108 AC_CHECK_FUNC(setlocale, [],
 109   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
 110
 111 AC_CHECK_LIB(seq, getpseudotty)
 112
 113 dnl | add compiler warnings only if compiler understands them
 114 AC_MSG_CHECKING(whether compiler understands -Wall -Wno-parentheses)
 115 SAVE_CFLAGS="$CFLAGS"
 116 CFLAGS="$CFLAGS -Wall -Wno-parentheses"
 117 AC_TRY_COMPILE([],[],
 118   AC_MSG_RESULT(yes),
 119   AC_MSG_RESULT(no)
 120   CFLAGS="$SAVE_CFLAGS")
 121
 122 dnl | check for pkg-config
 123 AC_CHECK_PROGS([PKGCONFIG], [pkg-config], pkgconfig_not_found)
 124 AS_IF( [test "x$PKGCONFIG" = xpkgconfig_not_found],
 125        AC_MSG_ERROR([cannot find pkg-config! Please install it.]))
 126
 127 dnl | check for cairo and librsvg
 128 PKG_CHECK_MODULES([CAIRO], [ cairo >= 1.2.0 librsvg-2.0 >= 2.14.0 ])
 129 AC_SUBST(CAIRO_CFLAGS)
 130 AC_SUBST(CAIRO_LIBS)
 131
 132 dnl | check which front end to use
 133 dnl | first check for gtk
 134 dnl | then for Xaw3d
 135 dnl | and then for Xaw
 136 FRONTEND_CFLAGS=""
 137 FRONTEND_LIBS=""
 138
 139 AC_ARG_WITH([gtk],
 140             [AS_HELP_STRING([--with-gtk],[use GTK front-end (experimental)])],
 141             [with_GTK=yes],
 142             [with_GTK=no])
 143
 144 AC_ARG_WITH([Xaw3d],
 145             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d front-end (not fully supported anymore)])],
 146             [with_Xaw3d=yes],
 147             [with_Xaw3d=no])
 148
 149 AC_ARG_WITH([Xaw],
 150             [AS_HELP_STRING([--with-Xaw],[use Xaw front-end (default)])],
 151             [with_Xaw=yes],
 152             [with_Xaw=no])
 153
 154 dnl | check for libraries
 155 if test x"$with_GTK" = x"yes" ; then
 156   PKG_CHECK_MODULES([GTK], [ gtk+-2.0 >= 2.16.0 gmodule-2.0 ])
 157   FRONTEND_CFLAGS=$GTK_CFLAGS
 158   FRONTEND_LIBS=$GTK_LIBS
 159 fi
 160
 161 if test x"$with_GTK" = x"no" ; then
 162
 163 dnl | general check for Xaw and Xaw3d
 164   AC_PATH_XTRA
 165   if test -n "$no_x" ; then
 166     AC_MSG_ERROR([ "    $PACKAGE requires the X Window System header files and libraries!
 167     They were not found on your system.  See FAQ topic C.2.
 168     configure failed"])
 169   fi
 170
 171   save_cflags="$CFLAGS"
 172   save_cppflags="$CPPFLAGS"
 173   CFLAGS="$CFLAGS $X_CFLAGS"
 174   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 175   AC_CHECK_HEADER([X11/Intrinsic.h],[xt="yes"],[xt="no"])
 176   CFLAGS="$save_cflags"
 177   CPPFLAGS="$save_cppflags"
 178
 179   if test "$xt" = "no" ; then
 180      AC_MSG_ERROR([Xt headers not found. Please install the X11 packages.])
 181   fi
 182
 183 dnl | check availability of Xaw3d
 184   FRONTEND_LIBS=
 185   AS_IF([test x"$with_Xaw3d" != x"no"],
 186             [AC_CHECK_LIB([Xaw3d],
 187                     [XawTextReplace],
 188                     [ FRONTEND_LIBS="-lXaw3d"
 189                       AC_DEFINE([USE_XAW3D], [1], [Define if you want to use Xaw3d])],
 190                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
 191                                [-lXaw])])
 192
 193 dnl | no Xaw3d, check for Xaw; make it the default
 194   if test x"$with_Xaw3d" = x"no" ; then
 195      with_Xaw=yes
 196      save_cflags="$CFLAGS"
 197      save_cppflags="$CPPFLAGS"
 198      CFLAGS="$CFLAGS $X_CFLAGS"
 199      CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 200      AC_CHECK_HEADER([X11/Xaw/Dialog.h],[xaw_headers="yes"], [xaw_headers="no"])
 201      CFLAGS="$save_cflags"
 202      CPPFLAGS="$save_cppflags"
 203
 204      if test x"$xaw_headers" = x"no" ; then
 205         AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
 206      fi
 207
 208      FRONTEND_LIBS="-lXaw"
 209   fi
 210
 211 fi
 212
 213 dnl | make results available in Makefile.am
 214 AM_CONDITIONAL([withGTK],   [test x"$with_GTK" = x"yes"])
 215 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw3d" = x"yes"])
 216 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw" = x"yes"])
 217
 218
 219 AC_SUBST(FRONTEND_CFLAGS)
 220 AC_SUBST(FRONTEND_LIBS)
 221
 222 dnl | end Front-end check
 223
 224 AC_CANONICAL_HOST
 225
 226 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
 227 dnl| we are trying to find out whether this is a System-V derivative in
 228 dnl| which pipes don't work with select() and if so, whether there is anything
 229 dnl| strange about the way to open a pty.  Some of the work was done above
 230 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
 231 dnl| properties of particular systems are also handled here.
 232
 233 dnl| 4/6/97 I'm not sure there really are any systems where pipes
 234 dnl| don't work with select(), and ptys cause problems on many
 235 dnl| systems, so I'm changing the default to disable ptys in all
 236 dnl| cases.  I will change it back if I get bug reports that are fixed
 237 dnl| by doing a "configure --enable-ptys"
 238
 239 USE_PTYS=0
 240 case "$host" in
 241   *-*-hpux* )
 242     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 243         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
 244     AC_DEFINE(PTY_NAME_SPRINTF,
 245         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
 246 dnl| USE_PTYS=1
 247     if test "$GCC" = yes; then
 248       CONF_CFLAGS="-fwritable-strings"
 249     else
 250
 251 dnl| Note: You might be able to build xboard even if your compiler does not
 252 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
 253 dnl| know whether the X header files on HP-UX require it.
 254
 255       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
 256     fi
 257
 258 dnl| HP doesn't supply a full set of X header files and libraries.  People
 259 dnl| often have some things installed in one place and some in another.
 260 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
 261 dnl| likely ones that might be missing here.  It might be better to
 262 dnl| change AC_PATH_XTRA to try to extract this information from imake,
 263 dnl| since folks who install the missing bits often configure their
 264 dnl| imake to find them, but I don't want to delve into autoconf and
 265 dnl| hack on its internals.
 266
 267     if test -d /opt/hppd/include/X11; then
 268       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
 269       X_LIBS="$X_LIBS -L/opt/hppd/lib"
 270     elif test -d /usr/contrib/X11R5/include; then
 271       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
 272       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
 273     elif test -d /usr/contrib/mitX11R5/include; then
 274       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
 275       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
 276     elif test -d /MIT/X11R5/include; then
 277       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
 278       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
 279     elif test -d /usr/local/include/X11R5; then
 280       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
 281       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
 282     fi
 283     if test -d /usr/include/X11R5; then
 284       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
 285       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
 286     elif test -d /usr/include/X11R4; then
 287       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
 288       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
 289     fi
 290   ;;
 291
 292   romp-ibm-aix* )
 293     AC_DEFINE(IBMRTAIX, 1)
 294 dnl| USE_PTYS=1
 295   ;;
 296
 297   i386-ibm-aix )
 298 dnl| USE_PTYS=1
 299     if test "$GCC" = yes; then
 300       CONF_CFLAGS="-fwritable-strings"
 301     fi
 302   ;;
 303
 304   *-*-aix3* | *-*-bosx* )
 305     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 306     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 307     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
 308 dnl| USE_PTYS=1
 309   ;;
 310
 311   *-*-cxux* )
 312     AC_DEFINE(FIRST_PTY_LETTER, 'A')
 313     AC_DEFINE(LAST_PTY_LETTER, 'P')
 314 dnl| USE_PTYS=1
 315   ;;
 316
 317   *-*-uniplus* )
 318     AC_DEFINE(UNIPLUS, 1)
 319 dnl| USE_PTYS=1
 320   ;;
 321
 322   *-*-rtu* )
 323     AC_DEFINE(FIRST_PTY_LETTER, 'z')
 324     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 325         [sprintf (pty_name, "/dev/ttyp%x", i);])
 326     AC_DEFINE(PTY_NAME_SPRINTF,
 327         [sprintf (pty_name, "/dev/pty%x", i);])
 328     AC_DEFINE(RTU, 1)
 329 dnl| USE_PTYS=1
 330   ;;
 331
 332   *-*-iris* | *-*-irix3* )
 333     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 334     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 335     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 336         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
 337 dnl| USE_PTYS=1
 338   ;;
 339
 340   *-*-irix* )
 341 dnl| USE_PTYS=1
 342   ;;
 343
 344   *-*-sunos4* | *-*-solaris1* )
 345
 346 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
 347 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
 348 dnl|  "overkill," but doesn't explain what should be done instead.
 349
 350     if test "$GCC" = yes; then
 351       PRE_XMULIB="-static"
 352       POST_XMULIB="-dynamic"
 353     else
 354       PRE_XMULIB="-Bstatic"
 355       POST_XMULIB="-Bdynamic"
 356     fi
 357   ;;
 358
 359   *-*-sunos5* | *-*-solaris2* )
 360 dnl| USE_PTYS=1
 361
 362 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
 363 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
 364 dnl| code above.
 365
 366     X_LIBS="$X_LIBS -lelf"
 367   ;;
 368
 369   *-*-sco* )
 370     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
 371     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
 372     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
 373 dnl| USE_PTYS=1
 374   ;;
 375
 376   *-*-dynix* | *-*-ptx* )
 377 dnl| USE_PTYS=1
 378   ;;
 379
 380   *-*-esix* )
 381 dnl| USE_PTYS=1
 382   ;;
 383
 384   *-*-usg5-4* | *-*-sysvr4* )
 385 dnl| USE_PTYS=1
 386   ;;
 387
 388   *-*-usg* | *-*-sysv* | *-*-aix* )
 389 dnl| USE_PTYS=1
 390   ;;
 391
 392   vax-*-ultrix )
 393     if test "$GCC" = yes; then
 394       CONF_CFLAGS="-fwritable-strings"
 395     fi
 396   ;;
 397
 398 dnl| add some libs for OS X
 399   *-apple-* )
 400   ;;
 401 esac
 402
 403 AC_ARG_ENABLE(  [xpm],
 404                 [AS_HELP_STRING([--enable-xpm],[libXpm will be used if found (default)])],
 405                 [enable_xpm="$enableval"],
 406                 [enable_xpm="yes"])
 407
 408 if test x"$enable_xpm" != "xno"; then
 409   save_cflags="$CFLAGS"
 410   save_cppflags="$CPPFLAGS"
 411   CFLAGS="$CFLAGS $X_CFLAGS"
 412   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 413   AC_CHECK_HEADERS(X11/xpm.h)
 414   CFLAGS="$save_cflags"
 415   CPPFLAGS="$save_cppflags"
 416   if test "$ac_cv_header_X11_xpm_h" = "yes"; then
 417     save_ldflags="$LDFLAGS"
 418     LDFLAGS="$LDFLAGS $X_LIBS"
 419     AC_CHECK_LIB(Xpm, XpmReadFileToPixmap,
 420                  [X_PRE_LIBS="-lXpm $X_PRE_LIBS"; AC_DEFINE(HAVE_LIBXPM)], [],
 421                  [$X_PRE_LIBS -lX11 $X_EXTRA_LIBS])
 422     LDFLAGS="$save_ldflags"
 423   fi
 424 fi
 425
 426 AC_SUBST(PRE_XMULIB)
 427 AC_SUBST(POST_XMULIB)
 428 AC_SUBST(CONF_CFLAGS)
 429 AC_SUBST(CONF_LDFLAGS)
 430
 431 AC_MSG_CHECKING(whether ptys or pipes should be used)
 432 AC_ARG_ENABLE( [ptys],
 433                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
 434 [if test "$enableval" = yes; then
 435   USE_PTYS=1
 436   enable_ptys="ptys"
 437   AC_MSG_RESULT([ptys (user override)])
 438 fi
 439 if test "$enableval" = no; then
 440   USE_PTYS=0
 441   enable_ptys="pipes"
 442   AC_MSG_RESULT([pipes (user override)])
 443 fi],
 444 [if test "$USE_PTYS" = 1; then
 445   AC_MSG_RESULT(ptys)
 446   enable_ptys="ptys"
 447 else
 448   AC_MSG_RESULT(pipes)
 449   enable_ptys="pipes"
 450 fi])
 451 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
 452
 453
 454 dnl | define not to build zippy as a default, so that autoheader is happy
 455 AC_ARG_ENABLE( [zippy],
 456                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
 457                [],
 458                [enable_zippy="no"])
 459
 460 if test x"$enable_zippy" != xno; then
 461   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
 462 else
 463   AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
 464 fi
 465 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
 466
 467
 468 AC_ARG_ENABLE(sigint,
 469 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
 470 [if test "$enableval" = yes; then
 471   AC_DEFINE(ATTENTION, 1)
 472 fi
 473 enable_sigint=$enableval
 474 ],
 475 [enable_sigint="yes"
 476 AC_DEFINE(ATTENTION, 1)])
 477
 478
 479 if test x"$with_Xaw3d" = x"yes" -o  x"$with_Xaw" = x"yes" ; then
 480 dnl | save all information for X in X_LIBS, also add the libraries themself
 481 dnl | since AC_PATH_XTRA only adds the paths
 482 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
 483 AC_SUBST(X_CFLAGS)
 484 AC_SUBST(X_LIBS)
 485 fi
 486
 487 dnl | should we install desktop icons and mime associations?
 488 AC_ARG_ENABLE(  [update-mimedb],
 489                 [AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]])],
 490                 [enable_mimedb="no"],
 491                 [enable_mimedb="yes"])
 492
 493 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x"$enable_mimedb" = "xyes")
 494
 495 if test x"$enable_mimedb" = "xyes"; then
 496    AC_PATH_PROG([XDG_MIME],[xdg-mime])
 497    AC_SUBST(XDG_MIME)
 498    AC_PATH_PROG([XDG_DESKTOP_MENU],[xdg-desktop-menu])
 499    AC_SUBST(XDG_DESKTOP_MENU)
 500    AC_PATH_PROG([XDG_ICON_RESOURCE],[xdg-icon-resource])
 501    AC_SUBST(XDG_ICON_RESOURCE)
 502 fi
 503
 504 dnl |  output Makefile
 505 AC_CONFIG_FILES([Makefile cmail po/Makefile.in])
 506 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
 507 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
 508 AC_OUTPUT
 509
 510 dnl
 511 dnl Output a summary
 512 dnl
 513 echo ""
 514 echo " Configurations summary:"
 515 echo ""
 516 echo "        prefix:          $prefix       "
 517 echo "        datarootdir:     $datarootdir  "
 518 echo "        datadir:         $datadir   (icons will go in \$datadir/icons/hicolor/...)"
 519 echo "                                    (bitmaps will go in \$datadir/games/xboard/...)"
 520 echo "        infodir:         $infodir   (info files will go here)"
 521 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
 522 echo ""
 523 echo "        update mimedb:   $enable_mimedb"
 524 echo ""
 525 echo "        NLS support:     $USE_NLS"
 526 echo ""
 527 echo "        GTK:             $with_GTK"
 528 echo "        Xaw3d:           $with_Xaw3d"
 529 echo "        Xaw:             $with_Xaw"
 530 echo ""
 531 echo "        xpm:             $enable_xpm"
 532 echo "        ptys:            $enable_ptys"
 533 echo "        zippy:           $enable_zippy"
 534 echo "        sigint:          $enable_sigint"