parser.l

   1 %a 10000
   2 %o 10000
   3 %e 2000
   4 %k 2500
   5 %p 7000
   6 %n 1000
   7 %{
   8 /*
   9  * parser.l -- lex parser of algebraic chess moves for XBoard
  10  *
  11  * Copyright 1991 by Digital Equipment Corporation, Maynard,
  12  * Massachusetts.
  13  *
  14  * Enhancements Copyright 1992-2001, 2002, 2003, 2004, 2005,
  15  * 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
  16  *
  17  * The following terms apply to Digital Equipment Corporation's copyright
  18  * interest in XBoard:
  19  * ------------------------------------------------------------------------
  20  * All Rights Reserved
  21  *
  22  * Permission to use, copy, modify, and distribute this software and its
  23  * documentation for any purpose and without fee is hereby granted,
  24  * provided that the above copyright notice appear in all copies and that
  25  * both that copyright notice and this permission notice appear in
  26  * supporting documentation, and that the name of Digital not be
  27  * used in advertising or publicity pertaining to distribution of the
  28  * software without specific, written prior permission.
  29  *
  30  * DIGITAL DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE, INCLUDING
  31  * ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO EVENT SHALL
  32  * DIGITAL BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR
  33  * ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS,
  34  * WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION,
  35  * ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS
  36  * SOFTWARE.
  37  * ------------------------------------------------------------------------
  38  *
  39  * The following terms apply to the enhanced version of XBoard
  40  * distributed by the Free Software Foundation:
  41  * ------------------------------------------------------------------------
  42  *
  43  * GNU XBoard is free software: you can redistribute it and/or modify
  44  * it under the terms of the GNU General Public License as published by
  45  * the Free Software Foundation, either version 3 of the License, or (at
  46  * your option) any later version.
  47  *
  48  * GNU XBoard is distributed in the hope that it will be useful, but
  49  * WITHOUT ANY WARRANTY; without even the implied warranty of
  50  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  51  * General Public License for more details.
  52  *
  53  * You should have received a copy of the GNU General Public License
  54  * along with this program. If not, see http://www.gnu.org/licenses/.
  55  *
  56  *------------------------------------------------------------------------
  57  ** See the file ChangeLog for a revision history.  */
  58
  59 /* This parser handles all forms of promotion.
  60  * The parser resolves ambiguous moves by searching and check-testing.
  61  * It also parses comments of the form [anything] or (anything).
  62  *
  63  * [HGM] Parser extensively modified for bigger boards, Shogi-like syntax,
  64  * and unknow pieces. All pieces are now mandatory upper case, but can be
  65  * any letter A-Z. Files must be lower case (as before), but can run upto 'l'.
  66  * Ranks can be 0-9. The parser returns 0 for off-board files and ranks.
  67  * For an unknown piece (as mover or promotion piece) it returns
  68  * IllegalMove, like it does when the piece doesn't match.
  69  * Promotions can now also be appended Shogi-style, a bare '=' or '+',
  70  * and this is then returned as promotion character. The piece indicator
  71  * can be prefixed by a '+' to indicate it is a promoted piece.
  72  */
  73
  74 #include "config.h"
  75
  76 #define NO_CONSTRAINT   -1
  77 #undef YYLMAX
  78 #define YYLMAX                  4096
  79 #define UNPUT_BUF_SIZE          YYLMAX
  80
  81 #ifdef FLEX_SCANNER
  82 /* yytext is probably a char*, but could be a char[].  yy_text is set
  83    in YY_DECL below, because if yytext is a char*, its value is not
  84    constant. */
  85 char *yy_text;
  86 #else /*!FLEX_SCANNER*/
  87 /* yytext is definitely a char[], so yy_text can be set here, statically. */
  88 char *yy_text = (char *) yytext;
  89 #endif
  90
  91 #ifdef FLEX_SCANNER
  92 /* This is flex */
  93 /* [AP] use prototypes in function declarations */
  94 #define YY_USE_PROTOS
  95
  96 #ifdef YY_USE_PROTOS
  97 #define YY_PROTO(proto) proto
  98 #else
  99 #define YY_PROTO(proto) ()
 100 #endif
 101 /* end of [AP] fix */
 102
 103 #undef YY_INPUT
 104 #define YY_INPUT(buf, result, max_size) my_yy_input(buf, &result, max_size)
 105 #undef YY_DECL
 106 #define YY_DECL                     \
 107     int _yylex YY_PROTO((void));    \
 108     int yylex YY_PROTO((void))      \
 109     {                               \
 110         int result = _yylex();      \
 111         yy_text = (char *) yytext;  \
 112         return(result);             \
 113     }                               \
 114     int _yylex YY_PROTO((void))
 115 #else
 116 /* This is lex */
 117 #undef input
 118 #undef output
 119 #undef unput
 120 #endif
 121
 122 /* The includes must be here, below the #undef input */
 123
 124 #include <ctype.h>
 125
 126 #if STDC_HEADERS
 127 # include <stdlib.h>
 128 # include <string.h>
 129 #else /* not STDC_HEADERS */
 130 # if HAVE_STRING_H
 131 #  include <string.h>
 132 # else /* not HAVE_STRING_H */
 133 #  include <strings.h>
 134 # endif /* not HAVE_STRING_H */
 135 #endif /* not STDC_HEADERS */
 136
 137 #if HAVE_UNISTD_H
 138 # include <unistd.h>
 139 #endif
 140
 141 #if defined(_amigados)
 142 # include <errno.h>
 143 # if HAVE_FCNTL_H
 144 #  include <fcntl.h>    /*  isatty() prototype  */
 145 # endif /*  HAVE_FCNTL_H        */
 146 #endif  /*  defined(_amigados)  */
 147
 148 #include "common.h"
 149 #include "backend.h"
 150 #include "frontend.h"
 151 #include "parser.h"
 152 #include "moves.h"
 153
 154 extern int PosFlags P((int));
 155
 156 extern Board    boards[MAX_MOVES];
 157 int             yyboardindex;
 158 int             yyskipmoves = FALSE;
 159 char            currentMoveString[YYLMAX];
 160 #ifndef FLEX_SCANNER
 161 char            unputBuffer[UNPUT_BUF_SIZE];
 162 int             unputCount = 0;
 163 #endif
 164
 165 #ifdef FLEX_SCANNER
 166 void my_yy_input P((char *buf, int *result, int max_size));
 167 #else /*!FLEX_SCANNER*/
 168 static int input P((void));
 169 static void output P((int ch));
 170 static void unput P((int ch));
 171 int yylook P((void));
 172 int yyback P((int *, int));
 173 #endif
 174 #undef yywrap
 175 int yywrap P((void));
 176 extern void CopyBoard P((Board to, Board from));
 177
 178 %}
 179 %%
 180
 181 "+"?[A-Z][/]?[a-l][0-9][xX:-]?[a-l][0-9]((=?\(?[A-Z]\)?)|=)? {
 182     /*
 183      * Fully-qualified algebraic move, possibly with promotion
 184      */
 185     int skip1 = 0, skip2 = 0, skip3 = 0, promoted = 0;
 186     ChessSquare piece;
 187     ChessMove result;
 188     char c;
 189
 190     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 191
 192     if (yytext[0] == '+') skip1 = skip3 = promoted = 1; /* [HGM] Shogi promoted */
 193
 194     /* remove the / */
 195     if (yytext[1+skip1] == '/')  skip1++;
 196
 197     /* remove the [xX:-] */
 198     if ((yytext[3+skip1] == 'x') || (yytext[3+skip1] == 'X') ||
 199         (yytext[3+skip1] == '-') || (yytext[3+skip1] == ':')) skip2 = 1;
 200
 201     currentMoveString[0] = yytext[1+skip1];
 202     currentMoveString[1] = yytext[2+skip1];
 203     currentMoveString[2] = yytext[3+skip1+skip2];
 204     currentMoveString[3] = yytext[4+skip1+skip2];
 205     currentMoveString[4] = NULLCHAR;
 206
 207     if (appData.debugMode) {
 208         fprintf(debugFP, "Parser Qa1b2: yyleng=%d\n",
 209         yyleng);
 210     }
 211
 212     if (yyleng-skip1-skip2 > 5) { char c;
 213         if (yytext[yyleng-1] == ')') {
 214             c = currentMoveString[4] = ToLower(yytext[yyleng-2]);
 215         } else {
 216             c = currentMoveString[4] = ToLower(yytext[yyleng-1]);
 217         }
 218         currentMoveString[5] = NULLCHAR;
 219         if(c != '=' && c != '+' && CharToPiece(c) == EmptySquare)
 220             return IllegalMove; /* [HGM] promotion to invalid piece */
 221     }
 222
 223     if (appData.debugMode) {
 224         fprintf(debugFP, "parser: %s\n", currentMoveString);
 225     }
 226     /* [HGM] do not allow values beyond board size */
 227     if(currentMoveString[1] - ONE >= BOARD_HEIGHT ||
 228        currentMoveString[1] - ONE <  0            ||
 229        currentMoveString[0] - AAA >= BOARD_RGHT   ||
 230        currentMoveString[3] - ONE >= BOARD_HEIGHT ||
 231        currentMoveString[3] - ONE <  0            ||
 232        currentMoveString[2] - AAA >= BOARD_RGHT   ||
 233        currentMoveString[0] - AAA <  BOARD_LEFT   ||
 234        currentMoveString[2] - AAA <  BOARD_LEFT     )
 235       return ImpossibleMove;
 236
 237     piece = boards[yyboardindex]
 238       [currentMoveString[1] - ONE][currentMoveString[0] - AAA];
 239     if(PieceToChar(piece) == '+' && appData.icsActive) promoted = 1, yytext[skip3] = PieceToChar(DEMOTED piece); // trust ICS
 240     if(promoted) piece = (ChessSquare) (DEMOTED piece);
 241     c = PieceToChar(piece);
 242     if(c == '~') c = PieceToChar((ChessSquare) (DEMOTED piece));
 243     if (ToLower(yytext[skip3]) != ToLower(c))
 244       return (int) IllegalMove;
 245
 246     result = LegalityTest(boards[yyboardindex],
 247                           PosFlags(yyboardindex)&~F_MANDATORY_CAPTURE, // [HGM] losers: might think we can e.p.!
 248                           currentMoveString[1] - ONE,
 249                           currentMoveString[0] - AAA,
 250                           currentMoveString[3] - ONE,
 251                           currentMoveString[2] - AAA,
 252                           currentMoveString[4]);
 253
 254     if (currentMoveString[4] == NULLCHAR &&
 255         (result == WhitePromotion  || result == BlackPromotion)) {
 256         if(gameInfo.variant == VariantCourier || gameInfo.variant == VariantShatranj)
 257             currentMoveString[4] = PieceToChar(BlackFerz);
 258         else if(gameInfo.variant == VariantGreat)
 259             currentMoveString[4] = PieceToChar(BlackMan);
 260         else if(gameInfo.variant == VariantShogi)
 261             currentMoveString[4] = '+';
 262         else
 263             currentMoveString[4] = PieceToChar(BlackQueen);
 264         currentMoveString[5] = NULLCHAR;
 265     }
 266
 267     return (int) result;
 268 }
 269
 270 [a-l][0-9][xX:-]?[a-l][0-9]((=?\(?[A-Za-z]\)?)|=)?      {
 271     /*
 272      * Simple algebraic move, possibly with promotion
 273      * [HGM] Engine moves are received in this format, with lower-case promoChar!
 274      */
 275     int skip = 0;
 276     ChessMove result;
 277
 278     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 279
 280     /* remove the [xX:-] */
 281     if ((yytext[2] == 'x') || (yytext[2] == 'X') ||
 282         (yytext[2] == '-') || (yytext[2] == ':')) skip = 1;
 283
 284     currentMoveString[0] = yytext[0];
 285     currentMoveString[1] = yytext[1];
 286     currentMoveString[2] = yytext[2+skip];
 287     currentMoveString[3] = yytext[3+skip];
 288     currentMoveString[4] = NULLCHAR;
 289
 290     if (yyleng-skip > 4) { char c;
 291         if (yytext[yyleng-1] == ')') {
 292             c = currentMoveString[4] = ToLower(yytext[yyleng-2]);
 293         } else {
 294             c = currentMoveString[4] = ToLower(yytext[yyleng-1]);
 295         }
 296         currentMoveString[5] = NULLCHAR;
 297         if(c != '=' && c != '+' && CharToPiece(c) == EmptySquare)
 298             return IllegalMove;
 299     }
 300
 301     /* [HGM] do not allow values beyond board size */
 302     if(currentMoveString[1] - ONE >= BOARD_HEIGHT ||
 303        currentMoveString[1] - ONE <  0            ||
 304        currentMoveString[0] - AAA >= BOARD_RGHT   ||
 305        currentMoveString[3] - ONE >= BOARD_HEIGHT ||
 306        currentMoveString[3] - ONE <  0            ||
 307        currentMoveString[2] - AAA >= BOARD_RGHT   ||
 308        currentMoveString[0] - AAA <  BOARD_LEFT   ||
 309        currentMoveString[2] - AAA <  BOARD_LEFT     )
 310       return ImpossibleMove;
 311
 312     result = LegalityTest(boards[yyboardindex],
 313                           PosFlags(yyboardindex)&~F_MANDATORY_CAPTURE, // [HGM] losers: might think we can e.p.!
 314                           currentMoveString[1] - ONE,
 315                           currentMoveString[0] - AAA,
 316                           currentMoveString[3] - ONE,
 317                           currentMoveString[2] - AAA,
 318                           currentMoveString[4]);
 319
 320     if (currentMoveString[4] == NULLCHAR) {
 321       if(result == WhitePromotion  || result == BlackPromotion) {
 322         if(gameInfo.variant == VariantShatranj || gameInfo.variant == VariantCourier || gameInfo.variant == VariantMakruk)
 323             currentMoveString[4] = PieceToChar(BlackFerz);
 324         else if(gameInfo.variant == VariantGreat)
 325             currentMoveString[4] = PieceToChar(BlackMan);
 326         else if(gameInfo.variant == VariantShogi)
 327             currentMoveString[4] = '+'; // Queen might not be defined in mini variants!
 328         else
 329             currentMoveString[4] = PieceToChar(BlackQueen);
 330         currentMoveString[5] = NULLCHAR;
 331       }
 332     } else if(appData.testLegality && // strip off unnecessary and false promo characters
 333        !(result == WhitePromotion  || result == BlackPromotion ||
 334          result == WhiteNonPromotion || result == BlackNonPromotion)) currentMoveString[4] = NULLCHAR;
 335
 336     return (int) result;
 337 }
 338
 339 [A-L][0-9][xX:-]?[A-L][0-9]      {
 340     /*
 341      * Simple algebraic move, in capitals
 342      * [HGM] Engine moves are received in this format, with lower-case promoChar!
 343      */
 344     int skip = 0;
 345     ChessMove result;
 346
 347     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 348
 349     /* remove the [xX:-] */
 350     if ((yytext[2] == 'x') || (yytext[2] == 'X') ||
 351         (yytext[2] == '-') || (yytext[2] == ':')) skip = 1;
 352
 353     currentMoveString[0] = yytext[0]+32;
 354     currentMoveString[1] = yytext[1];
 355     currentMoveString[2] = yytext[2+skip]+32;
 356     currentMoveString[3] = yytext[3+skip];
 357     currentMoveString[4] = NULLCHAR;
 358
 359     /* [HGM] do not allow values beyond board size */
 360     if(currentMoveString[1] - ONE >= BOARD_HEIGHT ||
 361        currentMoveString[1] - ONE <  0            ||
 362        currentMoveString[0] - AAA >= BOARD_RGHT   ||
 363        currentMoveString[3] - ONE >= BOARD_HEIGHT ||
 364        currentMoveString[3] - ONE <  0            ||
 365        currentMoveString[2] - AAA >= BOARD_RGHT   ||
 366        currentMoveString[0] - AAA <  BOARD_LEFT   ||
 367        currentMoveString[2] - AAA <  BOARD_LEFT     )
 368       return ImpossibleMove;
 369
 370     result = LegalityTest(boards[yyboardindex],
 371                           PosFlags(yyboardindex)&~F_MANDATORY_CAPTURE, // [HGM] losers: might think we can e.p.!
 372                           currentMoveString[1] - ONE,
 373                           currentMoveString[0] - AAA,
 374                           currentMoveString[3] - ONE,
 375                           currentMoveString[2] - AAA,
 376                           currentMoveString[4]);
 377
 378     if (currentMoveString[4] == NULLCHAR &&
 379         (result == WhitePromotion  || result == BlackPromotion)) {
 380         if(gameInfo.variant == VariantShatranj || gameInfo.variant == VariantCourier || gameInfo.variant == VariantMakruk)
 381             currentMoveString[4] = PieceToChar(BlackFerz);
 382         else if(gameInfo.variant == VariantGreat)
 383             currentMoveString[4] = PieceToChar(BlackMan);
 384         else
 385             currentMoveString[4] = PieceToChar(BlackQueen);
 386         currentMoveString[5] = NULLCHAR;
 387     }
 388
 389     return (int) result;
 390 }
 391
 392 [a-l][0-9]((=?\(?[A-Za-z]\)?)|=)?       {
 393     /*
 394      * Pawn move, possibly with promotion
 395      */
 396     DisambiguateClosure cl;
 397     int skip = 0; char c;
 398
 399     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 400
 401     /* remove the =() */
 402     if (yytext[2] == '=' && yytext[3] != NULLCHAR) skip++;
 403     if (yytext[2+skip] == '(') skip++;
 404
 405     cl.pieceIn = WhiteOnMove(yyboardindex) ? WhitePawn : BlackPawn;
 406     cl.rfIn = -1;
 407     cl.ffIn = yytext[0] - AAA;
 408     cl.rtIn = yytext[1] - ONE;
 409     cl.ftIn = yytext[0] - AAA;
 410     c = cl.promoCharIn = ToLower(yytext[2+skip]);
 411
 412     /* [HGM] do not allow values beyond board size */
 413     if(cl.rtIn >= BOARD_HEIGHT ||
 414        cl.rtIn <  0            ||
 415        cl.ffIn >= BOARD_RGHT   ||
 416        cl.ftIn <  BOARD_LEFT     )
 417       return ImpossibleMove;
 418
 419     if(c != '=' && c != '+' && c != NULLCHAR && CharToPiece(c) == EmptySquare)
 420       return IllegalMove;
 421
 422
 423     Disambiguate(boards[yyboardindex], PosFlags(yyboardindex), &cl);
 424
 425     currentMoveString[0] = cl.ff + AAA;
 426     currentMoveString[1] = cl.rf + ONE;
 427     currentMoveString[2] = cl.ft + AAA;
 428     currentMoveString[3] = cl.rt + ONE;
 429     currentMoveString[4] = cl.promoChar;
 430     currentMoveString[5] = NULLCHAR;
 431
 432     return (int) cl.kind;
 433 }
 434
 435
 436 (ab|bc|cd|de|ef|fg|gh|hi|ij|jk|kl|lk|kj|ji|ih|hg|gf|fe|ed|dc|cb|ba|aa|bb|cc|dd|ee|ff|gg|hh|ii|jj|kk|ll|([a-l][xX:-][a-l]))((=?\(?[A-Z]\)?)|ep|"e.p."|=)? {
 437     /*
 438      * Pawn capture, possibly with promotion, possibly ambiguous
 439      */
 440     DisambiguateClosure cl;
 441     int skip1 = 0, skip2 = 0; char c;
 442
 443     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 444
 445     /* remove trailing ep or e.p. (nonstandard PGN) */
 446     if (yytext[yyleng-1] == 'p') {
 447       yyleng -= 2;
 448       yytext[yyleng] = NULLCHAR;
 449     } else if (yytext[yyleng-1] == '.') {
 450       yyleng -= 4;
 451       yytext[yyleng] = NULLCHAR;
 452     }
 453
 454     /* remove the [xX:-] and =() */
 455     if ((yytext[1] == 'x') || (yytext[1] == 'X')
 456         || (yytext[1] == ':') || (yytext[1] == '-')) skip1 = 1;
 457     if (yytext[2+skip1] == '=' && yytext[3+skip1] != NULLCHAR) skip2++;
 458     if (yytext[2+skip1+skip2] == '(') skip2++;
 459
 460     cl.pieceIn = WhiteOnMove(yyboardindex) ? WhitePawn : BlackPawn;
 461     cl.rfIn = -1;
 462     cl.ffIn = yytext[0] - AAA;
 463     cl.rtIn = -1;
 464     cl.ftIn = yytext[1+skip1] - AAA;
 465     c = cl.promoCharIn = yytext[2+skip1+skip2];
 466
 467     /* [HGM] do not allow values beyond board size */
 468     if(cl.ffIn >= BOARD_RGHT  ||
 469        cl.ffIn <  BOARD_LEFT  ||
 470        cl.ftIn >= BOARD_RGHT  ||
 471        cl.ftIn <  BOARD_LEFT     )
 472       return ImpossibleMove;
 473
 474     if(c != '=' && c != '+' && c != NULLCHAR && CharToPiece(c) == EmptySquare)
 475       return IllegalMove;
 476
 477     Disambiguate(boards[yyboardindex], PosFlags(yyboardindex), &cl);
 478
 479     currentMoveString[0] = cl.ff + AAA;
 480     currentMoveString[1] = cl.rf + ONE;
 481     currentMoveString[2] = cl.ft + AAA;
 482     currentMoveString[3] = cl.rt + ONE;
 483     currentMoveString[4] = cl.promoChar;
 484     currentMoveString[5] = NULLCHAR;
 485
 486     return (int) cl.kind;
 487 }
 488
 489 [a-l][xX:]?[a-l][0-9]((=?\(?[A-Z]\)?)|ep|"e.p."|=)? {
 490     /*
 491      * unambiguously abbreviated Pawn capture, possibly with promotion
 492      */
 493     int skip = 0;
 494     ChessMove result; char c;
 495
 496     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 497
 498     /* remove trailing ep or e.p. (nonstandard PGN) */
 499     if (yytext[yyleng-1] == 'p') {
 500       yyleng -= 2;
 501       yytext[yyleng] = NULLCHAR;
 502     } else if (yytext[yyleng-1] == '.') {
 503       yyleng -= 4;
 504       yytext[yyleng] = NULLCHAR;
 505     }
 506
 507     /* remove the [xX:-] */
 508     if ((yytext[1] == 'x') || (yytext[1] == 'X')
 509         || (yytext[1] == ':') || (yytext[1] == '-')) skip = 1;
 510
 511     currentMoveString[0] = yytext[0];
 512     currentMoveString[2] = yytext[1+skip];
 513     currentMoveString[3] = yytext[2+skip];
 514
 515     /* [HGM] do not allow values beyond board size */
 516     if(currentMoveString[0] - AAA >= BOARD_RGHT   ||
 517        currentMoveString[3] - ONE >= BOARD_HEIGHT ||
 518        currentMoveString[3] - ONE <  0            ||
 519        currentMoveString[2] - AAA >= BOARD_RGHT   ||
 520        currentMoveString[0] - AAA <  BOARD_LEFT   ||
 521        currentMoveString[2] - AAA <  BOARD_LEFT     )
 522       return ImpossibleMove;
 523
 524     if (gameInfo.variant == VariantXiangqi && /* [HGM] In Xiangqi rank stays same */
 525          currentMoveString[0] != currentMoveString[2] ) {
 526         currentMoveString[1] = yytext[2+skip];
 527     } else
 528     if (WhiteOnMove(yyboardindex)) {
 529         if (yytext[2+skip] == ONE) return (int) ImpossibleMove;
 530         currentMoveString[1] = yytext[2+skip] - 1;
 531         if(boards[yyboardindex][currentMoveString[1]-ONE][currentMoveString[0]-AAA] != WhitePawn)
 532                 return ImpossibleMove;
 533     } else {
 534         currentMoveString[1] = currentMoveString[3] + 1;
 535         if (currentMoveString[3] == ONE+BOARD_HEIGHT-1) return (int) ImpossibleMove;
 536         if(boards[yyboardindex][currentMoveString[1]-ONE][currentMoveString[0]-AAA] != BlackPawn)
 537                 return ImpossibleMove;
 538     }
 539     if (yyleng-skip > 3) {
 540         if (yytext[yyleng-1] == ')')
 541           c = currentMoveString[4] = ToLower(yytext[yyleng-2]);
 542         else
 543           c = currentMoveString[4] = ToLower(yytext[yyleng-1]);
 544         currentMoveString[5] = NULLCHAR;
 545         if(c != '=' && c != '+' && CharToPiece(c) == EmptySquare)
 546             return IllegalMove;
 547     } else {
 548         currentMoveString[4] = NULLCHAR;
 549     }
 550
 551     result = LegalityTest(boards[yyboardindex],
 552                           PosFlags(yyboardindex)&~F_MANDATORY_CAPTURE, // [HGM] losers: might think we can e.p.!
 553                           currentMoveString[1] - ONE,
 554                           currentMoveString[0] - AAA,
 555                           currentMoveString[3] - ONE,
 556                           currentMoveString[2] - AAA,
 557                           currentMoveString[4]);
 558
 559     if (currentMoveString[4] == NULLCHAR &&
 560         (result == WhitePromotion  || result == BlackPromotion)) {
 561         currentMoveString[4] = PieceToChar(BlackQueen);
 562         // [HGM] shatranj: take care of variants without Queen
 563         if(gameInfo.variant == VariantShatranj || gameInfo.variant == VariantCourier || gameInfo.variant == VariantMakruk)
 564             currentMoveString[4] = PieceToChar(BlackFerz);
 565         if(gameInfo.variant == VariantGreat)
 566             currentMoveString[4] = PieceToChar(BlackMan);
 567         currentMoveString[5] = NULLCHAR;
 568     }
 569
 570     if (result != IllegalMove) return (int) result;
 571
 572     /* Special case: improperly written en passant capture */
 573     if (WhiteOnMove(yyboardindex)) {
 574         if (currentMoveString[3] == '5') {
 575             currentMoveString[1] = '5';
 576             currentMoveString[3] = '6';
 577         } else {
 578             return (int) IllegalMove;
 579         }
 580     } else {
 581         if (currentMoveString[3] == '4') {
 582             currentMoveString[1] = '4';
 583             currentMoveString[3] = '3';
 584         } else {
 585             return (int) IllegalMove;
 586         }
 587     }
 588
 589     result = LegalityTest(boards[yyboardindex],
 590                           PosFlags(yyboardindex)&~F_MANDATORY_CAPTURE, // [HGM] losers: might think we can e.p.!
 591                           currentMoveString[1] - ONE,
 592                           currentMoveString[0] - AAA,
 593                           currentMoveString[3] - ONE,
 594                           currentMoveString[2] - AAA,
 595                           currentMoveString[4]);
 596
 597     if (result == WhiteCapturesEnPassant || result == BlackCapturesEnPassant)
 598       return (int) result;
 599     else
 600       return (int) IllegalMove;
 601 }
 602
 603 "+"?[A-Z][xX:-]?[a-l][0-9]=?  {
 604     /*
 605      * piece move, possibly ambiguous
 606      */
 607     DisambiguateClosure cl;
 608     int skip = 0, skip2 = 0, promoted = 0;
 609
 610     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 611
 612     if(yytext[0] == '+') promoted = skip = skip2 = 1;
 613
 614     /* remove the [xX:-] */
 615     if ((yytext[1+skip] == 'x') || (yytext[1+skip] == 'X')
 616         || (yytext[1+skip] == ':') || (yytext[1+skip] == '-')) skip++;
 617
 618     if (WhiteOnMove(yyboardindex)) {
 619         cl.pieceIn = CharToPiece(ToUpper(yytext[skip2]));
 620     } else {
 621         cl.pieceIn = CharToPiece(ToLower(yytext[skip2]));
 622     }
 623     if(promoted) cl.pieceIn = (ChessSquare) (PROMOTED cl.pieceIn);
 624
 625     cl.rfIn = -1;
 626     cl.ffIn = -1;
 627     cl.rtIn = yytext[2+skip] - ONE;
 628     cl.ftIn = yytext[1+skip] - AAA;
 629     cl.promoCharIn = NULLCHAR;
 630
 631     if(yyleng-skip > 3) /* [HGM] can have Shogi-style promotion */
 632         cl.promoCharIn = yytext[yyleng-1];
 633
 634     if (appData.debugMode) {
 635         fprintf(debugFP, "Parser Qa1: yyleng=%d,  %d(%d,%d)-(%d,%d) = %d (%c)\n",
 636         yyleng,
 637         cl.pieceIn,cl.ffIn,cl.rfIn,cl.ftIn,cl.rtIn,cl.promoCharIn,cl.promoCharIn?cl.promoCharIn:' ');
 638     }
 639
 640     /* [HGM] but do not allow values beyond board size */
 641     if(cl.rtIn >= BOARD_HEIGHT ||
 642        cl.rtIn <  0            ||
 643        cl.ftIn >= BOARD_RGHT   ||
 644        cl.ftIn <  BOARD_LEFT     )
 645       return ImpossibleMove;
 646
 647     Disambiguate(boards[yyboardindex], PosFlags(yyboardindex), &cl);
 648
 649     currentMoveString[0] = cl.ff + AAA;
 650     currentMoveString[1] = cl.rf + ONE;
 651     currentMoveString[2] = cl.ft + AAA;
 652     currentMoveString[3] = cl.rt + ONE;
 653     currentMoveString[4] = cl.promoChar;
 654     currentMoveString[5] = NULLCHAR;
 655
 656     return (int) cl.kind;
 657 }
 658
 659 "+"?[A-Z][a-l0-9][xX:-]?[a-l][0-9]=?   {
 660     /*
 661      * piece move with rank or file disambiguator
 662      */
 663     DisambiguateClosure cl;
 664     int skip = 0, skip2 = 0; int promoted=0;
 665
 666     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 667
 668     if(yytext[0]=='+') promoted = skip = skip2 = 1;
 669
 670     /* remove the [xX:-] */
 671     if ((yytext[2+skip] == 'x') || (yytext[2+skip] == 'X')
 672         || (yytext[2+skip] == ':') || (yytext[2+skip] == '-')) skip++;
 673
 674     if (WhiteOnMove(yyboardindex)) {
 675         cl.pieceIn = CharToPiece(ToUpper(yytext[skip2]));
 676     } else {
 677         cl.pieceIn = CharToPiece(ToLower(yytext[skip2]));
 678     }
 679     if(promoted) cl.pieceIn = (ChessSquare) (PROMOTED cl.pieceIn);
 680
 681     if (isalpha(yytext[1+skip2])) {
 682         cl.rfIn = -1;
 683         cl.ffIn = yytext[1+skip2] - AAA;
 684
 685         if(cl.ffIn >= BOARD_RGHT ||
 686            cl.ffIn <  BOARD_LEFT   ) return 0;
 687     } else {
 688         cl.rfIn = yytext[1+skip2] - ONE;
 689         cl.ffIn = -1;
 690         if(cl.rfIn >= BOARD_HEIGHT ||
 691            cl.rfIn <  0) return 0;
 692     }
 693     cl.rtIn = yytext[3+skip] - ONE;
 694     cl.ftIn = yytext[2+skip] - AAA;
 695     cl.promoCharIn = NULLCHAR;
 696
 697     if(yyleng-skip > 4) /* [HGM] can have Shogi-style promotion */
 698         cl.promoCharIn = yytext[yyleng-1];
 699
 700     /* [HGM] do not allow values beyond board size */
 701     if(cl.rtIn >= BOARD_HEIGHT ||
 702        cl.rtIn <  0            ||
 703        cl.ftIn >= BOARD_RGHT   ||
 704        cl.ftIn <  BOARD_LEFT     )
 705       return ImpossibleMove;
 706
 707     Disambiguate(boards[yyboardindex], PosFlags(yyboardindex), &cl);
 708
 709     currentMoveString[0] = cl.ff + AAA;
 710     currentMoveString[1] = cl.rf + ONE;
 711     currentMoveString[2] = cl.ft + AAA;
 712     currentMoveString[3] = cl.rt + ONE;
 713     currentMoveString[4] = cl.promoChar;
 714     currentMoveString[5] = NULLCHAR;
 715
 716     return (int) cl.kind;
 717 }
 718
 719 000|0-0-0|ooo|OOO|o-o-o|O-O-O   {
 720     int rf, ff, rt, ft;
 721
 722     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 723
 724     /* [HGM] all squares referenced to board edges in stead of absolute */
 725     if (WhiteOnMove(yyboardindex)) {
 726         if (boards[yyboardindex][0][(BOARD_WIDTH-1)>>1] == WhiteKing) {
 727             /* ICS wild castling */
 728             rf = 0;
 729             ff = (BOARD_WIDTH-1)>>1;
 730             rt = 0;
 731             ft = BOARD_RGHT-3;
 732         } else {
 733             rf = 0;
 734             ff = BOARD_WIDTH>>1;
 735             rt = 0;
 736             ft = BOARD_LEFT+2;
 737         }
 738     } else{
 739         if (boards[yyboardindex][BOARD_HEIGHT-1][(BOARD_WIDTH-1)>>1] == BlackKing) {
 740             /* ICS wild castling */
 741             rf = BOARD_HEIGHT-1;
 742             ff = (BOARD_WIDTH-1)>>1;
 743             rt = BOARD_HEIGHT-1;
 744             ft = BOARD_RGHT-3;
 745         } else {
 746             rf = BOARD_HEIGHT-1;
 747             ff = BOARD_WIDTH>>1;
 748             rt = BOARD_HEIGHT-1;
 749             ft = BOARD_LEFT+2;
 750         }
 751     }
 752     if(PosFlags(0) & F_FRC_TYPE_CASTLING) {
 753
 754         if (WhiteOnMove(yyboardindex)) {
 755             ff = initialRights[2];
 756             ft = initialRights[1];
 757         } else {
 758             ff = initialRights[5];
 759             ft = initialRights[4];
 760         }
 761         if (appData.debugMode)
 762         {
 763           fprintf(debugFP, "Parser FRC long %d %d\n", ff, ft);
 764         };
 765         if(ff < 0 || ft < 0) return 0;
 766     }
 767     sprintf(currentMoveString, "%c%c%c%c",ff+AAA,rf+ONE,ft+AAA,rt+ONE);
 768     if (appData.debugMode) {
 769         fprintf(debugFP, "long castling %d %d\n", ff, ft);
 770     }
 771     return (int) LegalityTest(boards[yyboardindex],
 772                               PosFlags(yyboardindex)&~F_MANDATORY_CAPTURE, // [HGM] losers: e.p.!
 773                               rf, ff, rt, ft, NULLCHAR);
 774 }
 775
 776 00|0-0|oo|OO|o-o|O-O    {
 777     int rf, ff, rt, ft;
 778
 779     if (yyskipmoves) return (int) AmbiguousMove; /* not disambiguated */
 780
 781     if (WhiteOnMove(yyboardindex)) {
 782         if (boards[yyboardindex][0][(BOARD_WIDTH-1)>>1] == WhiteKing) {
 783             /* ICS wild castling */
 784             rf = 0;
 785             ff = (BOARD_WIDTH-1)>>1;
 786             rt = 0;
 787             ft = BOARD_LEFT+1;
 788         } else {
 789             rf = 0;
 790             ff = BOARD_WIDTH>>1;
 791             rt = 0;
 792             ft = BOARD_RGHT-2;
 793         }
 794     } else {
 795         if (boards[yyboardindex][BOARD_HEIGHT-1][(BOARD_WIDTH-1)>>1] == BlackKing) {
 796             /* ICS wild castling */
 797             rf = BOARD_HEIGHT-1;
 798             ff = (BOARD_WIDTH-1)>>1;
 799             rt = BOARD_HEIGHT-1;
 800             ft = BOARD_LEFT+1;
 801         } else {
 802             rf = BOARD_HEIGHT-1;
 803             ff = BOARD_WIDTH>>1;
 804             rt = BOARD_HEIGHT-1;
 805             ft = BOARD_RGHT-2;
 806         }
 807     }
 808     if(PosFlags(0) & F_FRC_TYPE_CASTLING) {
 809         if (WhiteOnMove(yyboardindex)) {
 810             ff = initialRights[2];
 811             ft = initialRights[0];
 812         } else {
 813             ff = initialRights[5];
 814             ft = initialRights[3];
 815         }
 816     if (appData.debugMode) {
 817         fprintf(debugFP, "Parser FRC short %d %d\n", ff, ft);
 818     }
 819         if(ff < 0 || ft < 0) return 0;
 820     }
 821     sprintf(currentMoveString, "%c%c%c%c",ff+AAA,rf+ONE,ft+AAA,rt+ONE);
 822     if (appData.debugMode) {
 823         fprintf(debugFP, "short castling %d %d\n", ff, ft);
 824     }
 825
 826     return (int) LegalityTest(boards[yyboardindex],
 827                               PosFlags(yyboardindex)&~F_MANDATORY_CAPTURE, // [HGM] losers: e.p.!
 828                               rf, ff, rt, ft, NULLCHAR);
 829 }
 830
 831 [A-Z][@*][a-l][0-9] {
 832     /* Bughouse piece drop. */
 833     currentMoveString[1] = '@';
 834     currentMoveString[2] = yytext[2];
 835     currentMoveString[3] = yytext[3];
 836     currentMoveString[4] = NULLCHAR;
 837
 838     if (appData.debugMode) {
 839         fprintf(debugFP, "Drop: %s\n", currentMoveString);
 840     }
 841     /* [HGM] do not allow values beyond board size */
 842     if(currentMoveString[3] - ONE >= BOARD_HEIGHT ||
 843        currentMoveString[2] - AAA >= BOARD_WIDTH     )
 844       return ImpossibleMove;
 845
 846     if (WhiteOnMove(yyboardindex)) {
 847         currentMoveString[0] = ToUpper(yytext[0]);
 848     } else {
 849         currentMoveString[0] = ToLower(yytext[0]);
 850     }
 851     return LegalityTest(boards[yyboardindex], PosFlags(yyboardindex), DROP_RANK, // [HGM] does drops now too
 852                         CharToPiece(currentMoveString[0]), currentMoveString[3] - ONE, currentMoveString[2] - AAA, NULLCHAR);
 853 }
 854
 855 [Rr]esign(s|ed)?  {
 856     if (WhiteOnMove(yyboardindex))
 857       return (int) BlackWins;
 858     else
 859       return (int) WhiteWins;
 860 }
 861
 862 (([Ww](hite)?)|([Bb](lack)?))" "(([Rr]esign)|([Ff]orfeit))(s|ed)?  {
 863     return (int) (ToUpper(yytext[0]) == 'W' ? BlackWins : WhiteWins);
 864 }
 865
 866 (([Ww](hite)?)|([Bb](lack)?))" "[Dd]isconnect(s|ed)  {
 867     return (int) GameUnfinished;
 868 }
 869
 870 [Ss]talemate  {
 871     return (int) GameIsDrawn;
 872 }
 873
 874 "+-+"  {
 875     return (int) GameIsDrawn;
 876 }
 877
 878 ([Cc]heck)?[Mm]ate {
 879     if (WhiteOnMove(yyboardindex))
 880       return (int) BlackWins;
 881     else
 882       return (int) WhiteWins;
 883 }
 884
 885 "++"  {
 886     if (WhiteOnMove(yyboardindex))
 887       return (int) BlackWins;
 888     else
 889       return (int) WhiteWins;
 890 }
 891
 892 [Dd]raw(n)?(" "by)?(" "[Rr]epetition)|(" "[Aa]gree(d|ment))  {
 893     return (int) GameIsDrawn;
 894 }
 895
 896 [Dd]raw(n)?(" (".*")")?  {
 897     return (int) GameIsDrawn;
 898 }
 899
 900 (([Ww](hite)?)|([Bb](lack)?))" "(([Mm]ates)|([Ww][io]n(s)?)) {
 901     return (int) (ToUpper(yytext[0]) == 'W' ? WhiteWins : BlackWins);
 902 }
 903
 904 (([Ww](hite)?)|([Bb](lack)?))" "(([Mm]ated)|([Ll]os[tes]+)) {
 905     return (int) (ToUpper(yytext[0]) == 'W' ? BlackWins : WhiteWins);
 906 }
 907
 908 ("{"[^\}\n]*"} ")?(1-0|"1 - 0"|"1/0"|"1 / 0"|"1:0"|"1 : 0")(" (".*")"|" {".*"}")? {
 909     return (int) WhiteWins;
 910 }
 911
 912 ("{"[^\}\n]*"} ")?(0-1|"0 - 1"|"0/1"|"0 / 1"|"0:1"|"0 : 1")(" (".*")"|" {".*"}")? {
 913     return (int) BlackWins;
 914 }
 915
 916 ("{"[^\}\n]*"} ")?("1/2"|"1 / 2")(" "?[-:]" "?("1/2"|"1 / 2"))?(" (".*")"|" {".*"}")? {
 917     return (int) GameIsDrawn;
 918 }
 919
 920 ("{"[^\}\n]*"} ")?"*"(" (".*")"|" {".*"}")? {
 921     return (int) GameUnfinished;
 922 }
 923
 924 [1-9][0-9]*/"."?[ \t\n]*[a-lNnPpRrBQqKACFEWDGHOo]    {
 925     /* move numbers */
 926     if ((yyleng == 1) && (yytext[0] == '1'))
 927       return (int) MoveNumberOne;
 928 }
 929
 930 \([0-9]+:[0-9][0-9](\.[0-9]+)?\)|\{[0-9]+:[0-9][0-9](\.[0-9]+)?\} {
 931     /* elapsed time indication, e.g. (0:12) or {10:21.071} */
 932     return (int) ElapsedTime;
 933 }
 934
 935 "[--"[^\]]*"--]" {
 936     /* position diagram enclosed in [-- --] */
 937     return (int) PositionDiagram;
 938 }
 939
 940 ^"{--------------"\n[^\}]*\n"--------------}"$ {
 941     /* position diagram enclosed in {-- --} */
 942     return (int) PositionDiagram;
 943 }
 944
 945 \[[ \t\n]*[A-Za-z0-9][A-Za-z0-9_+#=-]*[ \t\n]*\"[^"]*\"[ \t\n]*\] {
 946     return (int) PGNTag;
 947 }
 948
 949 [Gg](nu|NU)" "?[Cc](hess|HESS).*[Gg](ame|AME) {
 950     return (int) GNUChessGame;
 951 }
 952
 953 ^[#;%]" "[^ ]*(" game file"|" position file").*$ {
 954     return (int) XBoardGame;
 955 }
 956
 957 \$[0-9]+        {                               /* numeric annotation glyph */
 958     return (int) NAG;
 959 }
 960
 961 \{[^\}]*\}      {                               /* anything in {} */
 962     return (int) Comment;
 963 }
 964
 965 ;.*$ {                                          /* ; to end of line */
 966     return (int) Comment;
 967 }
 968
 969 \[[^\]]*\]      {                               /* anything in [] */
 970     return (int) Comment;
 971 }
 972
 973 \([^()]*(\([^()]*(\([^()]*(\([^()]*\)[^()]*)*\)[^()]*)*\)[^()]*)+[^()]*\)  { /* very nested () */
 974     return (int) Comment;
 975 }
 976
 977 \([^)][^)]+\)   {                               /* >=2 chars in () */
 978     return (int) Comment;
 979 }
 980
 981 ^[-a-zA-Z0-9]+:" ".*(\n[ \t]+.*)*  {
 982         /* Skip mail headers */
 983 }
 984
 985 [a-zA-Z0-9'-]+                  {
 986         /* Skip random words */
 987 }
 988
 989 .|\n                            {
 990         /* Skip everything else */
 991 }
 992
 993 %%
 994
 995
 996 static char *StringToLex;
 997
 998 #ifndef FLEX_SCANNER
 999 static FILE *lexFP;
1000
1001 static int input()
1002 {
1003     int ret;
1004
1005     if (StringToLex != NULL) {
1006         ret = *StringToLex;
1007         if (ret == NULLCHAR)
1008           ret = EOF;
1009         else
1010           StringToLex++;
1011     } else if (unputCount > 0) {
1012         ret = unputBuffer[--unputCount];
1013     } else {
1014         ret = fgetc(lexFP);
1015     }
1016
1017     if (ret == EOF)
1018       return 0;
1019     else
1020       return ret;
1021 }
1022
1023 /*
1024  * Return offset of next pattern within current file
1025  */
1026 int yyoffset()
1027 {
1028     int offset = ftell(lexFP) - unputCount;
1029
1030     if (offset < 0) {
1031         offset = 0;
1032     }
1033     return(offset);
1034 }
1035
1036 static void output(ch)
1037      int ch;
1038 {
1039     if(appData.debugMode) fprintf(debugFP, "PARSER BUG: unmatched character '%c' (0%o)\n",
1040             ch, ch);
1041 }
1042
1043 static void unput(ch)
1044      int ch;
1045 {
1046     if (ch == 0) return;
1047     if (StringToLex != NULL) {
1048         StringToLex--;
1049     } else {
1050         if (unputCount >= UNPUT_BUF_SIZE)
1051           if(appData.debugMode) fprintf(debugFP, "PARSER BUG: unput buffer overflow '%c' (0%o)\n",
1052                   ch, ch);
1053         unputBuffer[unputCount++] = ch;
1054     }
1055 }
1056
1057 /* Get ready to lex from a new file.  Kludge below sticks
1058    an artificial newline at the front of the file, which the
1059    above grammar ignores, but which makes ^ at start of pattern
1060    match at the real start of the file.
1061 */
1062 void yynewfile(f)
1063      FILE *f;
1064 {
1065     lexFP = f;
1066     StringToLex = NULL;
1067     unputCount = 0;
1068     unput('\n'); /* kludge */
1069 }
1070
1071 /* Get ready to lex from a string.  ^ at start of pattern WON'T
1072    match at the start of the string!
1073 */
1074 void yynewstr(s)
1075      char *s;
1076 {
1077     lexFP = NULL;
1078     StringToLex = s;
1079     unputCount = 0;
1080 }
1081 #endif /*!FLEX_SCANNER*/
1082
1083 #ifdef FLEX_SCANNER
1084 void my_yy_input(buf, result, max_size)
1085      char *buf;
1086      int *result;
1087      int max_size;
1088 {
1089     int count;
1090
1091     if (StringToLex != NULL) {
1092         count = 0;
1093         while (*StringToLex != NULLCHAR) {
1094             *buf++ = *StringToLex++;
1095             count++;
1096         }
1097         *result = count;
1098         return;
1099     } else {
1100         count = fread(buf, 1, max_size, yyin);
1101         if (count == 0) {
1102             *result = YY_NULL;
1103         } else {
1104             *result = count;
1105         }
1106         return;
1107     }
1108 }
1109
1110 static YY_BUFFER_STATE my_file_buffer = NULL;
1111
1112 /*
1113     Return offset of next pattern in the current file.
1114 */
1115 int yyoffset()
1116 {
1117     int pos = yy_c_buf_p - YY_CURRENT_BUFFER->yy_ch_buf;
1118
1119     return(ftell(YY_CURRENT_BUFFER->yy_input_file) -
1120          yy_n_chars + pos);
1121 }
1122
1123
1124 void yynewstr(s)
1125      char *s;
1126 {
1127     if (my_file_buffer != NULL)
1128       yy_delete_buffer(my_file_buffer);
1129     StringToLex = s;
1130     my_file_buffer = yy_create_buffer(stdin, YY_BUF_SIZE);
1131     yy_switch_to_buffer(my_file_buffer);
1132 }
1133
1134 void yynewfile(f)
1135      FILE *f;
1136 {
1137     if (my_file_buffer != NULL)
1138       yy_delete_buffer(my_file_buffer);
1139     StringToLex = NULL;
1140     my_file_buffer = yy_create_buffer(f, YY_BUF_SIZE);
1141     yy_switch_to_buffer(my_file_buffer);
1142 }
1143 #endif /*FLEX_SCANNER*/
1144
1145 int yywrap()
1146 {
1147     return TRUE;
1148 }
1149
1150 /* Parse a move from the given string s */
1151 /* ^ at start of pattern WON'T work here unless using flex */
1152 ChessMove yylexstr(boardIndex, s, text, len)
1153      int boardIndex, len;
1154      char *s, *text;
1155 {
1156     ChessMove ret;
1157     char *oldStringToLex;
1158 #ifdef FLEX_SCANNER
1159     YY_BUFFER_STATE buffer, oldBuffer;
1160 #endif
1161
1162     yyboardindex = boardIndex;
1163     oldStringToLex = StringToLex;
1164     StringToLex = s;
1165 #ifdef FLEX_SCANNER
1166     buffer = yy_create_buffer(stdin, YY_BUF_SIZE);
1167     oldBuffer = YY_CURRENT_BUFFER;
1168     yy_switch_to_buffer(buffer);
1169 #endif /*FLEX_SCANNER*/
1170
1171     ret = (ChessMove) yylex();
1172      strncpy(text, yy_text, len-1); // [HGM] vari: yy_text is not available to caller after buffer switch ?!?
1173      text[len-1] = NULLCHAR;
1174
1175 #ifdef FLEX_SCANNER
1176     if (oldBuffer != NULL)
1177       yy_switch_to_buffer(oldBuffer);
1178     yy_delete_buffer(buffer);
1179 #endif /*FLEX_SCANNER*/
1180     StringToLex = oldStringToLex;
1181
1182     return ret;
1183 }