configure.ac

   1 dnl| configure.in
   2 dnl|
   3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 dnl| 2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
   5 dnl|
   6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
   7 dnl| it under the terms of the GNU General Public License as published by
   8 dnl| the Free Software Foundation, either version 3 of the License, or (at
   9 dnl| your option) any later version.
  10 dnl|
  11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
  12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 dnl| General Public License for more details.
  15 dnl|
  16 dnl| You should have received a copy of the GNU General Public License
  17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
  18 dnl|
  19 dnl| --------------------------------------------------------------------
  20 dnl|
  21 dnl| You can process this file with autoconf to produce a configure script.
  22 dnl| However, normally the supplied configure script will work fine.
  23 dnl|
  24 dnl| If you do need to change the configure script, instead of editing
  25 dnl| it directly, try to edit configure.in (in a way that will keep
  26 dnl| it portable to sites and systems other than your own), and run autoconf
  27 dnl| to regenerate configure.  Then submit your changes to be folded into
  28 dnl| the standard version of xboard.
  29
  30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
  31 AC_INIT([xboard],[master-20120930],[bug-xboard@gnu.org])
  32
  33 dnl| need this to be able to compile some files in a subdir (filebrowser)
  34 AM_INIT_AUTOMAKE([subdir-objects])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 AC_CONFIG_HEADERS([config.h])
  38
  39 dnl | a bunch of templates for defines used below
  40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
  41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
  42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
  43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
  44 AH_TEMPLATE([HAVE_RANDOM],[template])
  45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
  46 AH_TEMPLATE([IBMRTAIX],[template])
  47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
  48 AH_TEMPLATE([PTY_ITERATION],[template])
  49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
  50 AH_TEMPLATE([PTY_OPEN],[template])
  51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
  52 AH_TEMPLATE([REMOTE_SHELL],[template])
  53 AH_TEMPLATE([RTU],[template])
  54 AH_TEMPLATE([UNIPLUS],[template])
  55 AH_TEMPLATE([USE_PTYS],[template])
  56 AH_TEMPLATE([X_WCHAR],[template])
  57 AH_TEMPLATE([ATTENTION],[template])
  58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
  59 AH_TEMPLATE([HAVE_LIBXPM],[template])
  60 AH_TEMPLATE([USE_XAW3D],[template])
  61 AH_TEMPLATE([X_LOCALE],[template])
  62
  63
  64
  65 if test -z "$CFLAGS" ; then
  66 dnl| Prevent the next macro from setting CFLAGS to -g
  67   CFLAGS=" "
  68 fi
  69 AC_PROG_CC
  70
  71 dnl| need this to be able to compile files in a subdir
  72 AM_PROG_CC_C_O
  73
  74 AC_PROG_CPP
  75 AC_ISC_POSIX
  76 AC_PROG_INSTALL
  77
  78 dnl| add gettext support
  79 AM_GNU_GETTEXT_VERSION(0.17)
  80 AM_GNU_GETTEXT([external])
  81
  82 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
  83 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
  84 if test "$MINFO" = makeinfo_not_found ; then
  85    echo Please install \"makeinfo\"
  86    exit 1
  87 fi
  88 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
  89 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
  90 AC_SUBST(NROFFFLAGS)
  91 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
  92 AC_PATH_PROGS(PERLPATH, perl)
  93
  94 AC_HEADER_STDC
  95 AC_HEADER_TIME
  96 AC_HEADER_SYS_WAIT
  97 AC_HEADER_DIRENT
  98 AC_TYPE_SIGNAL
  99 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
 100 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
 101 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
 102 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
 103
 104 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
 105 AC_CHECK_FUNCS(gettimeofday ftime, break)
 106 AC_CHECK_FUNCS(random rand48, break)
 107 AC_CHECK_FUNCS(gethostname sysinfo, break)
 108 AC_CHECK_FUNC(setlocale, [],
 109   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
 110
 111 AC_CHECK_LIB(seq, getpseudotty)
 112
 113 dnl | add compiler warnings only if compiler understands them
 114 AC_MSG_CHECKING(whether compiler understands -Wall -Wno-parentheses)
 115 SAVE_CFLAGS="$CFLAGS"
 116 CFLAGS="$CFLAGS -Wall -Wno-parentheses"
 117 AC_TRY_COMPILE([],[],
 118   AC_MSG_RESULT(yes),
 119   AC_MSG_RESULT(no)
 120   CFLAGS="$SAVE_CFLAGS")
 121
 122 dnl | check for cairo and librsvg
 123
 124 PKG_CHECK_MODULES([CAIRO], [ cairo >= 1.2.0 librsvg-2.0 >= 2.14.0 ])
 125 AC_SUBST(CAIRO_CFLAGS)
 126 AC_SUBST(CAIRO_LIBS)
 127
 128 dnl | check which front end to use
 129 dnl | first check for gtk
 130 dnl | then for Xaw3d
 131 dnl | and then for Xaw
 132 FRONTEND_CFLAGS=""
 133 FRONTEND_LIBS=""
 134
 135 AC_ARG_WITH([gtk],
 136             [AS_HELP_STRING([--with-gtk],[use GTK front-end (experimental)])],
 137             [with_GTK=yes],
 138             [with_GTK=no])
 139
 140 AC_ARG_WITH([Xaw3d],
 141             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d front-end (not fully supported anymore)])],
 142             [with_Xaw3d=yes],
 143             [with_Xaw3d=no])
 144
 145 AC_ARG_WITH([Xaw],
 146             [AS_HELP_STRING([--with-Xaw],[use Xaw front-end (default)])],
 147             [with_Xaw=yes],
 148             [with_Xaw=no])
 149
 150 dnl | make results available in Makefile.am
 151 AM_CONDITIONAL([withGTK],   [test x"$with_GTK" = x"yes"])
 152 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw3d" = x"yes"])
 153 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw" = x"yes"])
 154
 155 dnl | check for libraries
 156 if test x"$with_GTK" = x"yes" ; then
 157   PKG_CHECK_MODULES([GTK], [ gtk+-2.0 >= 2.16.0 gmodule-2.0 ])
 158   FRONTEND_CFLAGS=$GTK_CFLAGS
 159   FRONTEND_LIBS=$GTK_LIBS
 160 fi
 161
 162 if test x"$with_GTK" = x"no" ; then
 163
 164 dnl | general check for Xaw and Xaw3d
 165   AC_PATH_XTRA
 166   if test -n "$no_x" ; then
 167     AC_MSG_ERROR([ "    $PACKAGE requires the X Window System header files and libraries!
 168     They were not found on your system.  See FAQ topic C.2.
 169     configure failed"])
 170   fi
 171
 172   save_cflags="$CFLAGS"
 173   save_cppflags="$CPPFLAGS"
 174   CFLAGS="$CFLAGS $X_CFLAGS"
 175   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 176   AC_CHECK_HEADER([X11/Intrinsic.h],[xt="yes"],[xt="no"])
 177   CFLAGS="$save_cflags"
 178   CPPFLAGS="$save_cppflags"
 179
 180   if test "$xt" = "no" ; then
 181      AC_MSG_ERROR([Xt headers not found. Please install the X11 packages.])
 182   fi
 183
 184 dnl | check availability of Xaw3d
 185   FRONTEND_LIBS=
 186   AS_IF([test x"$with_Xaw3d" != x"no"],
 187             [AC_CHECK_LIB([Xaw3d],
 188                     [XawTextReplace],
 189                     [ FRONTEND_LIBS="-lXaw3d"
 190                       AC_DEFINE([USE_XAW3D], [1], [Define if you want to use Xaw3d])],
 191                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
 192                                [-lXaw])])
 193
 194 dnl | no Xaw3d, check for Xaw
 195   if test x"$with_Xaw3d" = x"no" ; then
 196      save_cflags="$CFLAGS"
 197      save_cppflags="$CPPFLAGS"
 198      CFLAGS="$CFLAGS $X_CFLAGS"
 199      CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 200      AC_CHECK_HEADER([X11/Xaw/Dialog.h],[xaw_headers="yes"], [xaw_headers="no"])
 201      CFLAGS="$save_cflags"
 202      CPPFLAGS="$save_cppflags"
 203
 204      if test x"$xaw_headers" = x"no" ; then
 205         AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
 206      fi
 207
 208      FRONTEND_LIBS="-lXaw"
 209   fi
 210
 211 fi
 212
 213 AC_SUBST(FRONTEND_CFLAGS)
 214 AC_SUBST(FRONTEND_LIBS)
 215
 216 dnl | end Front-end check
 217
 218 AC_CANONICAL_HOST
 219
 220 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
 221 dnl| we are trying to find out whether this is a System-V derivative in
 222 dnl| which pipes don't work with select() and if so, whether there is anything
 223 dnl| strange about the way to open a pty.  Some of the work was done above
 224 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
 225 dnl| properties of particular systems are also handled here.
 226
 227 dnl| 4/6/97 I'm not sure there really are any systems where pipes
 228 dnl| don't work with select(), and ptys cause problems on many
 229 dnl| systems, so I'm changing the default to disable ptys in all
 230 dnl| cases.  I will change it back if I get bug reports that are fixed
 231 dnl| by doing a "configure --enable-ptys"
 232
 233 USE_PTYS=0
 234 case "$host" in
 235   *-*-hpux* )
 236     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 237         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
 238     AC_DEFINE(PTY_NAME_SPRINTF,
 239         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
 240 dnl| USE_PTYS=1
 241     if test "$GCC" = yes; then
 242       CONF_CFLAGS="-fwritable-strings"
 243     else
 244
 245 dnl| Note: You might be able to build xboard even if your compiler does not
 246 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
 247 dnl| know whether the X header files on HP-UX require it.
 248
 249       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
 250     fi
 251
 252 dnl| HP doesn't supply a full set of X header files and libraries.  People
 253 dnl| often have some things installed in one place and some in another.
 254 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
 255 dnl| likely ones that might be missing here.  It might be better to
 256 dnl| change AC_PATH_XTRA to try to extract this information from imake,
 257 dnl| since folks who install the missing bits often configure their
 258 dnl| imake to find them, but I don't want to delve into autoconf and
 259 dnl| hack on its internals.
 260
 261     if test -d /opt/hppd/include/X11; then
 262       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
 263       X_LIBS="$X_LIBS -L/opt/hppd/lib"
 264     elif test -d /usr/contrib/X11R5/include; then
 265       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
 266       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
 267     elif test -d /usr/contrib/mitX11R5/include; then
 268       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
 269       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
 270     elif test -d /MIT/X11R5/include; then
 271       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
 272       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
 273     elif test -d /usr/local/include/X11R5; then
 274       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
 275       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
 276     fi
 277     if test -d /usr/include/X11R5; then
 278       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
 279       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
 280     elif test -d /usr/include/X11R4; then
 281       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
 282       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
 283     fi
 284   ;;
 285
 286   romp-ibm-aix* )
 287     AC_DEFINE(IBMRTAIX, 1)
 288 dnl| USE_PTYS=1
 289   ;;
 290
 291   i386-ibm-aix )
 292 dnl| USE_PTYS=1
 293     if test "$GCC" = yes; then
 294       CONF_CFLAGS="-fwritable-strings"
 295     fi
 296   ;;
 297
 298   *-*-aix3* | *-*-bosx* )
 299     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 300     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 301     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
 302 dnl| USE_PTYS=1
 303   ;;
 304
 305   *-*-cxux* )
 306     AC_DEFINE(FIRST_PTY_LETTER, 'A')
 307     AC_DEFINE(LAST_PTY_LETTER, 'P')
 308 dnl| USE_PTYS=1
 309   ;;
 310
 311   *-*-uniplus* )
 312     AC_DEFINE(UNIPLUS, 1)
 313 dnl| USE_PTYS=1
 314   ;;
 315
 316   *-*-rtu* )
 317     AC_DEFINE(FIRST_PTY_LETTER, 'z')
 318     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 319         [sprintf (pty_name, "/dev/ttyp%x", i);])
 320     AC_DEFINE(PTY_NAME_SPRINTF,
 321         [sprintf (pty_name, "/dev/pty%x", i);])
 322     AC_DEFINE(RTU, 1)
 323 dnl| USE_PTYS=1
 324   ;;
 325
 326   *-*-iris* | *-*-irix3* )
 327     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 328     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 329     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 330         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
 331 dnl| USE_PTYS=1
 332   ;;
 333
 334   *-*-irix* )
 335 dnl| USE_PTYS=1
 336   ;;
 337
 338   *-*-sunos4* | *-*-solaris1* )
 339
 340 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
 341 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
 342 dnl|  "overkill," but doesn't explain what should be done instead.
 343
 344     if test "$GCC" = yes; then
 345       PRE_XMULIB="-static"
 346       POST_XMULIB="-dynamic"
 347     else
 348       PRE_XMULIB="-Bstatic"
 349       POST_XMULIB="-Bdynamic"
 350     fi
 351   ;;
 352
 353   *-*-sunos5* | *-*-solaris2* )
 354 dnl| USE_PTYS=1
 355
 356 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
 357 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
 358 dnl| code above.
 359
 360     X_LIBS="$X_LIBS -lelf"
 361   ;;
 362
 363   *-*-sco* )
 364     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
 365     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
 366     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
 367 dnl| USE_PTYS=1
 368   ;;
 369
 370   *-*-dynix* | *-*-ptx* )
 371 dnl| USE_PTYS=1
 372   ;;
 373
 374   *-*-esix* )
 375 dnl| USE_PTYS=1
 376   ;;
 377
 378   *-*-usg5-4* | *-*-sysvr4* )
 379 dnl| USE_PTYS=1
 380   ;;
 381
 382   *-*-usg* | *-*-sysv* | *-*-aix* )
 383 dnl| USE_PTYS=1
 384   ;;
 385
 386   vax-*-ultrix )
 387     if test "$GCC" = yes; then
 388       CONF_CFLAGS="-fwritable-strings"
 389     fi
 390   ;;
 391
 392 dnl| add some libs for OS X
 393   *-apple-* )
 394   ;;
 395 esac
 396
 397 AC_ARG_ENABLE(  [xpm],
 398                 [AS_HELP_STRING([--enable-xpm],[libXpm will be used if found (default)])],
 399                 [enable_xpm="$enableval"],
 400                 [enable_xpm="yes"])
 401
 402 if test x"$enable_xpm" != "xno"; then
 403   save_cflags="$CFLAGS"
 404   save_cppflags="$CPPFLAGS"
 405   CFLAGS="$CFLAGS $X_CFLAGS"
 406   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 407   AC_CHECK_HEADERS(X11/xpm.h)
 408   CFLAGS="$save_cflags"
 409   CPPFLAGS="$save_cppflags"
 410   if test "$ac_cv_header_X11_xpm_h" = "yes"; then
 411     save_ldflags="$LDFLAGS"
 412     LDFLAGS="$LDFLAGS $X_LIBS"
 413     AC_CHECK_LIB(Xpm, XpmReadFileToPixmap,
 414                  [X_PRE_LIBS="-lXpm $X_PRE_LIBS"; AC_DEFINE(HAVE_LIBXPM)], [],
 415                  [$X_PRE_LIBS -lX11 $X_EXTRA_LIBS])
 416     LDFLAGS="$save_ldflags"
 417   fi
 418 fi
 419
 420 AC_SUBST(PRE_XMULIB)
 421 AC_SUBST(POST_XMULIB)
 422 AC_SUBST(CONF_CFLAGS)
 423 AC_SUBST(CONF_LDFLAGS)
 424
 425 AC_MSG_CHECKING(whether ptys or pipes should be used)
 426 AC_ARG_ENABLE( [ptys],
 427                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
 428 [if test "$enableval" = yes; then
 429   USE_PTYS=1
 430   enable_ptys="ptys"
 431   AC_MSG_RESULT([ptys (user override)])
 432 fi
 433 if test "$enableval" = no; then
 434   USE_PTYS=0
 435   enable_ptys="pipes"
 436   AC_MSG_RESULT([pipes (user override)])
 437 fi],
 438 [if test "$USE_PTYS" = 1; then
 439   AC_MSG_RESULT(ptys)
 440   enable_ptys="ptys"
 441 else
 442   AC_MSG_RESULT(pipes)
 443   enable_ptys="pipes"
 444 fi])
 445 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
 446
 447
 448 dnl | define not to build zippy as a default, so that autoheader is happy
 449 AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
 450 AC_ARG_ENABLE( [zippy],
 451                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
 452                [],
 453                [enable_zippy="yes"])
 454
 455 if test x"$enable_zippy" != xno; then
 456   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
 457 fi
 458 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
 459
 460
 461 AC_ARG_ENABLE(sigint,
 462 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
 463 [if test "$enableval" = yes; then
 464   AC_DEFINE(ATTENTION, 1)
 465 fi
 466 enable_sigint=$enableval
 467 ],
 468 [enable_sigint="yes"
 469 AC_DEFINE(ATTENTION, 1)])
 470
 471
 472 dnl | save all information for X in X_LIBS, also add the libraries themself
 473 dnl | since AC_PATH_XTRA only adds the paths
 474 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
 475 AC_SUBST(X_CFLAGS)
 476 AC_SUBST(X_LIBS)
 477
 478 dnl | should we install desktop icons and mime associations?
 479 AC_ARG_ENABLE(  [update-mimedb],
 480                 [AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]])],
 481                 [enable_mimedb="no"],
 482                 [enable_mimedb="yes"])
 483
 484 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x"$enable_mimedb" = "xyes")
 485
 486 if test x"$enable_mimedb" = "xyes"; then
 487    AC_PATH_PROG([XDG_MIME],[xdg-mime])
 488    AC_SUBST(XDG_MIME)
 489    AC_PATH_PROG([XDG_DESKTOP_MENU],[xdg-desktop-menu])
 490    AC_SUBST(XDG_DESKTOP_MENU)
 491    AC_PATH_PROG([XDG_ICON_RESOURCE],[xdg-icon-resource])
 492    AC_SUBST(XDG_ICON_RESOURCE)
 493 fi
 494
 495 dnl |  output Makefile
 496 AC_CONFIG_FILES([Makefile cmail po/Makefile.in])
 497 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
 498 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
 499 AC_OUTPUT
 500
 501 dnl
 502 dnl Output a summary
 503 dnl
 504 echo ""
 505 echo " Configurations summary:"
 506 echo ""
 507 echo "        prefix:          $prefix       "
 508 echo "        datarootdir:     $datarootdir  "
 509 echo "        datadir:         $datadir   (icons will go in \$datadir/icons/hicolor/...)"
 510 echo "                                    (bitmaps will go in \$datadir/games/xboard/...)"
 511 echo "        infodir:         $infodir   (info files will go here)"
 512 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
 513 echo ""
 514 echo "        update mimedb:   $enable_mimedb"
 515 echo ""
 516 echo "        NLS support:     $USE_NLS"
 517 echo ""
 518 echo "        GTK:             $with_GTK"
 519 echo "        Xaw3d:           $with_Xaw3d"
 520 echo "        Xaw:             $with_Xaw"
 521 echo ""
 522 echo "        xpm:             $enable_xpm"
 523 echo "        ptys:            $enable_ptys"
 524 echo "        zippy:           $enable_zippy"
 525 echo "        sigint:          $enable_sigint"