configure.ac

   1 dnl| configure.in
   2 dnl|
   3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 dnl| 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   5 dnl|
   6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
   7 dnl| it under the terms of the GNU General Public License as published by
   8 dnl| the Free Software Foundation, either version 3 of the License, or (at
   9 dnl| your option) any later version.
  10 dnl|
  11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
  12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 dnl| General Public License for more details.
  15 dnl|
  16 dnl| You should have received a copy of the GNU General Public License
  17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
  18 dnl|
  19 dnl| --------------------------------------------------------------------
  20 dnl|
  21 dnl| You can process this file with autoconf to produce a configure script.
  22 dnl| However, normally the supplied configure script will work fine.
  23 dnl|
  24 dnl| If you do need to change the configure script, instead of editing
  25 dnl| it directly, try to edit configure.in (in a way that will keep
  26 dnl| it portable to sites and systems other than your own), and run autoconf
  27 dnl| to regenerate configure.  Then submit your changes to be folded into
  28 dnl| the standard version of xboard.
  29
  30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
  31 AC_INIT([xboard],[master-20110411],[bug-xboard@gnu.org])
  32
  33 dnl| need this to be able to compile some files in a subdir (filebrowser)
  34 AM_INIT_AUTOMAKE([subdir-objects])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  36
  37 AC_CONFIG_HEADERS([config.h])
  38
  39 dnl | a bunch of templates for defines used below
  40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
  41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
  42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
  43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
  44 AH_TEMPLATE([HAVE_RANDOM],[template])
  45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
  46 AH_TEMPLATE([IBMRTAIX],[template])
  47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
  48 AH_TEMPLATE([PTY_ITERATION],[template])
  49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
  50 AH_TEMPLATE([PTY_OPEN],[template])
  51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
  52 AH_TEMPLATE([REMOTE_SHELL],[template])
  53 AH_TEMPLATE([RTU],[template])
  54 AH_TEMPLATE([UNIPLUS],[template])
  55 AH_TEMPLATE([USE_PTYS],[template])
  56 AH_TEMPLATE([X_WCHAR],[template])
  57 AH_TEMPLATE([ATTENTION],[template])
  58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
  59 AH_TEMPLATE([HAVE_LIBXPM],[template])
  60 AH_TEMPLATE([USE_XAW3D],[template])
  61 AH_TEMPLATE([X_LOCALE],[template])
  62
  63
  64
  65 if test -z "$CFLAGS" ; then
  66 dnl| Prevent the next macro from setting CFLAGS to -g
  67   CFLAGS=" "
  68 fi
  69 AC_PROG_CC
  70
  71 dnl| need this to be able to compile files in a subdir
  72 AM_PROG_CC_C_O
  73
  74 AC_PROG_CPP
  75 AC_ISC_POSIX
  76 AC_PROG_INSTALL
  77
  78 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
  79 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
  80 if test "$MINFO" = makeinfo_not_found ; then
  81    echo Please install \"makeinfo\"
  82    exit 1
  83 fi
  84 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
  85 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
  86 AC_SUBST(NROFFFLAGS)
  87 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
  88 AC_PATH_PROGS(PERLPATH, perl)
  89
  90 AC_HEADER_STDC
  91 AC_HEADER_TIME
  92 AC_HEADER_SYS_WAIT
  93 AC_HEADER_DIRENT
  94 AC_TYPE_SIGNAL
  95 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
  96 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
  97 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
  98 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
  99
 100 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
 101 AC_CHECK_FUNCS(gettimeofday ftime, break)
 102 AC_CHECK_FUNCS(random rand48, break)
 103 AC_CHECK_FUNCS(gethostname sysinfo, break)
 104 AC_CHECK_FUNC(setlocale, [],
 105   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
 106
 107 AC_CHECK_LIB(seq, getpseudotty)
 108
 109
 110 dnl | check for X-libraries
 111 AC_PATH_XTRA
 112 if test -n "$no_x" ; then
 113   echo $PACKAGE requires the X Window System header files and libraries!
 114   echo They were not found on your system.  See FAQ topic C.2.
 115   echo configure failed
 116   exit 1
 117 fi
 118
 119 AC_CHECK_HEADER(X11/Intrinsic.h,xt="yes",xt="no")
 120
 121 if test "$xt" = "no" ; then
 122    echo Xt headers not found
 123    exit 1
 124 fi
 125
 126 dnl | test if user wants ot use Xaw3d or Xaw
 127
 128 dnl | add configure option for Xaw3d
 129 AC_ARG_WITH([Xaw3d],
 130             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d instead of Xaw])],
 131             [],
 132             [with_Xaw3d=no])
 133
 134 dnl | check availability of Xaw3d
 135 XAW_LIBS=
 136 AS_IF([test x"$with_Xaw3d" != x"no"],
 137       [AC_CHECK_LIB([Xaw3d],
 138                     [XawTextReplace],
 139                     [AC_SUBST([XAW_LIBS],["-lXaw3d"])
 140                      AC_DEFINE([USE_XAW3D], [1],
 141                                [Define if you want to use Xaw3d])],
 142                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
 143                                [-lXaw])])
 144 dnl | no Xaw3d, check for Xaw
 145 if test x"$with_Xaw3d" = x"no" ; then
 146    AC_CHECK_HEADER(X11/Xaw/Dialog.h,xaw_headers="yes", xaw_headers="no")
 147    if test x"$xaw_headers" = x"no" ; then
 148       AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
 149    fi
 150    XAW_LIBS="-lXaw"
 151 fi
 152 AC_SUBST(XAW_LIBS)
 153
 154 dnl | end Xaw/Xaw3d test
 155
 156
 157 AC_CANONICAL_HOST
 158
 159 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
 160 dnl| we are trying to find out whether this is a System-V derivative in
 161 dnl| which pipes don't work with select() and if so, whether there is anything
 162 dnl| strange about the way to open a pty.  Some of the work was done above
 163 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
 164 dnl| properties of particular systems are also handled here.
 165
 166 dnl| 4/6/97 I'm not sure there really are any systems where pipes
 167 dnl| don't work with select(), and ptys cause problems on many
 168 dnl| systems, so I'm changing the default to disable ptys in all
 169 dnl| cases.  I will change it back if I get bug reports that are fixed
 170 dnl| by doing a "configure --enable-ptys"
 171
 172 USE_PTYS=0
 173 case "$host" in
 174   *-*-hpux* )
 175     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 176         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
 177     AC_DEFINE(PTY_NAME_SPRINTF,
 178         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
 179 dnl| USE_PTYS=1
 180     if test "$GCC" = yes; then
 181       CONF_CFLAGS="-fwritable-strings"
 182     else
 183
 184 dnl| Note: You might be able to build xboard even if your compiler does not
 185 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
 186 dnl| know whether the X header files on HP-UX require it.
 187
 188       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
 189     fi
 190
 191 dnl| HP doesn't supply a full set of X header files and libraries.  People
 192 dnl| often have some things installed in one place and some in another.
 193 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
 194 dnl| likely ones that might be missing here.  It might be better to
 195 dnl| change AC_PATH_XTRA to try to extract this information from imake,
 196 dnl| since folks who install the missing bits often configure their
 197 dnl| imake to find them, but I don't want to delve into autoconf and
 198 dnl| hack on its internals.
 199
 200     if test -d /opt/hppd/include/X11; then
 201       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
 202       X_LIBS="$X_LIBS -L/opt/hppd/lib"
 203     elif test -d /usr/contrib/X11R5/include; then
 204       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
 205       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
 206     elif test -d /usr/contrib/mitX11R5/include; then
 207       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
 208       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
 209     elif test -d /MIT/X11R5/include; then
 210       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
 211       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
 212     elif test -d /usr/local/include/X11R5; then
 213       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
 214       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
 215     fi
 216     if test -d /usr/include/X11R5; then
 217       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
 218       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
 219     elif test -d /usr/include/X11R4; then
 220       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
 221       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
 222     fi
 223   ;;
 224
 225   romp-ibm-aix* )
 226     AC_DEFINE(IBMRTAIX, 1)
 227 dnl| USE_PTYS=1
 228   ;;
 229
 230   i386-ibm-aix )
 231 dnl| USE_PTYS=1
 232     if test "$GCC" = yes; then
 233       CONF_CFLAGS="-fwritable-strings"
 234     fi
 235   ;;
 236
 237   *-*-aix3* | *-*-bosx* )
 238     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 239     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 240     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
 241 dnl| USE_PTYS=1
 242   ;;
 243
 244   *-*-cxux* )
 245     AC_DEFINE(FIRST_PTY_LETTER, 'A')
 246     AC_DEFINE(LAST_PTY_LETTER, 'P')
 247 dnl| USE_PTYS=1
 248   ;;
 249
 250   *-*-uniplus* )
 251     AC_DEFINE(UNIPLUS, 1)
 252 dnl| USE_PTYS=1
 253   ;;
 254
 255   *-*-rtu* )
 256     AC_DEFINE(FIRST_PTY_LETTER, 'z')
 257     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 258         [sprintf (pty_name, "/dev/ttyp%x", i);])
 259     AC_DEFINE(PTY_NAME_SPRINTF,
 260         [sprintf (pty_name, "/dev/pty%x", i);])
 261     AC_DEFINE(RTU, 1)
 262 dnl| USE_PTYS=1
 263   ;;
 264
 265   *-*-iris* | *-*-irix3* )
 266     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
 267     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
 268     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
 269         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
 270 dnl| USE_PTYS=1
 271   ;;
 272
 273   *-*-irix* )
 274 dnl| USE_PTYS=1
 275   ;;
 276
 277   *-*-sunos4* | *-*-solaris1* )
 278
 279 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
 280 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
 281 dnl|  "overkill," but doesn't explain what should be done instead.
 282
 283     if test "$GCC" = yes; then
 284       PRE_XMULIB="-static"
 285       POST_XMULIB="-dynamic"
 286     else
 287       PRE_XMULIB="-Bstatic"
 288       POST_XMULIB="-Bdynamic"
 289     fi
 290   ;;
 291
 292   *-*-sunos5* | *-*-solaris2* )
 293 dnl| USE_PTYS=1
 294
 295 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
 296 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
 297 dnl| code above.
 298
 299     X_LIBS="$X_LIBS -lelf"
 300   ;;
 301
 302   *-*-sco* )
 303     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
 304     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
 305     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
 306 dnl| USE_PTYS=1
 307   ;;
 308
 309   *-*-dynix* | *-*-ptx* )
 310 dnl| USE_PTYS=1
 311   ;;
 312
 313   *-*-esix* )
 314 dnl| USE_PTYS=1
 315   ;;
 316
 317   *-*-usg5-4* | *-*-sysvr4* )
 318 dnl| USE_PTYS=1
 319   ;;
 320
 321   *-*-usg* | *-*-sysv* | *-*-aix* )
 322 dnl| USE_PTYS=1
 323   ;;
 324
 325   vax-*-ultrix )
 326     if test "$GCC" = yes; then
 327       CONF_CFLAGS="-fwritable-strings"
 328     fi
 329   ;;
 330
 331 dnl| add some libs for OS X
 332   *-apple-* )
 333   ;;
 334 esac
 335
 336 AC_ARG_ENABLE(  [xpm],
 337                 [AS_HELP_STRING([--enable-xpm],[libXpm will be used if found (default)])],
 338                 [enable_xpm="$enableval"],
 339                 [enable_xpm="yes"])
 340
 341 if test x"$enable_xpm" != "xno"; then
 342   save_cflags="$CFLAGS"
 343   CFLAGS="$CFLAGS $X_CFLAGS"
 344   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 345   AC_CHECK_HEADERS(X11/xpm.h)
 346   CFLAGS="$save_cflags"
 347   if test "$ac_cv_header_X11_xpm_h" = "yes"; then
 348     save_ldflags="$LDFLAGS"
 349     LDFLAGS="$LDFLAGS $X_LIBS"
 350     AC_CHECK_LIB(Xpm, XpmReadFileToPixmap,
 351                  [X_PRE_LIBS="-lXpm $X_PRE_LIBS"; AC_DEFINE(HAVE_LIBXPM)], [],
 352                  [$X_PRE_LIBS -lX11 $X_EXTRA_LIBS])
 353     LDFLAGS="$save_ldflags"
 354   fi
 355 fi
 356
 357 AC_SUBST(PRE_XMULIB)
 358 AC_SUBST(POST_XMULIB)
 359 AC_SUBST(CONF_CFLAGS)
 360 AC_SUBST(CONF_LDFLAGS)
 361
 362 AC_MSG_CHECKING(whether ptys or pipes should be used)
 363 AC_ARG_ENABLE( [ptys],
 364                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
 365 [if test "$enableval" = yes; then
 366   USE_PTYS=1
 367   enable_ptys="ptys"
 368   AC_MSG_RESULT([ptys (user override)])
 369 fi
 370 if test "$enableval" = no; then
 371   USE_PTYS=0
 372   enable_ptys="pipes"
 373   AC_MSG_RESULT([pipes (user override)])
 374 fi],
 375 [if test "$USE_PTYS" = 1; then
 376   AC_MSG_RESULT(ptys)
 377   enable_ptys="ptys"
 378 else
 379   AC_MSG_RESULT(pipes)
 380   enable_ptys="pipes"
 381 fi])
 382 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
 383
 384
 385 dnl | define not to build zippy as a default, so that autoheader is happy
 386 AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
 387 AC_ARG_ENABLE( [zippy],
 388                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
 389                [],
 390                [enable_zippy="yes"])
 391
 392 if test x"$enable_zippy" != xno; then
 393   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
 394 fi
 395 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
 396
 397
 398 AC_ARG_ENABLE(sigint,
 399 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
 400 [if test "$enableval" = yes; then
 401   AC_DEFINE(ATTENTION, 1)
 402 fi
 403 enable_sigint=$enableval
 404 ],
 405 [enable_sigint="yes"
 406 AC_DEFINE(ATTENTION, 1)])
 407
 408
 409 dnl | save all information for X in X_LIBS, also add the libraries themself
 410 dnl | since AC_PATH_XTRA only adds the paths
 411 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
 412 AC_SUBST(X_CFLAGS)
 413 AC_SUBST(X_LIBS)
 414
 415
 416 AC_CONFIG_FILES([Makefile cmail])
 417 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
 418 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
 419 AC_OUTPUT
 420
 421 dnl
 422 dnl Output a summary
 423 dnl
 424 echo ""
 425 echo " Configurations summary:"
 426 echo ""
 427 echo "        prefix:          $prefix       "
 428 echo "        datarootdir:     $datarootdir  "
 429 echo "        datadir:         $datadir   (icons will go in \$datadir/icons/hicolor/...)"
 430 echo "                                    (bitmaps will go in \$datadir/games/xboard/...)"
 431 echo "        infodir:         $infodir   (info files will go here)"
 432 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
 433 echo ""
 434 echo "        Xaw3d:           $with_Xaw3d"
 435 echo ""
 436 echo "        xpm:             $enable_xpm"
 437 echo "        ptys:            $enable_ptys"
 438 echo "        zippy:           $enable_zippy"
 439 echo "        sigint:          $enable_sigint"